	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

[CS 1.6] HNS Distance

Теги: Скачать плагины csОстальные

Плагин для HNS (и подобных) серверов, показывает в HUD чате преследующих игроков (списком в столбик). Список игроков формируется исходя из того, смотря на какую дистанцию (настройка в .cfg) вышли преследующие игроки. Если игрок отошел от нужной дистанции, то из списка он пропадет, иначе, если опять появится в нужной зоне дистанции, то попадет вновь в список.

Компилятор: 1.8.3 Multibild +ZIP 913

Команды:

say /show-dist - Команды на вкл/выкл показа преследующих игроков.

say /hns-dist - Команды на вкл/выкл показа преследующих игроков.

.sma / .sp

/*
* - ----------
	"HNS-Distance"
* - ----------
	Поддержка плагина:
* - ----------
	Dev-Cs: @wellasgood
	Telegram: @WellAsGood
* - ----------
	Благодарности:
* - ----------
	Schokk, voed, BlackSignature, Анатолий (goldsrc), w0w, F@ntom, fl0wer, Denzer, wopox1337
* - ----------
	Описание:
* - ----------
	Плагин для HNS (и подобных) серверов, показывает в HUD чате преследующих игроков (списком в столбик). Список игроков формируется исходя из того, смотря на какую дистанцию (настройка в .sma) вышли преследующие игроки. Если игрок отошел от нужной дистанции, то из списка он пропадет, иначе, если опять появится в нужной зоне дистанции, то попадет вновь в список.
* - ----------
*/

/*
* - ----------
	Новые версии:
* - ----------
	ver 1.0.1:
	- Изменен client_PreThink на глобальный set_task (чекер)
	- Добавлена новая настройка (g_TimeTask - время промежутка между запуском set_task до конца карты)

ver 1.0.2:
	- Изменена функция func_persecution, убран аргумент id, так как глобальный сет таск не передает его.
	- Переработана функция func_persecution с учетом изменений, разделена на две функции.
	- Для каждого террориста будет показываться кто его преследует.
	- Основные функции будут работать только тогда, когда будет больше 1 игрока на сервере.
	- Добавлен #define ACCOUNTING_BOTS. По дефолту закомменитрован (отключено), учет ботов в поиске среди всех игроков (а также в отображении HUD списке преследующих).
	- Добавлена поддержка разных языков. (LANG файл)
	- Добавлена функция очищающая HUD канал перед новым показом. (от накладывания сообщений друг на друга)

ver 1.0.3:
	- define ACCOUNTING_BOTS изменен на квар.
	- Настройки в виде констант изменены на enum, далее фигурирует в кварах.
	- Добавлена поддержка автосоздания CFG
	- Убрана поддержка 1.8.3 amxx
	- set_task заменен на set_task_ex
	- Убран include cstrike, теперь команда игрока узнается с помощью get_user_team, include amxmisc.
	- Добавлен enum для индексов команд (избавляемся от магических чисел по коду)
	- get_players заменено на get_players_ex

ver 1.0.4:
	- Добавлены новые переводы в LANG файл: ua, ms
	- Изменен порядок отображения в LANG файле языков (расставлено по алфавиту, спасибо: w0w)

ver 1.0.5:
	- Убрана венгерская нотация по коду. (автор решил пока что ее убрать, так как, еще учит ее, есть недопонимание)
	- Изменены названия функций на нормальные.
	- Изменены некоторые переменные
	- Изменена функция ActionPursuitOne, вычисление координат игрока перенесено во вторую функцию. (спасибо: F@ntom)
	- Добавлен глобальный счетчик для проверки когда очищается канал сообщений. (что-бы не очищался когда не нужно)
	- Добавлена функция выхода игрока с сервера client_disconnected, для сброса счетчика учета.
	- Функция ActionPursuitTwo сделана не public.

ver 1.0.6:
	- Изменено название элемента enum: c AccountingBots на UseBots (использование ботов, спасибо: fl0wer)
	- Добавлена проверка для CheckMsg[TerroristID] = true; в функции ActionPursuitTwo (что бы не устанавливолось если и так true)
	- Поправлены некоторые названия кваров.

ver 1.1.0:
	- Рефакторинг кода
	- Добавлен дефайн РЕЖИМ ХУДА, использовать hud или dhud
	- Добавлен квар, отвечающий за то, активировать ли показ инфы при входе на сервер.
	- Добавлена возможность использовать команды игроками на вкл/выкл показ инфы. (можно менять(добавлять свои) в конст)
	- Добавлена мультиязычность описаний кваров.
	- Дополнен LANG файл.
	- Оставлена только поддержка языков: ru, en.

ver 1.1.1:

- Добавлено отображение информации в чат, о вкл/выкл показа преследующих игроков.
	- Подправлен код.

ver 1.1.2:

- Исправлен хардкод выставления флагов в функции get_players_ex, аттач флагов вынесен в отдельную функцию (thx: Denzer, wopox1337)
	- Изменен код, с учетом нового обновления.
*/

#include <amxmodx>
#include <amxmisc>

#define MULTI_DESC(%0) fmt("%L", LANG_SERVER, %0)

#define AUTO_CONFIG //Автоматическое создание конфига

#define HUD_MODE 1 //Режим показа сообщений. Возможные значения: 1-hud, 2-dhud

new const PLUGIN[] = "HNS-Distance";
new const VERSION[] = "1.1.2";
new const AUTHOR[] = "wellasgood";

enum any:CvarData
{
	UseBots,
	MinDistance,
	MaxDistance,
	Float:TimeHud,
	Float:InfoHudOne,
	Float:InfoHudTwo,
	Float:PlayersHud,
	Float:TimeTask,
	ShowMode
};

enum _:TeamData
{
	Team_tt = 1,
	Team_ct
};

new eCvarData[CvarData], bool:CheckMsg[MAX_PLAYERS+1], bool:CheckShow[MAX_PLAYERS+1], GetPlayersFlags:Flags;

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	register_dictionary("hns-distance.txt");

//Команды на вкл/выкл показа преследующих игроков. (можно менять/добавлять соблюдая структуру)
	new const CMD_OFFON[][] =
	{
		"show-dist",
		"say /show-dist",
		"hns-dist",
		"say /hns-dist"
	};

for(new i; i < sizeof(CMD_OFFON); i++)
	{
		register_clcmd(CMD_OFFON[i], "@CommandHandler");
	}

CreateCvars();

#if defined AUTO_CONFIG
	AutoExecConfig(true, "hns-distance");
#endif

set_task_ex(eCvarData[TimeTask], "@ActionPursuitOne", .flags = SetTask_Repeat);
}

public client_connect(id)
{
	CheckShow[id] = !eCvarData[ShowMode] ? false : true;
}

public client_disconnected(id)
{
	CheckMsg[id] = false;
}

@ActionPursuitOne()
{
	new PlayersID[MAX_PLAYERS], PlayersCount, TerroristID, CheckTeam;

CheckFlags();
	get_players_ex(PlayersID, PlayersCount, Flags);

if(PlayersCount > 1)
	{
		for(new i; i < PlayersCount; i++)
		{
			CheckTeam = get_user_team(PlayersID[i]);

if(CheckTeam != Team_tt || !CheckShow[PlayersID[i]])
			{
				continue;
			}

TerroristID = PlayersID[i];
			ActionPursuitTwo(TerroristID);
		}
	}
}

ActionPursuitTwo(TerroristID)
{
	new PlayersID[MAX_PLAYERS], PlayersCount, Origin_tt[3], Origin_ct[3];
	new CheckTeam, Float:DisplayingMsg = eCvarData[PlayersHud];

if(CheckMsg[TerroristID])
	{
		#if HUD_MODE == 2
		new ClearNum = 8;

for(new i; i < ClearNum; i++)
		{
			show_dhudmessage(TerroristID, "");
		}
		#endif

CheckMsg[TerroristID] = false;
	}

CheckFlags();
	get_players_ex(PlayersID, PlayersCount, Flags);

for(new i; i < PlayersCount; i++)
	{
		CheckTeam = get_user_team(PlayersID[i]);

if(PlayersID[i] != TerroristID && CheckTeam == Team_ct)
		{
			get_user_origin(TerroristID, Origin_tt);
			get_user_origin(PlayersID[i], Origin_ct);

if(eCvarData[MinDistance] <= get_distance(Origin_tt, Origin_ct) <= eCvarData[MaxDistance])
			{
				#if HUD_MODE == 1
				set_hudmessage(255, 255, 255, eCvarData[InfoHudTwo], eCvarData[InfoHudOne], 1, 2.6, 2.6, 0.1, eCvarData[TimeHud], -1);
				show_hudmessage(TerroristID, "%L", TerroristID, "HNS_LANGUAGE_SUPPORT");

set_hudmessage(0, 128, 0, eCvarData[InfoHudTwo], DisplayingMsg, 1, 2.6, 2.6, 0.1, eCvarData[TimeHud], -1);
				show_hudmessage(TerroristID, "%n", PlayersID[i]);
				#else
				set_dhudmessage(255, 255, 255, eCvarData[InfoHudTwo], eCvarData[InfoHudOne], 1, 2.6, 2.6, 0.1, eCvarData[TimeHud]);
				show_dhudmessage(TerroristID, "%L", TerroristID, "HNS_LANGUAGE_SUPPORT");

set_dhudmessage(0, 128, 0, eCvarData[InfoHudTwo], DisplayingMsg, 1, 2.6, 2.6, 0.1, eCvarData[TimeHud]);
				show_dhudmessage(TerroristID, "%n", PlayersID[i]);
				#endif

DisplayingMsg = DisplayingMsg + 0.03;

if(!CheckMsg[TerroristID])
				{
					CheckMsg[TerroristID] = true;
				}
			}
		}
	}
}

CheckFlags()
{
	Flags = (GetPlayers_ExcludeDead|GetPlayers_ExcludeHLTV);

if(!eCvarData[UseBots])
	{
		Flags += GetPlayers_ExcludeBots;
	}
}

@CommandHandler(id)
{
	CheckShow[id] = !CheckShow[id];
	client_print_color(id, print_team_default, "%l", !CheckShow[id] ? "HNS_SHOW_OFF" : "HNS_SHOW_ON");
}

CreateCvars()
{
	bind_pcvar_num(create_cvar(
		.name = "hns_use_bots",
		.string = "0",
		.description = MULTI_DESC("HNS_DESC_USE_BOTS")),
		eCvarData[UseBots]
	);

bind_pcvar_num(create_cvar(
		.name = "hns_min_distance",
		.string = "10",
		.description = MULTI_DESC("HNS_DESC_MIN_DIST")),
		eCvarData[MinDistance]
	);

bind_pcvar_num(create_cvar(
		.name = "hns_max_distance",
		.string = "400",
		.description = MULTI_DESC("HNS_DESC_MAX_DIST")),
		eCvarData[MaxDistance]
	);

bind_pcvar_float(create_cvar(
		.name = "hns_time_hud",
		.string = "0.1",
		.description = MULTI_DESC("HNS_DESC_TIME_HUD")),
		eCvarData[TimeHud]
	);

bind_pcvar_float(create_cvar(
		.name = "hns_info_hud_one",
		.string = "0.15",
		.description = MULTI_DESC("HNS_DESC_HUD_ONE")),
		eCvarData[InfoHudOne]
	);

bind_pcvar_float(create_cvar(
		.name = "hns_info_hud_two",
		.string = "0.8",
		.description = MULTI_DESC("HNS_DESC_HUD_TWO")),
		eCvarData[InfoHudTwo]
	);

bind_pcvar_float(create_cvar(
		.name = "hns_players_hud",
		.string = "0.20",
		.description = MULTI_DESC("HNS_DESC_PLAYERS_HUD")),
		eCvarData[PlayersHud]
	);

bind_pcvar_float(create_cvar(
		.name = "hns_time_task",
		.string = "2.0",
		.description = MULTI_DESC("HNS_DESC_TIME_TASK")),
		eCvarData[TimeTask]
	);

bind_pcvar_num(create_cvar(
		.name = "hns_show_mode",
		.string = "1",
		.description = MULTI_DESC("HNS_DESC_SHOW_MODE"),
		.has_min = true,
		.min_val = 0.0,
		.has_max = true,
		.max_val = 1.0),
		eCvarData[ShowMode]
	);
}

Загрузил FliNe

2021-01-12 19:25:36

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram