	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Adverts HUD 1.0.1

Теги: Скачать плагины csСерверные

Плагин рекламы в HUD/DHUD сообщениях с поддержкой мультиязычности, функционал вполне приличен, вся настройка производится в конфигурационном файле, и (пока что) одном кваре регулирующем интервал появления рекламы.

.sma
#define AUTO_CFG //Автоматическое создание конфига configs/plugins/plugins-adverts_hud.cfg

Настроить плагин можно в: adverts_hud.cfg
Настроить сообщения можно в: adverts_hud.ini

Компилятор: 1.8.3 REapi +ZIP 1241

Команды:

Кваров и команд нет

.sma / .sp

#pragma semicolon 1

//#define DEBUG

#define AUTO_CFG

#include <amxmodx>
#include <amxmisc>

#define MAX_MESSAGE_LEN		516

#define MSG_TYPE_HUD		0
#define MSG_TYPE_DHUD		1

#define MSG_WHOM_DIES		0
#define MSG_WHOM_ALIVES		1
#define MSG_WHOM_ALL		2

const TASK__ADVERT			= 13371;

enum _: cvars_struct	{
	Float: cvar_frequency
};

enum _: color_struct	{
	col_red,
	col_green,
	col_blue
};

enum _: pos_struct	{
	Float: pos_x,
	Float: pos_y
};

enum _: msg_struct	{
	msg_type,
	msg_whom,
	bool: msg_lang,
	msg_color[color_struct],
	msg_pos[pos_struct],
	Float: msg_hold_time,
	msg_channel,
	msg_body[MAX_MESSAGE_LEN]
};

new Array: g_aMsg,
	g_iAdvertsCount;

new g_pCvar[cvars_struct];
new g_eMsgData[msg_struct];

new g_curPos;
new g_syncObj;

public plugin_init()	{
	register_plugin("Adverts hud", "1.0.1", "cpctrl");

register_dictionary("adverts_hud.txt");

bind_pcvar_float(
		create_cvar(
			"advert_frequency",
			"30",
			.description = "Interval between automatic adverts"
		),
		g_pCvar[cvar_frequency]
	);

#if defined AUTO_CFG
		AutoExecConfig();
	#endif

g_syncObj = CreateHudSyncObj();
}

public OnConfigsExecuted()	{
	g_aMsg = ArrayCreate(msg_struct);

new cfgDir[PLATFORM_MAX_PATH];
	get_localinfo("amxx_configsdir", cfgDir, charsmax(cfgDir));
	add(cfgDir, charsmax(cfgDir), "/adverts_hud.ini");

if (!file_exists(cfgDir))	{
		set_fail_state("Configutation file not found <%s>", cfgDir);
		return;
	}

load_adverts(cfgDir);
}

load_adverts(const cfgDir[PLATFORM_MAX_PATH])	{
	new file = fopen(cfgDir, "r");

if (!file)	{
		set_fail_state("Cannot read configuration file <%s>", cfgDir);
		return;
	}

new buffer[MAX_MESSAGE_LEN*2], type[3], whom[3], color[13], pos[13], holdtime[5], channel[3];

new c_red[4], c_green[4], c_blue[4];
	new p_x[5], p_y[5];

while (!feof(file))	{
		fgets(file, buffer, charsmax(buffer));

if (!isdigit(buffer[0]))	{
			continue;
		}

parse(buffer,
			type, charsmax(type),
			whom, charsmax(whom),
			color, charsmax(color),
			pos, charsmax(pos),
			holdtime, charsmax(holdtime),
			channel, charsmax(channel),
			g_eMsgData[msg_body], MAX_MESSAGE_LEN - 1
		);

g_eMsgData[msg_type] = str_to_num(type);
		g_eMsgData[msg_whom] = str_to_num(whom);

parse(color,
			c_red, charsmax(c_red),
			c_green, charsmax(c_green),
			c_blue, charsmax(c_blue)
		);

g_eMsgData[msg_color][col_red] = str_to_num(c_red);
		g_eMsgData[msg_color][col_green] = str_to_num(c_green);
		g_eMsgData[msg_color][col_blue] = str_to_num(c_blue);

parse(pos,
			p_x, charsmax(p_x),
			p_y, charsmax(p_y)
		);

g_eMsgData[msg_pos][pos_x] = str_to_float(p_x);
		g_eMsgData[msg_pos][pos_y] = str_to_float(p_y);

g_eMsgData[msg_hold_time] = str_to_float(holdtime);
		g_eMsgData[msg_channel] = str_to_num(channel);

g_eMsgData[msg_lang] = bool: (equal(g_eMsgData[msg_body], "ADVERT_KEY", 10));

ArrayPushArray(g_aMsg, g_eMsgData);
		g_iAdvertsCount++;
	}

fclose(file);

#if defined DEBUG
		do_debug();
	#endif

server_print("[Advert hud] Loaded %d messages from file", g_iAdvertsCount);

if (g_iAdvertsCount > 0)	{
		set_task(g_pCvar[cvar_frequency], "Task_AdvertShow", TASK__ADVERT);
	}
}

public Task_AdvertShow()	{
	if (g_curPos == g_iAdvertsCount)	{
		g_curPos = 0;
	}

ArrayGetArray(g_aMsg, g_curPos++, g_eMsgData);

new players[MAX_PLAYERS], count, id, szMsg[MAX_MESSAGE_LEN];

new GetPlayersFlags: flags = GetPlayers_ExcludeBots|GetPlayers_ExcludeHLTV;

if (g_eMsgData[msg_whom] == MSG_WHOM_ALIVES)	{
		flags |= GetPlayers_ExcludeDead;
	}
	else if (g_eMsgData[msg_whom] == MSG_WHOM_DIES)	{
		flags |= GetPlayers_ExcludeAlive;
	}

get_players_ex(players, count, flags);

for (new i; i < count; i++)	{
		id = players[i];

if (g_eMsgData[msg_lang])	{
			replace_ml_player(id, szMsg, MAX_MESSAGE_LEN - 1);
		}
		else	{
			copy(szMsg, MAX_MESSAGE_LEN - 1, g_eMsgData[msg_body]);
		}

if (g_eMsgData[msg_type] == MSG_TYPE_HUD)	{
			set_hudmessage(
				g_eMsgData[msg_color][col_red],
				g_eMsgData[msg_color][col_green],
				g_eMsgData[msg_color][col_blue],
				g_eMsgData[msg_pos][pos_x],
				g_eMsgData[msg_pos][pos_y],
				.holdtime = g_eMsgData[msg_hold_time],
				.channel = g_eMsgData[msg_channel]
			);
			ShowSyncHudMsg(id, g_syncObj, szMsg);
		}
		else	{
			set_dhudmessage(
				g_eMsgData[msg_color][col_red],
				g_eMsgData[msg_color][col_green],
				g_eMsgData[msg_color][col_blue],
				g_eMsgData[msg_pos][pos_x],
				g_eMsgData[msg_pos][pos_y],
				.holdtime = g_eMsgData[msg_hold_time]
			);
			show_dhudmessage(id, szMsg);
		}
	}

set_task(g_pCvar[cvar_frequency], "Task_AdvertShow", TASK__ADVERT);
}

stock replace_ml_player(id, szMsg[MAX_MESSAGE_LEN], len)	{
	formatex(szMsg, len, "%L", id, g_eMsgData[msg_body]);
}

public plugin_end()	{
	if (g_aMsg != Invalid_Array)	{
		ArrayDestroy(g_aMsg);
	}
}

#if defined DEBUG
do_debug()	{
	new msg[MAX_MESSAGE_LEN*2], len, i;

do	{
		ArrayGetArray(g_aMsg, i, g_eMsgData);

len = formatex(msg, charsmax(msg), "^nmsg_count = '%d/%d'", ++i, g_iAdvertsCount);
		len += formatex(msg[len], charsmax(msg) - len, "^nmsg_body = '%s'", g_eMsgData[msg_body]);
		len += formatex(msg[len], charsmax(msg) - len, "^nmsg_type = '%d'", g_eMsgData[msg_type]);
		len += formatex(msg[len], charsmax(msg) - len, "^nmsg_whom = '%d'", g_eMsgData[msg_whom]);
		len += formatex(msg[len], charsmax(msg) - len, "^nmsg_lang = '%d'", g_eMsgData[msg_lang]?1:0);
		len += formatex(msg[len], charsmax(msg) - len, "^nmsg_color = 'R%d G%d B%d'", g_eMsgData[msg_color][col_red], g_eMsgData[msg_color][col_green], g_eMsgData[msg_color][col_blue]);
		len += formatex(msg[len], charsmax(msg) - len, "^nmsg_pos = 'X%0.2f Y%0.2f'", g_eMsgData[msg_pos][pos_x], g_eMsgData[msg_pos][pos_y]);
		len += formatex(msg[len], charsmax(msg) - len, "^nmsg_holdtime = '%0.2f'", g_eMsgData[msg_hold_time]);
		len += formatex(msg[len], charsmax(msg) - len, "^nmsg_channel = '%d'", g_eMsgData[msg_channel]);

server_print(msg);
	}	while (i < g_iAdvertsCount);
}
#endif

Загрузил ADEPT

2020-03-04 21:54:24

120

Скачать

У К Р А Ї Н С Ь К И Й - GUNGAME + SKILL - [ © 18+ ]

91.211.118.38:27015

УКРАЇНСЬКИЙ - P U B L I C - [ UP-CS.TOP ] - [ 18+ ]

195.211.60.214:27015

УКРАЇНСЬКИЙ - ПАТРІОТ [ 2013 - 2026 ] © 18+

195.211.60.214:27017

CSHOST.COM.UA |REHLDS|

195.211.60.214:27018

УКРАЇНА - Б А Н Д Е Р Ш Т А Т - [2000 FPS] 18+

91.211.118.156:27071

195.211.60.214:27016

УКРАЇНСЬКІ - ДІВЧАТА - [ RYZEN 9 - 5.7 GHZ ]

91.211.118.49:27030

К І Б О Р Г И - У К Р А Ї Н И [RYZEN 9 - 4.7 GHZ]

91.211.118.49:27037

Не загуржаются настройки плагина(

AndrejSky

2020-04-23 08:24:48

root та картинка есть все норм

ADEPT

2020-03-06 01:47:05

ADEPT у меня её вообще не видно

root

2020-03-05 16:40:54

root а что с ней?

ADEPT

2020-03-05 15:28:33

чет с картинкой, загрузите по новой

root

2020-03-05 00:58:18

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram