	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Auto Team Balance [Авто балансировка игроков]

Теги: Скачать плагины csСерверные

Описание:
Плагин автоматический переводит игроков.
Существуют различные настройки, позволяющие настроить балансировку так, как вам угодно.

Доступные методы перевода:
* Стандартный - рандомный игрок из команды с достатком игроков переводится в противоположную команду с недостатком игроков.
* По скиллу игрока - игрок с высшим показателем убийства/смерти заменяется на игрока с низшим показателем убийства/смерти противоположной команды.

Требования:
* AMX Mod X 1.8.3
* ReGameDLL + ReAPI

Конфигигурационный файл создаётся автоматический по пути: amxmodx/addons/configs/plugins.
Если вам не нужен вывод в чат, вы можете удалить строку в словаре.

Компилятор: 1.8.2 REapi +ZIP 1645

Команды:

Кваров и команд нет

.sma / .sp

/*
	Список изменений:
		1.0 - релиз;
		1.1 - рефакторинг кода;
		1.2 - фикс перевода по скиллу;
		1.3 - добавлена поддержка 1.8.2;
		2.0b - полный рефакторинг кода / добавление кваров, словаря / убрана поддержка 1.8.2.
*/

#include <amxmodx>

#if AMXX_VERSION_NUM < 183
	#assert "AMX Mod X 1.8.3+ required!"
#endif

#tryinclude <reapi>

#if !defined _reapi_included
	#assert "Full reapi library required!"
#endif

new const PLUGIN_NAME[] =	 "Auto Team Balance";
new const PLUGIN_VERSION[] = "2.0b";
new const PLUGIN_AUTHOR[] =	 "MakapoH.";

enum PluginCvars
{
	STANDARD_BALANCE,
	SKILL_BALANCE,
	PLAYER_TRANSFERS_NUM,
	STANDARD_MIN_PLAYERS,
	STANDARD_SCORE_DIFFERENCE,
	SKILL_MIN_PLAYERS,
	SKILL_SCORE_DIFFERENCE
};

new cvar_pointer[PluginCvars];
new cvar_value[PluginCvars];
new cvarhook:cvar_hook_handle[PluginCvars];

new bool:player_already_balance[MAX_CLIENTS + 1];
new player_transfers_num[MAX_CLIENTS + 1];

public plugin_init()
{
	register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR);

register_dictionary("auto_team_balance.txt");

cvar_pointer[STANDARD_BALANCE] = create_cvar("atb_standard_balance", "1", FCVAR_SERVER | FCVAR_PROTECTED, "Стандартный баланс.", true, 0.0, true, 1.0);

cvar_pointer[SKILL_BALANCE] = create_cvar("atb_skill_balance", "1", FCVAR_SERVER | FCVAR_PROTECTED, "Баланс по скиллу.", true, 0.0, true, 1.0);

cvar_pointer[PLAYER_TRANSFERS_NUM] = create_cvar("atb_player_transfers_num", "3", FCVAR_SERVER | FCVAR_PROTECTED, "Количество раундов блокировки перевода игрока. Во избежании повторного перевода.", true, 0.0);

cvar_pointer[STANDARD_MIN_PLAYERS] = create_cvar("atb_standard_min_players", "10", FCVAR_SERVER | FCVAR_PROTECTED, "Минимальное количество игроков для стандартного баланса игроков.", true, 3.0, true, 32.0);

cvar_pointer[STANDARD_SCORE_DIFFERENCE] = create_cvar("atb_standard_score_difference", "2", FCVAR_SERVER | FCVAR_PROTECTED, "Разница в счете между командами для стандартного баланса игроков.", true);

cvar_pointer[SKILL_MIN_PLAYERS] = create_cvar("atb_skill_min_players", "10", FCVAR_SERVER | FCVAR_PROTECTED, "Минимальное количество игроков для баланса по скиллу игроков.", true, 3.0, true, 32.0);

cvar_pointer[SKILL_SCORE_DIFFERENCE] = create_cvar("atb_skill_score_difference", "2", FCVAR_SERVER | FCVAR_PROTECTED, "Разница в счете между командами для баланса игроков по скиллу.", true);

AutoExecConfig(true, "auto_team_balance");

RegisterHookChain(RG_CSGameRules_RestartRound, "GamedllFunc_CSGameRules_RestartRound_Pre", 0);
}

public OnAutoConfigsBuffered()
{
	set_cvar_num("mp_autoteambalance", 0);

cvar_value[STANDARD_BALANCE] = get_pcvar_num(cvar_pointer[STANDARD_BALANCE]);
	cvar_value[SKILL_BALANCE] = get_pcvar_num(cvar_pointer[SKILL_BALANCE]);

hook_cvar_change(cvar_pointer[STANDARD_BALANCE], "cvar_change_callback");
	hook_cvar_change(cvar_pointer[SKILL_BALANCE], "cvar_change_callback");

if(cvar_value[STANDARD_BALANCE])
	{
		cvar_value[STANDARD_MIN_PLAYERS] = get_pcvar_num(cvar_pointer[STANDARD_MIN_PLAYERS]);
		cvar_value[STANDARD_SCORE_DIFFERENCE] = get_pcvar_num(cvar_pointer[STANDARD_SCORE_DIFFERENCE]);

cvar_hook_handle[STANDARD_MIN_PLAYERS] = cvarhook:hook_cvar_change(cvar_pointer[STANDARD_MIN_PLAYERS], "cvar_change_callback");
		cvar_hook_handle[STANDARD_SCORE_DIFFERENCE] = cvarhook:hook_cvar_change(cvar_pointer[STANDARD_SCORE_DIFFERENCE], "cvar_change_callback");
	}

if(cvar_value[SKILL_BALANCE])
	{
		cvar_value[SKILL_MIN_PLAYERS] = get_pcvar_num(cvar_pointer[SKILL_MIN_PLAYERS]);
		cvar_value[SKILL_SCORE_DIFFERENCE] = get_pcvar_num(cvar_pointer[SKILL_SCORE_DIFFERENCE]);

cvar_hook_handle[SKILL_MIN_PLAYERS] = hook_cvar_change(cvar_pointer[SKILL_MIN_PLAYERS], "cvar_change_callback");
		cvar_hook_handle[SKILL_SCORE_DIFFERENCE] = hook_cvar_change(cvar_pointer[SKILL_SCORE_DIFFERENCE], "cvar_change_callback");
	}

cvar_value[PLAYER_TRANSFERS_NUM] = get_pcvar_num(cvar_pointer[PLAYER_TRANSFERS_NUM]);

hook_cvar_change(cvar_pointer[PLAYER_TRANSFERS_NUM], "cvar_change_callback");
}

public cvar_change_callback(pcvar, const old_value[], const new_value[])
{
	if(pcvar == cvar_pointer[STANDARD_BALANCE])
	{
		cvar_value[STANDARD_BALANCE] = str_to_num(new_value);

if(cvar_value[STANDARD_BALANCE])
		{
			enable_cvar_hook(cvarhook:cvar_hook_handle[STANDARD_MIN_PLAYERS]);
			enable_cvar_hook(cvarhook:cvar_hook_handle[STANDARD_SCORE_DIFFERENCE]);
		}
		else
		{
			disable_cvar_hook(cvarhook:cvar_hook_handle[STANDARD_MIN_PLAYERS]);
			disable_cvar_hook(cvarhook:cvar_hook_handle[STANDARD_SCORE_DIFFERENCE]);
		}
	}

else if(pcvar == cvar_pointer[SKILL_BALANCE])
	{
		cvar_value[SKILL_BALANCE] = str_to_num(new_value);

if(cvar_value[SKILL_BALANCE])
		{
			enable_cvar_hook(cvarhook:cvar_hook_handle[SKILL_MIN_PLAYERS]);
			enable_cvar_hook(cvarhook:cvar_hook_handle[SKILL_SCORE_DIFFERENCE]);
		}
		else
		{
			disable_cvar_hook(cvarhook:cvar_hook_handle[SKILL_MIN_PLAYERS]);
			disable_cvar_hook(cvarhook:cvar_hook_handle[SKILL_SCORE_DIFFERENCE]);
		}
	}

else if(pcvar == cvar_pointer[PLAYER_TRANSFERS_NUM])
		cvar_value[PLAYER_TRANSFERS_NUM] = str_to_num(new_value);

else if(pcvar == cvar_pointer[STANDARD_MIN_PLAYERS])
		cvar_value[STANDARD_MIN_PLAYERS] = str_to_num(new_value);

else if(pcvar == cvar_pointer[STANDARD_SCORE_DIFFERENCE])
		cvar_value[STANDARD_SCORE_DIFFERENCE] = str_to_num(new_value);

else if(pcvar == cvar_pointer[SKILL_MIN_PLAYERS])
		cvar_value[SKILL_MIN_PLAYERS] = str_to_num(new_value);

else if(pcvar == cvar_pointer[SKILL_SCORE_DIFFERENCE])
		cvar_value[SKILL_SCORE_DIFFERENCE] = str_to_num(new_value);
}

public client_disconnected(id)
	player_transfers_num[id] = player_already_balance[id] = false;

public GamedllFunc_CSGameRules_RestartRound_Pre()
{
	new ct_wins_num = get_member_game(m_iNumCTWins);
	new te_wins_num = get_member_game(m_iNumTerroristWins);

new WinStatus:win_status = get_member_game(m_iRoundWinStatus);

if((ct_wins_num > te_wins_num) && (win_status == WINSTATUS_TERRORISTS) || (ct_wins_num < te_wins_num) && (win_status == WINSTATUS_CTS))
		return HC_CONTINUE;

new all_players_num = get_playersnum();

if(cvar_value[STANDARD_BALANCE])
		Standard_Balance(all_players_num, ct_wins_num, te_wins_num);

if(cvar_value[SKILL_BALANCE])
		Skill_Balance(all_players_num, ct_wins_num, te_wins_num);

return HC_CONTINUE;
}

stock Standard_Balance(all_players_num, ct_wins_num, te_wins_num)
{
	if(all_players_num < cvar_value[STANDARD_MIN_PLAYERS])
		return 0;

if(abs(ct_wins_num - te_wins_num) < cvar_value[STANDARD_SCORE_DIFFERENCE])
		return 0;

new ct_num = get_member_game(m_iNumCT);
	new te_num = get_member_game(m_iNumTerrorist);

new transfer_num = abs(ct_num - te_num) / 2;

if(!transfer_num)
		return 0;

new players[MAX_CLIENTS], players_num;
	get_players(players, players_num, "eh", (ct_num > te_num) ? "CT" : "TERRORIST");

for(new i, id, name[MAX_NAME_LENGTH]; i < players_num; i++)
	{
		id = players[i];

if(player_transfers_num[id])
		{
			player_transfers_num[id]--;
			continue;
		}
		else player_transfers_num[id] = cvar_value[PLAYER_TRANSFERS_NUM];

player_already_balance[id] = true;

rg_switch_team(id);
		get_user_name(id, name, charsmax(name));

if(GetLangTransKey("STANDARD_BALANCE_SUCCESS"))
			client_print_color(0, print_team_default, "%L", LANG_SERVER, "STANDARD_BALANCE_SUCCESS", name, (ct_num > te_num) ? "террористов" : "спецназа");

if(--transfer_num == 0)
			break;
	}

return 1;
}

stock Skill_Balance(all_players_num, ct_wins_num, te_wins_num)
{
	if(all_players_num < cvar_value[SKILL_MIN_PLAYERS])
		return 0;

if(abs(ct_wins_num - te_wins_num) < cvar_value[SKILL_SCORE_DIFFERENCE])
		return 0;

new player_id1, player_id2;
	new TeamName:leader_team = (ct_wins_num > te_wins_num) ? TEAM_CT : TEAM_TERRORIST;

new players[MAX_CLIENTS], players_num;
	get_players(players, players_num, "h");

for(new i, id, Float:frags, Float:deaths, Float:ratio[MAX_CLIENTS]; i < players_num; i++)
	{
		id = players[i];

if(player_already_balance[id])
			continue;

if(!cvar_value[STANDARD_BALANCE] || (cvar_value[STANDARD_BALANCE] && !player_already_balance[id]))
		{
			if(player_transfers_num[id])
			{
				player_transfers_num[id]--;
				continue;
			}
		}

frags = get_entvar(id, var_frags);
		deaths = float(get_member(id, m_iDeaths));

frags = (frags < 0.0) ? 0.0 : frags;
		deaths = (deaths <= 0.0) ? 1.0 : deaths;

ratio[id] = frags / deaths;
		ratio[id] = Float:(ratio[id] > 100.0) ? 100.0 : ratio[id];

new TeamName:team = get_member(id, m_iTeam);
		switch(team)
		{
			case TEAM_CT, TEAM_TERRORIST:
			{
				if(team == leader_team)
				{
					if(ratio[id] >= ratio[player_id1])
						player_id1 = id;
				}
				else if(ratio[player_id2] >= ratio[id])
					player_id2 = id;
			}
		}		
	}

if(player_id1 && player_id2)
	{
		new name1[MAX_NAME_LENGTH], name2[MAX_NAME_LENGTH];
		get_entvar(player_id1, var_netname, name1, charsmax(name1));
		get_entvar(player_id2, var_netname, name2, charsmax(name2));

rg_switch_team(player_id1);
		rg_switch_team(player_id2);

if(GetLangTransKey("SKILL_BALANCE_SUCCESS"))
			client_print_color(0, print_team_default, "%L", LANG_SERVER, "SKILL_BALANCE_SUCCESS", name1, name2);

player_transfers_num[player_id1] = player_transfers_num[player_id2] = cvar_value[PLAYER_TRANSFERS_NUM];
	}

arrayset(player_already_balance, false, sizeof(player_already_balance));

return 1;
}

Загрузил popca2424

2018-11-19 20:59:06

235

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram