	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

BhopMenu

Теги: Скачать плагины csСерверные

Плагин который дает возможность включить bhop , а так же ускорение.

Компилятор: 1.8.2 835

Команды:

bhop - В консоль что-бы открыть меню

//Настройки в исходнике

const MAXPLAYERS = 32; // Макс. кол-во игроков

const BHOP_FLAG = ADMIN_USER; // Флаг доступа к бхопу

const ACC_FLAG = ADMIN_LEVEL_H; // флаг доступа к ускорителю

const Float:ACCELERATOR_SPEED = 1.1; // Множитель ускорения

.sma / .sp

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>
#include <nvault>

#define get_settings(%0,%1)			g_iPlayerSettings[%0] & %1
#define set_settings(%0,%1)			g_iPlayerSettings[%0] |= %1
#define del_settings(%0,%1)			g_iPlayerSettings[%0] &= ~%1

/**-----------------------НАСТРОЙКИ----------------------------**/

const MAXPLAYERS = 32;					// Макс. кол-во игроков
const BHOP_FLAG = ADMIN_USER;		// Флаг доступа к бхопу
const ACC_FLAG = ADMIN_LEVEL_H;				// флаг доступа к ускорителю
const Float:ACCELERATOR_SPEED = 1.1;	// Множитель ускорения

/**------------------------------------------------------------**/

const iBitBhop 	= (1<<0);
const iBitAcc	= (1<<1);

const IP_LENGHT    = 16;		// не трогать!
const NAME_LENGHT  = 31;		// не трогать!
const STEAM_LENGHT = 34;		// не трогать!

new g_iPlayerSettings[MAXPLAYERS + 1];
new g_pPlayerKey, g_nBhop;
new g_szTemp[35];

public plugin_init()
{
	register_plugin("Bhop Menu", "1.2a", "gyxoBka");
	
	RegisterHam(Ham_Player_Jump, "player", "Ham_PlayerJump");
	
	register_saycmd("bhop", "cmdBhopmenu");
	register_saycmd("bmenu", "cmdBhopmenu");
	register_saycmd("bhopmenu", "cmdBhopmenu");
	
	g_pPlayerKey = register_cvar("bh_savetype", "2");
}

register_saycmd(saycommand[], function[]) 
{
	new szTemp[64];

formatex(szTemp, charsmax(szTemp), "say /%s", saycommand);
	register_clcmd(szTemp, function);
	
	formatex(szTemp, charsmax(szTemp), "say_team /%s", saycommand);
	register_clcmd(szTemp, function);
	
	formatex(szTemp, charsmax(szTemp), "%s", saycommand);
	register_clcmd(szTemp, function);
}

public plugin_cfg()
{
	g_nBhop = nvault_open("bh_menu");
	
	if(g_nBhop == INVALID_HANDLE) pause("a");
}

public client_putinserver(id)
{
	g_iPlayerSettings[id] = 0;
	
	if(~get_user_flags(id) & BHOP_FLAG) return PLUGIN_HANDLED;
	
	get_key(id);
	g_iPlayerSettings[id] = nvault_get(g_nBhop, g_szTemp);
	
	return PLUGIN_HANDLED;
}

public cmdBhopmenu(id)
{
	if(~get_user_flags(id) & BHOP_FLAG) return PLUGIN_HANDLED;
	
	new iMenu, szMenu[512], szTemp[128];
	formatex(szMenu, charsmax(szMenu), "\rМеню Бхопа \yツ");
	iMenu = menu_create(szMenu, "BhopMenuHandler");
	
	formatex(szTemp, charsmax(szTemp), "\wРаспрыжка %s", get_settings(id, iBitBhop) ? "\d[\yВключена\d]" : "\d[\rВыключена\d]");
	menu_additem(iMenu, szTemp);
	
	if(get_user_flags(id) & ACC_FLAG)
	{
		formatex(szTemp, charsmax(szTemp), "\wУскоритель %s", get_settings(id, iBitAcc) ? "\d[\yВключен\d]" : "\d[\rВыключен\d]");
		menu_additem(iMenu, szTemp);
	}
	
	menu_setprop(iMenu, MPROP_EXITNAME, "\rВыход");
	
	menu_display(id, iMenu);
	
	return PLUGIN_HANDLED;
}

public BhopMenuHandler(id, menu, item)
{
	if(item == MENU_EXIT)
	{
		menu_destroy(menu)
		return PLUGIN_HANDLED;
	}
	
	switch(item)
	{
		case 0:
		{
			if(get_settings(id, iBitBhop))
				del_settings(id, iBitBhop)
			else
				set_settings(id, iBitBhop)
		}
		case 1:
		{
			if(~get_user_flags(id) & ACC_FLAG)
			{
				cmdBhopmenu(id);
				return PLUGIN_HANDLED;
			}
			
			if(get_settings(id, iBitAcc)) 
				del_settings(id, iBitAcc)
			else 
				set_settings(id, iBitAcc)
		}
	}
	
	get_key(id);
	new szTempSets[12];
	num_to_str(g_iPlayerSettings[id], szTempSets, charsmax(szTempSets));
	nvault_set(g_nBhop, g_szTemp, szTempSets);
	
	cmdBhopmenu(id);
	
	return PLUGIN_HANDLED;
}

public Ham_PlayerJump(id)
{	
	if(~get_settings(id, iBitBhop)) return HAM_IGNORED;
	
	static iFlags; iFlags = pev(id, pev_flags);
	
	if(iFlags & FL_WATERJUMP || pev(id, pev_waterlevel) >= 2 || !(iFlags & FL_ONGROUND))
		return HAM_IGNORED;

static Float:fVelocity[3];
	pev(id, pev_velocity, fVelocity);
	
	if(get_settings(id, iBitAcc))
	{
		fVelocity[0] *= ACCELERATOR_SPEED;
		fVelocity[1] *= ACCELERATOR_SPEED;
	}
	
	fVelocity[2] = 250.0;
	
	set_pev(id, pev_velocity, fVelocity);
	set_pev(id, pev_gaitsequence, 6);
	set_pev(id, pev_fuser2, 0.0);
	
	return HAM_IGNORED;
}

get_key(const id)
{
	switch(get_pcvar_num(g_pPlayerKey))
	{
		case 1: get_user_name(id, g_szTemp, NAME_LENGHT) // получаем ник
		case 2: get_user_authid(id, g_szTemp, STEAM_LENGHT); // получаем стим
		case 3: get_user_ip( id, g_szTemp, IP_LENGHT, 1 ); // получаем ip
	}
}

public plugin_end()
{
	nvault_close(g_nBhop);
}

Загрузил dvoenkin23gfg

2019-01-07 17:33:44

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram