	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Bonus System

Теги: Скачать плагины csСерверные

Описание:
• Плагин дает бонусы при спавне

Компилятор: 1.8.2 +ZIP 1664

Команды:

; Настройки плагина Bonus System

; Прежде чем начать:

; Ознакомьтесь с функциями!

; Более подробно написано ВНИЗУ, не ленитесь читать!

; "Флаг":

; Флаг для доступа к пункту меню или для выдачи бонуса при спавне.

; Можно указать несколько флагов!

; Укажите "steam" - Для доступа к пункту или бонусу, Steam клиентам.

; А так же можно указать флаг и "steam" - Для доступа игрокам с флагом и Steam клиентам!

; Для этого надо воспользоваться разделителем "|"

; Пример:

; "ut" - Доступно игрокам с флагом "ut"

; "steam" - Доступно Steam клиентам

; "ut|steam" - Доступно игрокам с флагом "ut" и Steam клиентам

; "Идентификатор":

; Идентификатор выдаваемого оружия/гранаты/жизни/брони и т.д.

; А так же можно сразу выдать несколько оружия/гранаты/жизни/брони и т.д.

; Для этого надо воспользоваться разделителем "|"

; Идентификаторы:

; Выдать оружие/гранаты

; health - Выдать жизнь

; kevlar - Выдать броню

; vesthelm - Выдать броню и каску

; money - Выдать деньги

; defuser - Выдать усачки. Выдается только Спецназовцам!

; exec - Выполнить команду

; Пример:

; Для выдачи 2500$:

; "Идентификатор" "Дополнительно"

; "money" "2500"

; Для выдачи оружия Deagle с 35 патронами и для выдачи 2 ослепительных гранат:

; "Идентификатор" "Дополнительно"

; "deagle|flashbang" "35|2"

; Для выдачи 10 жизни и для выдачи 10 брони:

; "Идентификатор" "Дополнительно"

; "health|kevlar" "10|10"

; Для открытия Вип меню:

; "Идентификатор" "Дополнительно"

; "exec" "vipmenu"

; "Дополнительно":

; Количество патронов/гранаты/жизни/брони для выдаваемого оружия/гранаты/жизни/брони и т.д.

; Если для выдачи нескольких оружия/гранаты/жизни/брони, необходимо для каждого по порядку указать количество!

; Для этого надо воспользоваться разделителем "|"

; "Флаг" "Идентификатор" "Дополнительно" "Раунд"

"t" "deagle" "35" "1" ; Выдать игроку с флагом "t" - Deagle

"t" "exec" "vipmenu" "1" ; Автоматический открывать V.I.P меню

"t" "health" "10" "1" ; Выдать 10 хп

"STEAM" "deagle|health|hegrenade" "35|10|1" "1" ; Выдать deagle(35патрон)/хп(10)/граната

.sma / .sp

#include <amxmodx>
#include <reapi>

#define	MAX_ITEM_SPAWN	128	// max item spawn
enum _:SpawnData { sFlags[28], sItem[64], sValue[32], sRound };
new g_arrSpawnData[MAX_ITEM_SPAWN][SpawnData], g_iSpawnSize;

public plugin_init(){
	register_plugin("Bonus System", "1.0", "Dom1no_[KZ]");
	RegisterHookChain(RG_CSGameRules_PlayerSpawn, "CSGameRules_PlayerSpawn", .post = true);
}

public plugin_precache(){
	new szPath[64];	get_localinfo("amxx_configsdir", szPath, charsmax(szPath));
	add(szPath, charsmax(szPath), "/bonus_system.ini");

new iFile = fopen(szPath, "rt");
	if(!iFile){
		new szError[96];
		formatex(szError, charsmax(szError), "File '%s' not found OR incorrect CHMOD!", szPath);
		set_fail_state(szError);
	}

new szBuffer[1024], szRound[3];
	while(!feof(iFile)){
		fgets(iFile, szBuffer, charsmax(szBuffer));
		trim(szBuffer);

if(!szBuffer[0] || szBuffer[0] == ';')
			continue;
		if(parse(szBuffer,
			g_arrSpawnData[g_iSpawnSize][sFlags], charsmax(g_arrSpawnData[][sFlags]), 
			g_arrSpawnData[g_iSpawnSize][sItem], charsmax(g_arrSpawnData[][sItem]), 
			g_arrSpawnData[g_iSpawnSize][sValue], charsmax(g_arrSpawnData[][sValue]), 
			szRound,	charsmax(szRound)
		) == 4){
			g_arrSpawnData[g_iSpawnSize][sRound]	= str_to_num(szRound);
			g_iSpawnSize++;
		}
	}
	fclose(iFile);
}

public CSGameRules_PlayerSpawn(const id){
	if(is_user_alive(id)){
		for(new i; i < g_iSpawnSize; i++){
			if(is_user_flags(id, g_arrSpawnData[i][sFlags]) && get_member_game(m_iTotalRoundsPlayed) >= g_arrSpawnData[i][sRound] - 1)
				give_user_item(id, g_arrSpawnData[i][sItem], g_arrSpawnData[i][sValue]);
		}
	}
	return HC_CONTINUE;
}

give_user_item(const id, const item[], const value[]){
	new ePosItem,	stPosItem,	szItem[64];
	new ePosValue,	stPosValue,	szValue[32];
	do{
		ePosItem	= strfind(item[stPosItem], "|");
		ePosValue	= strfind(value[stPosValue], "|");
		formatex(szItem,	ePosItem,	item[stPosItem]);
		formatex(szValue,	ePosValue,	value[stPosValue]);
		stPosItem	+= ePosItem + 1;
		stPosValue	+= ePosValue + 1;
		trim(szItem);
		trim(szValue);
		if(szItem[0]){
			new iArmor	= rg_get_user_armor(id);

if(strcmp(szItem, "health") == 0)			set_entvar(id, var_health, Float:get_entvar(id, var_health) + Float:str_to_float(szValue));
			else if(strcmp(szItem, "kevlar") == 0)		rg_set_user_armor(id, iArmor + str_to_num(szValue), ARMOR_KEVLAR);
			else if(strcmp(szItem, "vesthelm") == 0)	rg_set_user_armor(id, iArmor + str_to_num(szValue), ARMOR_VESTHELM);
			else if(strcmp(szItem, "money") == 0)		rg_add_account(id, str_to_num(szValue), AS_ADD);
			else if(strcmp(szItem, "exec") == 0)		client_cmd(id, "%s", szValue);
			else if(strcmp(szItem, "defuser") == 0){
				if(get_member(id, m_iTeam) == TEAM_CT)
					rg_give_defusekit(id);
			}
			else{
				new szWeapon[64];	formatex(szWeapon, charsmax(szWeapon), "%s", szItem);
				rg_give_item(id, szWeapon, str_to_num(szValue) < 3 ? GT_APPEND : GT_DROP_AND_REPLACE);
				rg_set_user_bpammo(id, rg_get_weapon_info(szWeapon, WI_ID), str_to_num(szValue));
			}
		}
	}
	while(ePosItem != -1 && ePosValue != -1)
	return HC_CONTINUE;
}

bool:is_user_flags(const id, const flags[]){
	new ePosFlags,	stPosFlags,	szFlags[28];
	do{
		ePosFlags	= strfind(flags[stPosFlags], "|");
		formatex(szFlags,	ePosFlags,	flags[stPosFlags]);
		stPosFlags	+= ePosFlags + 1;
		trim(szFlags);
		if(szFlags[0]){
			if(strcmp(szFlags, "STEAM") == 0){
				if(is_user_steam(id))
					return true;
			}
			else{
				if(get_user_flags(id) & read_flags(szFlags))
					return true;
			}
		}
	}
	while(ePosFlags != -1)
	return false;
}

Загрузил popca2424

2019-04-06 14:07:57

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram