	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Bot Features

Теги: Скачать плагины csАдминские

При взятии бота игроком, игрок получает:

Позицию бота
Позицию прицела бота
Положение в присяде бота (Duck)
Оружие бота
Деньги бота
Экипировку бота
Жизни и броню бота (HP & AP)
Бомбу бота
Щипцы бота
Кол-во патронов бота (ammo & bpammo)

Плагин имеет не навязчивое информирование в чат о взятии бота игроком.

Компилятор: 1.8.2 88

Команды:

Кваров и команд нет

.sma / .sp

//■■■■■■■■■■■■■■■■■■■■■■■ CONFIG START ■■■■■■■■■■■■■■■■■■■■■■■//

new const COMMAND[] = 			"nightvision" //

// #define IGNORE_FLAG  		ADMIN_LEVEL_A // weapon give ignore flag "m"

// #define MIN_BOTS  			1

#define ONLY_TEAMMATES		// required!
#define CHANGE_MODEL		//

#define BOMB_DEFUSE_SUPPORT
// #define LIMITATION_USE

// #define DEBUG		// debug

//■■■■■■■■■■■■■■■■■■■■■■■■ CONFIG END ■■■■■■■■■■■■■■■■■■■■■■■■//

#define VERSION 	"0.0.5"

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <cstrike> 
#include <fun>

#define get_weapon_state(%1)		get_pdata_int(%1, m_fWeaponState, XO_WEAPON)
#define set_weapon_state(%1,%2)		set_pdata_int(%1, m_fWeaponState, %2, XO_WEAPON)

#define SetFlagUsed(%1)				(g_bIsUsed |=  (1 << (%1 & 31)))
#define CheckFlagUsed(%1)  			(g_bIsUsed &   (1 << (%1 & 31)))
#define ClearFlagUsed(%1)	  		(g_bIsUsed &= ~(1 << (%1 & 31)))

#define IsPlayer(%1)				(1 <= %1 <= g_iMaxPlayers)

#define MAX_PLAYERS	 	32
#define MAX_NAME_LEN 	32
#define MAX_ITEM_TYPES  6
#define C4_SLOT 		5
#define PRIMARY_SLOT 	1
#define GRENADE_SLOT 	4
#define OBS_CHASE_FREE 	2	// Free Chase Cam
#define OBS_IN_EYE 		4	// First Person
#define PDATA_SAFE 		2
#define DMG_GRENADE		(1<<24)	// Counter-Strike only - Hit by HE grenade

const NADES_BIT_SUM = (1<<CSW_HEGRENADE)|(1<<CSW_FLASHBANG)|(1<<CSW_SMOKEGRENADE)

const m_flStartThrow = 30
const m_pActiveItem = 373
const m_LastHitGroup = 75
const m_bitsDamageType = 76
const m_fHasSurvivedLastRound = 113
const m_fInReload = 54
const m_fHasPrimary = 116
const m_iDeaths = 444
const m_fWeaponState = 74
const m_pNext = 42
const XO_WEAPON = 4
new const m_rgpPlayerItems_CBasePlayer[MAX_ITEM_TYPES] = {367, 368, ...}

new const g_szWeaponNames[CSW_P90+1][] = {
	"","weapon_p228","","weapon_scout","weapon_hegrenade","weapon_xm1014","weapon_c4",
	"weapon_mac10","weapon_aug","weapon_smokegrenade","weapon_elite","weapon_fiveseven","weapon_ump45",
	"weapon_sg550","weapon_galil","weapon_famas","weapon_usp","weapon_glock18","weapon_awp",
	"weapon_mp5navy","weapon_m249","weapon_m3","weapon_m4a1","weapon_tmp","weapon_g3sg1",
	"weapon_flashbang","weapon_deagle","weapon_sg552","weapon_ak47","weapon_knife","weapon_p90"
}

new const g_szShortWeaponNames[CSW_P90+1][] = {
	"","p228","","scout","grenade","xm1014","","mac10","aug","", "elite",
	"fiveseven","ump45","sg550","galil","famas","usp","glock18","awp","mp5navy",
	"m249","m3","m4a1","tmp","g3sg1","","deagle","sg552","ak47","knife","p90"
}

#if defined DEBUG
new const MODELS[CsInternalModel][] = {
	"UNKNOWN", "CT_URBAN", "T_TERROR", "T_LEET", "T_ARCTIC", "CT_GSG9", 
	"CT_GIGN", "CT_SAS", "T_GUERILLA", "CT_VIP", "T_MILITIA", "CT_SPETSNAZ"
}
#endif

new const Float:sign[4][2] = {{1.0, 1.0}, {1.0, -1.0}, {-1.0, -1.0}, {-1.0, 1.0}}
new g_iMsgIdScreenFade, g_iMsgIdDeathMsg, bool:g_bRoundEnd, g_bIsUsed
new g_szBotName[MAX_PLAYERS+1][MAX_NAME_LEN], g_iBotId[MAX_PLAYERS+1]
new g_iMaxPlayers

public plugin_init()
{
	register_plugin("Bot Features", VERSION, "Vaqtincha")
	register_clcmd(COMMAND, "ClCmd_ControlBot")

register_event("HLTV", "Event_NewRound", "a", "1=0", "2=0")
	register_logevent("LogEvent_RoundEnd", 2, "1=Round_End")
#if defined ONLY_TEAMMATES
	RegisterHam(Ham_Killed, "player", "PlayerKilled_Pre", false)
#endif
	RegisterHam(Ham_Spawn, "player", "PlayerSpawn_Post", true)

g_iMsgIdDeathMsg = get_user_msgid("DeathMsg")
	g_iMsgIdScreenFade = get_user_msgid("ScreenFade")
	g_iMaxPlayers = get_maxplayers()

}

public LogEvent_RoundEnd()
{
	g_bRoundEnd = true
}

public Event_NewRound()
{
	g_bRoundEnd = false
	g_bIsUsed = 0
}

public client_putinserver(id)
{
	if(is_user_bot(id))
	{
		get_user_name(id, g_szBotName[id], MAX_NAME_LEN -1)
	}else{
		g_szBotName[id][0] = 0
	}
}

public PlayerSpawn_Post(id)
{
	ClearFlagUsed(id)
	g_iBotId[id] = 0

if(!g_szBotName[id][0])
	{
		set_user_info(id, "*bot", "0")
	}
}

public PlayerKilled_Pre(id, killer, shouldgib)
{
	if(id == killer || !IsPlayer(killer))
	{
		return HAM_IGNORED
	}

const PARAM_VICTIM = 1
	const PARAM_KILLER = 2

if(g_iBotId[killer] > 0 && is_user_connected(g_iBotId[killer])) 
	{
		SetHamParamEntity(PARAM_KILLER, g_iBotId[killer])

new bool:bIsHeadShot = bool:(get_pdata_int(id, m_LastHitGroup) == HIT_HEAD)
		new iDamageType = get_pdata_int(id, m_bitsDamageType)
		if(iDamageType & DMG_BULLET)
		{
			SendDeathMsg(g_iBotId[killer], id, bIsHeadShot ? 1 : 0, g_szShortWeaponNames[get_user_weapon(killer)])
		}
		if(~iDamageType & DMG_BLAST && iDamageType & DMG_GRENADE)
		{
			SendDeathMsg(g_iBotId[killer], id, 0, "grenade")
		}

return HAM_HANDLED
	}

if(g_iBotId[id] > 0 && is_user_connected(g_iBotId[id])) 
	{
		SetHamParamEntity(PARAM_VICTIM, g_iBotId[id])
		user_kill_fix(id) // kill player manually

return HAM_HANDLED
	}
	
	return HAM_IGNORED
}

public ClCmd_ControlBot(id)
{
	if(is_user_alive(id))
	{
		return PLUGIN_CONTINUE
	}

new iBotId = pev(id, pev_iuser2)
	if(!iBotId || !g_szBotName[iBotId][0] /* is real player */ || iBotId == id /* DEAD_DYING */)
	{
		return PLUGIN_HANDLED
	}

new CsInternalModel:iUserModel, CsTeams:iUserTeam = cs_get_user_team(id, iUserModel)
	if(!(CS_TEAM_T <= iUserTeam <= CS_TEAM_CT))
	{
		client_print(id, print_center, "Спектаторы идите в... :D")
		return PLUGIN_HANDLED
	}

if(g_bRoundEnd)
	{
		client_print(id, print_center, "Раунд уже окончен")
		return PLUGIN_HANDLED
	}
#if defined LIMITATION_USE
	if(CheckFlagUsed(id))
	{
		client_print(id, print_center, "Вы уже использовали!")
		return PLUGIN_HANDLED
	}
#endif
	new iSpecCam = pev(id, pev_iuser1)
	if(is_user_alive(iBotId) && (iSpecCam == OBS_IN_EYE || iSpecCam == OBS_CHASE_FREE))
	{
		new CsInternalModel:iBotModel, CsTeams:iBotTeam = cs_get_user_team(iBotId, iBotModel)
	#if defined ONLY_TEAMMATES
		if(iUserTeam != iBotTeam)
		{
			client_print(id, print_center, "Играть можно только за тиммейтов!")
			return PLUGIN_HANDLED
		}
	#endif
	#if defined MIN_BOTS
		if(GetBotTeamCount(iUserTeam) <= MIN_BOTS)
		{
			client_print(id, print_center, "Это последный бот!^rДайте ему шанс")
			return PLUGIN_HANDLED
		}
	#endif
	#if defined ONLY_TEAMMATES && defined CHANGE_MODEL
		cs_set_user_team(id, iUserTeam, iBotModel)
		cs_set_user_team(iBotId, iBotTeam, iUserModel)
	#else
		cs_set_user_team(id, iBotTeam, iBotModel)
		cs_set_user_team(iBotId, iUserTeam, iUserModel)
	#endif
	#if defined DEBUG
		server_print("^n=================================================^n")
		server_print("BotTeam: %s | BotClass: %s | BotID: %d", iBotTeam == CS_TEAM_T ? "TERRORIST" : "CT", MODELS[iBotModel], iBotId)
	#endif
		if(PlayerSpawnFunc(id, iBotId))
		{
			g_iBotId[id] = iBotId
			set_user_info(id, "*bot", "1") // lol
			SetFlagUsed(id)

new szName[MAX_NAME_LEN]
			get_user_name(id, szName, charsmax(szName))
			client_print(0, print_chat, "Игрок ^"%s^" занял место бота ^"%s^"", szName, g_szBotName[iBotId])
		}
	}

return PLUGIN_HANDLED
}

PlayerSpawnFunc(id, iBotId)
{
	new Float:origin[3], Float:angles[3], Float:v_angles[3], Float:mins[3], Float:maxs[3], bool:bInDuck

// Get Bot position
	pev(iBotId, pev_origin, origin)
	pev(iBotId, pev_angles, angles)
	pev(iBotId, pev_v_angle, v_angles)
	pev(iBotId, pev_mins, mins)
	pev(iBotId, pev_maxs, maxs)
	bInDuck = bool:(pev(iBotId, pev_flags) & FL_DUCKING)

#if defined DEBUG
	server_print("^n----------- Position Info -----------")
	server_print("OriginX: %0.1f | OriginY: %0.1f | OriginZ: %0.1f", origin[0], origin[1], origin[2])
	server_print("AnglesX: %0.1f | AnglesY: %0.1f | AnglesZ: %0.1f", angles[0], angles[1], angles[2])
	server_print("V_AnglesX: %0.1f | V_AnglesY: %0.1f | V_AnglesZ: %0.1f", v_angles[0], v_angles[1], v_angles[2])
	server_print("MinsX: %0.1f | MinsY: %0.1f | MinsZ: %0.1f", mins[0], mins[1], mins[2])
	server_print("MaxsX: %0.1f | MaxsY: %0.1f | MaxsZ: %0.1f", maxs[0], maxs[1], maxs[2])
	server_print("^n----------- Other Info -----------")
	server_print("BotName: %s | Flags: %s", g_szBotName[iBotId], bInDuck ? "DUCKING" : "STANDING")
#endif

// spawn player
	#if AMXX_VERSION_NUM < 183
	set_pdata_int(id, m_fHasPrimary, 0) // fix bug
	#endif
	set_pdata_int(id, m_fHasSurvivedLastRound, 1) // block giving default items
	ExecuteHamB(Ham_CS_RoundRespawn, id)
	SendFadeEffect(id, .hold = 0.1, .r = 10, .g = 10, .b = 10, .a = 140)

#if defined IGNORE_FLAG
	if(~get_user_flags(id) & IGNORE_FLAG)
	{
		BotData(id, iBotId)
	}
#else
	BotData(id, iBotId)
#endif
	// bot kill (without sending "DeathMsg")
	user_kill_fix(iBotId)
	set_pev(iBotId, pev_effects, pev(iBotId, pev_effects) | EF_NODRAW) 	// hide bot player model
	engfunc(EngFunc_SetOrigin, iBotId, Float:{-8191.0, -8191.0, -8191.0}) // move "ClCorpse"

// set player position
	if(bInDuck)
	{
		set_pev(id, pev_flags, pev(id, pev_flags) | FL_DUCKING)
		set_pev(id, pev_button, pev(id, pev_button) | IN_DUCK)
	}

// origin[2] += 1.0
	engfunc(EngFunc_SetSize, id, mins, maxs)
	if(is_hull_vacant(origin, bInDuck ? HULL_HEAD : HULL_HUMAN))
	{
		engfunc(EngFunc_SetOrigin, id, origin)
	}else{
	#if defined DEBUG
		new attempts = 0
		server_print("^n----------- Spawn Info -----------")
		server_print("No free space! Another attempt...")
	#endif
		new Float:neworigin[3]; neworigin[2] = origin[2]

for(new i = 0; i < sizeof(sign); ++i) 
		{
			neworigin[0] = origin[0] - mins[0] * sign[i][0]
			neworigin[1] = origin[1] - mins[1] * sign[i][1]
			#if defined DEBUG
				attempts++
				server_print("attempt...%d", attempts)
			#endif
			if(is_hull_vacant(neworigin, bInDuck ? HULL_HEAD : HULL_HUMAN)) 
			{
				engfunc(EngFunc_SetOrigin, id, neworigin)
			#if defined DEBUG
				server_print("^nFree space found!")
			#endif
				break
			}
		}
	}
#if defined DEBUG
	server_print("^n=================================================^n")
#endif
	set_pev(id, pev_angles, angles)
	set_pev(id, pev_v_angle, v_angles)
	set_pev(id, pev_fixangle, 1)

return 1
}

BotData(id, iBotId)
{
	// get bot money & set player money
	new iMoney = cs_get_user_money(iBotId)
	cs_set_user_money(id, iMoney)
#if defined DEBUG
	server_print("Money: %d", iMoney)
#endif

// get bot armor & health
	new CsArmorType:iArmorType, iArmor = cs_get_user_armor(iBotId, iArmorType)
	new iHealth = get_user_health(iBotId)
#if defined DEBUG
	server_print("ArmorType: %s | Armor: %d | Health: %d", iArmorType == CS_ARMOR_KEVLAR ? "KEVLAR" : iArmorType == CS_ARMOR_VESTHELM ? "VESTHELM" : "NONE", iArmor, iHealth)
	server_print("^n----------- Weapons Info -----------")
#endif

// set player armor & health
	cs_set_user_armor(id, iArmor, iArmorType)
	set_user_health(id, iHealth)

#if defined BOMB_DEFUSE_SUPPORT
	if(cs_get_user_defuse(iBotId))
	{
		cs_set_user_defuse(iBotId, .defusekit = 0)
		cs_set_user_defuse(id, .defusekit = 1)
	}
	if(cs_get_user_plant(iBotId) /* && user_has_weapon(iBotId, CSW_C4) */)
	{
		TransferBomb(iBotId, id)
	}
#endif

// get bot weapons
	new iSlot, iId, iBpAmmo, iClip, iBotWeapon, iState, iNextWeapon

for(iSlot = PRIMARY_SLOT; iSlot <= GRENADE_SLOT; iSlot++)
	{
		iBotWeapon = get_pdata_cbase(iBotId, m_rgpPlayerItems_CBasePlayer[iSlot])
		while(iBotWeapon > 0)
		{
			iNextWeapon = get_pdata_cbase(iBotWeapon, m_pNext, XO_WEAPON)
			if(iSlot == GRENADE_SLOT && get_pdata_float(iBotWeapon, m_flStartThrow, 3) <= 0.0) // grenade throwed
			{
				ExecuteHamB(Ham_Weapon_RetireWeapon, iBotWeapon) // switch to best weapon
				iBotWeapon = iNextWeapon
				continue
			}

iClip = cs_get_weapon_ammo(iBotWeapon)
			iState = get_weapon_state(iBotWeapon)
			iId = cs_get_weapon_id(iBotWeapon)

if(iId > 0 && iId != CSW_KNIFE)
			{
				iBpAmmo = cs_get_user_bpammo(iBotId, iId)
			}

GiveWeapon(id, g_szWeaponNames[iId], iId, iClip, iBpAmmo, iState, .bSound = false)
			iBotWeapon = iNextWeapon

#if defined DEBUG
			server_print("WeaponName: %s | WeaponID: %d | WeaponClip: %d | WeaponAmmo: %d", g_szWeaponNames[iId], iId, iClip, iId == CSW_KNIFE ? 0 : iBpAmmo)
		#endif
		}
	}

new iButton, iActiveItem, iBotActiveItemID
	iActiveItem = get_pdata_cbase(iBotId, m_pActiveItem)
	if(iActiveItem > 0)
	{
		iBotActiveItemID = cs_get_weapon_id(iActiveItem)
		if(NADES_BIT_SUM & (1<<iBotActiveItemID) && (iButton = pev(iBotId, pev_button) & IN_ATTACK)) // ready to launch nade
		{
			set_pev(iBotId, pev_button, iButton &~IN_ATTACK)
		}
	}

engclient_cmd(id, g_szWeaponNames[iBotActiveItemID])
#if defined DEBUG
	server_print("^nActiveWeaponID: %d", iBotActiveItemID)
#endif
}

stock GiveWeapon(id, const szWeaponName[], iId, iClip, iBpAmmo, iState, bool:bSound = true)
{
	new wEnt = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, szWeaponName))
	if(wEnt > 0 && pev_valid(wEnt) == PDATA_SAFE)
	{
		set_pev(wEnt, pev_spawnflags, pev(wEnt, pev_spawnflags) | SF_NORESPAWN)
		dllfunc(DLLFunc_Spawn, wEnt)
		set_weapon_state(wEnt, iState) // set weaponstate before giving
		cs_set_weapon_ammo(wEnt, iClip)
		if(ExecuteHamB(Ham_AddPlayerItem, id, wEnt))
		{
			ExecuteHamB(Ham_Item_AttachToPlayer, wEnt, id)
			
			if(iId > 0 && iId != CSW_KNIFE)
			{
				cs_set_user_bpammo(id, iId, iBpAmmo)
			}
			if(bSound)
			{
				emit_sound(id, CHAN_ITEM, "items/gunpickup2.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
			}
			// set_pdata_int(wEnt, m_fInReload, 1, XO_WEAPON) // reload

return wEnt
		}
		set_pev(wEnt, pev_flags, pev(wEnt, pev_flags) | FL_KILLME)
	}
	return -1
}

stock GetBotTeamCount(CsTeams:iTeam)
{
	new iPlayers[32], iBotCount = 0
	get_players(iPlayers, iBotCount, "adeh", iTeam == CS_TEAM_T ? "TERRORIST" : "CT")
	
	return iBotCount
}

stock TransferBomb(iOwner, iReceiver)
{
	new iBomb = get_pdata_cbase(iOwner, m_rgpPlayerItems_CBasePlayer[C4_SLOT])
	if(iBomb > 0)
	{
		if(ExecuteHamB(Ham_RemovePlayerItem, iOwner, iBomb))
		{
			user_has_weapon(iOwner, CSW_C4, 0)
			ExecuteHamB(Ham_Item_Kill, iBomb)
			give_item(iReceiver, g_szWeaponNames[CSW_C4])
			cs_set_user_plant(iReceiver)

return 1
		}
	}
	return 0
}

stock SendDeathMsg(killer, victim,  headshot, const weapon[])
{
	set_msg_block(g_iMsgIdDeathMsg, BLOCK_ONCE)

message_begin(MSG_ALL, g_iMsgIdDeathMsg, .player = 0)
	write_byte(killer)
	write_byte(victim)
	write_byte(headshot)
	write_string(weapon)
	message_end()
}

stock SendFadeEffect(id, Float:hold = 1.0, r = 255, g = 255, b = 255, a = 255)
{
	message_begin(MSG_ONE_UNRELIABLE, g_iMsgIdScreenFade, .player = id)
	write_short(2<<12)
	write_short(FixedUnsigned16(hold, 1<<12)) // duration
	write_short(0x0000)
	write_byte(r)
	write_byte(g)
	write_byte(b)
	write_byte(a)
	message_end()
}

stock FixedUnsigned16(Float:flValue, iScale)
{
	new iOutput
	iOutput = floatround(flValue * iScale)
	if(iOutput < 0)
	{
		iOutput = 0
	}
	if(iOutput > 0xFFFF)
	{
		iOutput = 0xFFFF
	}
	return iOutput
}

// by VEN
stock bool:is_hull_vacant(const Float:origin[3], hull) 
{
	new tr = 0
	engfunc(EngFunc_TraceHull, origin, origin, 0, hull, 0, tr)

return bool:(!get_tr2(tr, TR_StartSolid) && !get_tr2(tr, TR_AllSolid) && get_tr2(tr, TR_InOpen))
}

stock user_kill_fix(index)
{
	set_msg_block(g_iMsgIdDeathMsg, BLOCK_ONCE)

new Float:frags, deaths = get_pdata_int(index, m_iDeaths)
	pev(index, pev_frags, frags)
	set_pdata_int(index, m_iDeaths, --deaths)
	set_pev(index, pev_frags, ++frags)

dllfunc(DLLFunc_ClientKill, index)

return 1
}

Загрузил perioh

2024-02-12 21:41:20

Скачать

Батяри

91.211.118.32:27025

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram