	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

BuyZone

Теги: Скачать плагины csgoСерверные

Плагин BuyZone – волшебный инструмент, который позволит вам создать новые зоны закупок на любой карте CS:GO, даже если этих зон не было там вообще. Расширение зон закупок в Counter-Strike: Global Offensive иногда бывает просто необходимо, особенно когда адаптируешь карту под большое количество игроков, к примеру, к 32 слотам на сервере.

Компилятор: 1.9.0.6281 1042

Команды:

Кваров и команд нет

.sma / .sp

#pragma semicolon 1
#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
#define PLUGIN_VERSION "1.1.0"

public Plugin:myinfo = {
	name = "[CSGO] BuyZone Simulator",
	author = "KawMAN",
	description = "Enable buyzones on maps that don't have them",
	version = PLUGIN_VERSION,
	url = "http://www.wsciekle.pl"
};

static const String:bz_classname[]	 		= "func_buyzone";
static const Float:PosRefreshEvery			= 1.0; // Position Refresh Time, sec
static const Float:BuyZoneRange			= 200000.0; //How far reach buyzone from spawn

new bool:gRightMap 									= false;
new gSpawnedBuyzone 								= -1;
new bool:gSDKHook_IsBuyZoneHooked[MAXPLAYERS+1]		= { false, ... };

new Handle:ghCvarMpBuyTime							= INVALID_HANDLE;
new Handle:tPosRefresh[MAXPLAYERS+1]				= { INVALID_HANDLE, ... };
new Float:gPlrSpawnPos[MAXPLAYERS+1][3]				;
new bool:gCanBuy[MAXPLAYERS+1]						= { false, ... };

public OnPluginStart() {
	CreateConVar("sm_bzsimulator_v", PLUGIN_VERSION, "[CSGO]BuyZone on GG Version", FCVAR_PLUGIN|FCVAR_SPONLY|FCVAR_REPLICATED|FCVAR_NOTIFY);
	if(!LibraryExists("sdkhooks")) { PrintToServer("[BuyZone Simulator] ERROR: No SDKHooks "); SetFailState("No SDKHooks");}
	if(!HookEventEx("round_start", ecRoundStart)){ PrintToServer("[BuyZone Simulator] ERROR: Can't hook round_start "); SetFailState("Can't hook round_start");  }
	ghCvarMpBuyTime = FindConVar("mp_buytime");
	
	if(GetClientCount(true)>0) {
		OnMapStart();
	}
}

public OnMapStart() {
	if(IsRightMap()) {
		gRightMap = true;
		if(!HookEventEx("player_spawn", ecPlayerSpawn)){ PrintToServer("[BuyZone Simulator] ERROR: Can't hook player_spawn "); SetFailState("Can't hook player_spawn"); }
		if(!HookEventEx("player_death", ecPlayerDeath)){ PrintToServer("[BuyZone Simulator] ERROR: Can't hook player_death "); SetFailState("Can't hook player_death");  }
		if(!HookEventEx("round_end", ecRoundEnd)){ PrintToServer("[BuyZone Simulator] ERROR: Can't hook round_end "); SetFailState("Can't hook round_end");  }
		gSpawnedBuyzone = CreateEntityByName(bz_classname);
		DispatchKeyValue(gSpawnedBuyzone, "TeamNum", "2"); //Maybe unnecessary
		if(!DispatchSpawn(gSpawnedBuyzone)) OnMapEnd();
		PrintToServer("[BuyZone Simulator] Enabled");
	}
}
public ecRoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
	if(gRightMap) {
		CreateTimer(GetConVarFloat(ghCvarMpBuyTime), tcAfterBuyTime);
	}
}
public Action:tcAfterBuyTime(Handle:timer)
{
	//unhook BuyZone
	for(new i=1; i<=MaxClients; i++) {
			UnHookBuyZone(i);
	}
}
public ecPlayerSpawn(Handle:event, const String:name[], bool:dontBroadcast)
{
	new client = GetClientOfUserId(GetEventInt(event, "userid"));
	if(gRightMap && GetEntProp(client, Prop_Send, "m_bIsControllingBot") != 1) { //Check if it's bot takeover or real spawn
		HookBuyZone(client);
	}
}
public ecPlayerDeath(Handle:event, const String:name[], bool:dontBroadcast)
{
	if(gRightMap) {
		new client = GetClientOfUserId(GetEventInt(event, "userid"));
		UnHookBuyZone(client);
	}
}
public ecRoundEnd(Handle:event, const String:name[], bool:dontBroadcast)
{
	if(gRightMap) {
		for(new i=1; i<=MaxClients; i++) {
			UnHookBuyZone(i);
		}
	}
}
public SDKHook_hcPostThinkSetBuyZone(client) {
	if(gCanBuy[client]) SetEntProp(client, Prop_Send, "m_bInBuyZone", 1);
}

HookBuyZone(client)	{
	if (IsClientInGame(client) ) {
			gCanBuy[client] = true;
			if(!gSDKHook_IsBuyZoneHooked[client]) gSDKHook_IsBuyZoneHooked[client] = SDKHookEx(client,SDKHook_PostThink, SDKHook_hcPostThinkSetBuyZone);
			GetClientAbsOrigin(client, gPlrSpawnPos[client]);
			tPosRefresh[client] = CreateTimer(PosRefreshEvery, tcPosRefresh, client, TIMER_REPEAT);
	}
}
UnHookBuyZone(client) {
	if(gSDKHook_IsBuyZoneHooked[client]) {
		SDKUnhook(client, SDKHook_PostThink, SDKHook_hcPostThinkSetBuyZone); 
		gSDKHook_IsBuyZoneHooked[client] = false;
		tPosRefresh[client] = INVALID_HANDLE; //Timer will auto kill
	}
}
public Action:tcPosRefresh(Handle:timer, any:client)
{
	if(timer!=tPosRefresh[client]) return Plugin_Stop; //Auto Kill
 
	decl Float:PlrPos[3];
	GetClientAbsOrigin(client, PlrPos);
	if(GetVectorDistance(PlrPos, gPlrSpawnPos[client], true) > BuyZoneRange) { gCanBuy[client] = false; } else { gCanBuy[client] = true; }
	
	return Plugin_Continue;
}

//Helpers 
bool:IsRightMap() {
	if(FindEntityByClassname(-1, "func_buyzone")==-1) {
		return true;
	}
	return false;
}

public OnMapEnd() {
	if(gSpawnedBuyzone != -1) {
		decl String:classname[128];
		GetEntityClassname(gSpawnedBuyzone, classname, sizeof(classname));
		if(strcmp(bz_classname, classname, false) == 0) {
			AcceptEntityInput(gSpawnedBuyzone, "Kill");
		}
		gSpawnedBuyzone = -1;
	}
	for(new i=1; i<=MaxClients; i++) {
			UnHookBuyZone(i);
	}
	gRightMap = false;
	UnhookEvent("player_spawn", ecPlayerSpawn);
	UnhookEvent("player_death", ecPlayerDeath);
	UnhookEvent("round_end", ecPlayerDeath);

PrintToServer("[BuyZone Simulator] Disabled");
}
public OnPluginEnd() {
	OnMapEnd();
}
public OnPluginPauseChange(bool:pause) {
	if(pause) {
		OnMapEnd();
	} else {
		OnPluginStart();
	}
}

Загрузил dvoenkin23gfg

2019-01-28 21:44:57

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram