	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Color Photo Skill

Теги: Скачать плагины csЭффекты

Данный плагин украсит ваш сервер различными эффектами при убийстве противника.
Особенности:
Если вы совершили обычное убийство противника - экран меркнёт синим (screenfade);
Если же Вы произвели убийство в голову - экран меркнёт зелёным (screenfade);
При двойном убийстве одновременно и более - экран меркнёт красным + будет эффект траектории убийства и обозначения мест убийств.

Компилятор: 1.8.3 984

Команды:

Кваров и команд нет

.sma / .sp

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

/* Если хочешь чтобы, код формировался с обязательным окончанием ";", то включи это.
IP: 31.28.170.102:27026
*/
#pragma semicolon 1

#define PLUGIN    "Color Photo Skill"
#define VERSION   "0.0.2"
#define AUTHOR    "wopox1337"

#define USE_BEAMSPRITE        // Использовать взрыв молнии при DoubleKill
//#define DEBUG

/* создаём перечисление для массива с цветами
в данном случае массив заполнился так:
red = 0,green = 1, blue = 2, alpha = 3
*/
enum Colors{ red, green, blue, alpha };
enum { CoordX, CoordY, CoordZ };

// SETTINGS
#if defined USE_BEAMSPRITE
// Настройка молнии
// new const g_szBeamrSprite[] = "sprites/lgtning.spr";
new const g_szBeamrSprite[] = "sprites/bluejet1.spr";

const STARTFRAME        = 0;    // Начальный кадр
const FRAMERATE            = 1500;    // Кол-во кадров в секунду
const LIFE_TIME            = 10;    // Время жизни (сек)
const LINE_WIDTH        = 60;    // Ширина спрайта
const LINE_NOISE_AMP    = 1;    // Амплитуда колебания
const LINE_RED            = 255;    // Цвет: R
const LINE_GREEN        = 255;    // Цвет: G
const LINE_BLUE            = 255;    // Цвет: B
const LINE_BRIGHTNESS    = 200;    // Яркость
const SCROLL_SPEED        = 30;    // Скорость прокрутки
#endif

// Настройка спрайта взрыва
new const g_szMarkSprite[] = "sprites/bexplo.spr";

const MARK_SCALE        = 10;    // Размер спрайта
const MARK_FRAMERATE    = 20;    // Скорость воспроизведения спрайта
const MARK_FLAGS        = TE_EXPLFLAG_NOSOUND;    // Флаги показа спрайта

// Настройка цвета для каждого типа убийства. RGBA
const All_Alpha    = 100;    // Общая настройка прозрачности эффекта (transparency)
new const g_Kill[Colors]         = {0, 0, 100, All_Alpha};
new const g_HeadShot[Colors]     = {0, 170, 0, All_Alpha};
new const g_DoubleKill[Colors]     = {255, 0, 0, All_Alpha};

// Settings for Screen Fade
const Float:flFxTime_Fade         = 1.0;        // Time
const Float:flHoldTime_Fade     = 1.0;        // Hold TIme

// Setings for Screen Shake
const Float:flAmount_Shake         = 10.0;    // Amount
const Float:flFxTime_Shake         = 2.0;        // Time
const Float:flFrequency_Shake     = 5.0;        // Frequency
// SETTINGS

#if AMXX_VERSION_NUM < 183
new MaxClients;
#endif

new g_iMsgScreenFade, g_iMsgScreenShake;
new Float:g_fLastKill[MAX_PLAYERS+1];

new g_pSpriteIndex_Beam, g_pSpriteIndex_Mark;

const m_LastHitGroup = 75;

#define isValidPlayer(%1) (1 <= %1 <= MaxClients)

#if !defined MAX_PLAYERS
    #define MAX_PLAYERS 32
#endif

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
   
    #if AMXX_VERSION_NUM < 183
    MaxClients = get_maxplayers();
    #endif

RegisterHam(Ham_Killed, "player", "Ham_Killed_post", .Post = true, .specialbot = true);

g_iMsgScreenFade = get_user_msgid("ScreenFade");
    g_iMsgScreenShake = get_user_msgid("ScreenShake");
}

public plugin_precache()
{
    #if defined USE_BEAMSPRITE
    g_pSpriteIndex_Beam = precache_model(g_szBeamrSprite);
    #endif
   
    g_pSpriteIndex_Mark = precache_model(g_szMarkSprite);
}

/* Событие убийства:
    iVictim - id жертвы,
    iKiller - id киллера,
    shouldgib - как убит игрок (???)
*/
public Ham_Killed_post(iVictim, iKiller, shouldgib)
{
    /*    Если id НЕ принадлежит игроку или id жертвы = id киллера,
        тогда не выполняем код дальше.    */
    if (!isValidPlayer(iKiller) || iVictim == iKiller)
    {
        // Выходим из функции проигнорировал дальнейший код функции
        return HAM_HANDLED;
    }
   
    // Создаём массив для цвета
    new iColors[Colors];
   
    // Если (текущее время - время последнего убийства киллера меньше 0.25 сек), то выполняем код:
    if(get_gametime() == g_fLastKill[iKiller])
    {
        // Задаём массиву с цветами данные, массива цвета для даблкила.
        iColors    = g_DoubleKill;
       
        // Выполняем фукнцию пошатывания экрана для киллера
        __UTIL_ScreenShake(iKiller);
       
        // Создаём массивы для хранения координат жертвы.
        new iVictimOrigin[3];
       
        // Получаем координаты жертвы
        get_user_origin(iVictim, iVictimOrigin, .mode = 0);
       
        #if defined USE_BEAMSPRITE
        // ..Убийцы
        new iKillerOrigin[3];
        get_user_origin(iKiller, iKillerOrigin, .mode = 0);
       
        // Показываем линию, между жертвой и убийцой
        Show_Beam(iVictimOrigin, iKillerOrigin);
        #endif
       
        // Показываем спрайт на убитых жертвах
        Mark_Players(iVictimOrigin);
       
        #if defined DEBUG
        // Пишем в лог сервера инфу
        log_amx("Player %d made Double Kill", iKiller, iVictim);
        #endif
    }
    /* Иначе если ("получаем последнюю группу попадания по жертве" и она равна ГОЛОВЕ), то выполняем код: */
    else if(get_pdata_int(iVictim, m_LastHitGroup) == HIT_HEAD)
    {
        // Задаём массиву с цветами данные, массива цвета для хедшота
        iColors    = g_HeadShot;
       
        #if defined DEBUG
        // Пишем в лог сервера инфу
        log_amx("Player %d killed %d (HeadShot)", iKiller, iVictim);
        #endif
    }
    /* Если никакое условие не выполняется (не подходит),
        то выполняем код: */
    else
    {
        // Задаём массиву с цветами данные, массива цвета для обычного убийства
        iColors    = g_Kill;
       
        #if defined DEBUG
        // Пишем в лог сервера инфу
        log_amx("Player %d killed %d", iKiller, iVictim);
        #endif
    }
   
    // Сохраняем для id киллера время последнего убийства.
    g_fLastKill[iKiller] = get_gametime();
       
    #if defined DEBUG
    // Логируем дебаг инфу, если нужно
    log_amx("iColors = ^nR=%d^nG=%d^nB=%d^nAlpha=%d, =============", iColors[red],iColors[green], iColors[blue], iColors[alpha])
    #endif
   
    /* Отправляем функцию, с агрументами заданными по условию выше.
        киллеру отправляем ScreenFade */
    __UTIL_ScreenFade(iKiller, iColors );

// Выходим из фукнции
    return HAM_IGNORED;
}

/* Это сток функция подсветки экрана.
    id - какому игроку
    iColor[Colors] - Цвет подсветки.
*/
stock __UTIL_ScreenFade(id, iColor[Colors] = {0, 0, 0, 0})
{
    // Задаём, какой тип ScreenFade нужен
    const FFADE_IN = 0x0000;

/* Указываем, какое сообщение мы будем отправлять клиенту, по какому каналу
        MSG_ONE - Сообщение одному игроку с гарантией доставки,
        g_iMsgScreenFade - номер (оффсет) нужного нам эффекта
        .player - id игрока
    */
    message_begin(MSG_ONE, g_iMsgScreenFade, .player = id);

// Параметры сообщения:
    write_short(UTIL_FixedUnsigned16(flFxTime_Fade, 1<<12));    // Время действия эффекта
    write_short(UTIL_FixedUnsigned16(flHoldTime_Fade, 1<<12)); // Время отхода эффекта
    write_short(FFADE_IN); // Тип ScreenFade
    write_byte(iColor[red]); // Цвета RGBA
    write_byte(iColor[green]);
    write_byte(iColor[blue]);
    write_byte(iColor[alpha]);
   
    message_end(); // Указание конца сообщения
}

/* Функция тряски экрана:
    id - id игрока,
*/
stock __UTIL_ScreenShake(id)
{
    /* Указываем, какое сообщение мы будем отправлять клиенту, по какому каналу
        MSG_ONE - Сообщение одному игроку с гарантией доставки,
        g_iMsgScreenShake - номер (оффсет) нужного нам эффекта
        .player - id игрока
    */
    message_begin(MSG_ONE, g_iMsgScreenShake, .player = id);

write_short(UTIL_FixedUnsigned16(flAmount_Shake, 1<<12));     // Сила (кол-во)
    write_short(UTIL_FixedUnsigned16(flFxTime_Shake, 1<<12));     // Время действия тряски
    write_short(UTIL_FixedUnsigned16(flFrequency_Shake, 1<<12)); // Частота тряски
   
    message_end(); // Указание конца сообщения
}

stock Show_Beam(StartOrigin[3], EndOrigin[3])
{
    message_begin(MSG_BROADCAST, SVC_TEMPENTITY);
   
    write_byte(TE_BEAMPOINTS);
    write_coord(StartOrigin[CoordX]);
    write_coord(StartOrigin[CoordY]);
    write_coord(StartOrigin[CoordZ]);
    write_coord(EndOrigin[CoordX]);
    write_coord(EndOrigin[CoordY]);
    write_coord(EndOrigin[CoordZ]);
    write_short(g_pSpriteIndex_Beam);
    write_byte(STARTFRAME);
    write_byte(FRAMERATE);
    write_byte(LIFE_TIME*60);
    write_byte(LINE_WIDTH);
    write_byte(LINE_NOISE_AMP);
    write_byte(LINE_RED);
    write_byte(LINE_BLUE);
    write_byte(LINE_BLUE);
    write_byte(LINE_BRIGHTNESS);
    write_byte(SCROLL_SPEED);
   
    message_end();
}

stock Mark_Players(fOrigin[3])
{
    message_begin(MSG_BROADCAST, SVC_TEMPENTITY);

write_byte(TE_EXPLOSION);
    write_coord(fOrigin[CoordX]);
    write_coord(fOrigin[CoordY]);
    write_coord(fOrigin[CoordZ]);
    write_short(g_pSpriteIndex_Mark);
    write_byte(MARK_SCALE);
    write_byte(MARK_FRAMERATE);
    write_byte(MARK_FLAGS);

message_end();
}

/* Спасибо ConnorMcLeod за этот полезный сток.
сток функция достаточно простая, можешь разобрать её сам используя гугл.
*/
stock UTIL_FixedUnsigned16(Float:Value, Scale )
{
    return clamp(floatround( Value * Scale ), 0, 0xFFFF );
}

Загрузил exec208

2019-01-10 21:41:51

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram