	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

[CS 1.6] Alternate Hostage Recue

Теги: Скачать плагины csОстальные

Плагин добавляет альтернативный способ спасать заложников. Надо просто подойти к заложнику нажать "E" и удержать пока полоса не заполниться (аналогично как обезвреживание бомбы)

Компилятор: 1.8.2 Multibild 745

Команды:

Кваров и команд нет

.sma / .sp

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

const RESCUE_TIME = 10
  
 #define PL_VERSION 		"0.1"

// offsets
const m_iTeam = 114

const m_bTouched = 96
const m_bRescueMe = 97
const m_State = 104

//
const hostage_target = pev_euser3
const hostage_rescuetime = pev_teleport_time
const use_waittime = pev_pain_finished

enum { HOSTAGE_FOLLOW, HOSTAGE_STAND, HOSTAGE_DUCK, HOSTAGE_SCARED, HOSTAGE_IDLE, HOSTAGE_FOLLOWPATH }

#define USE_OFF                         0
#define USE_ON                          1
#define USE_SET                         2
#define USE_TOGGLE                      3

#define MAX_CLIENTS                      32

new bool:g_bIsBot[MAX_CLIENTS + 1]

public plugin_init() 
{
	register_plugin("Alternate Hostage Rescue", PL_VERSION, "Vaqtincha")

RegisterHam(Ham_Use, "hostage_entity", "CHostage_Use", .Post = false)
	RegisterHam(Ham_ObjectCaps, "hostage_entity", "CHostage_ObjectCaps", .Post = false)
	RegisterHam(Ham_Think, "hostage_entity", "CHostage_Think", .Post = true)
}

public client_putinserver(pClient) 
{
	g_bIsBot[pClient] = bool:is_user_bot(pClient)
}

public CHostage_Think(const pHostage)
{
	if (pHostage <= 0)
		return HAM_IGNORED
	
	static Float:flWaitTime, Float:flRescueTime, pActivator

pActivator = pev(pHostage, pev_euser3)

if (pActivator > 0)
	{
		pev(pHostage, use_waittime, flWaitTime)
		
		if ((flWaitTime != 0.0 && get_gametime() >= flWaitTime) || !is_user_alive(pActivator))
		{
			ResetAll(pHostage, pActivator)
			// client_print(pActivator, print_chat, "AUTO CANCEL")
			return HAM_IGNORED
		}
	}
	
	pev(pHostage, hostage_rescuetime, flRescueTime)

if (flRescueTime != 0.0 && get_gametime() > flRescueTime)
	{
		set_pdata_int(pHostage, m_bRescueMe, 1)
		ResetAll(pHostage, pActivator)
	}
	
	return HAM_IGNORED
}

public CHostage_ObjectCaps(const pHostage)
{
	SetHamReturnInteger(FCAP_CONTINUOUS_USE|FCAP_ONOFF_USE)
	return HAM_SUPERCEDE
}

public CHostage_Use(const pHostage, const pActivator, const pCaller, const useType, Float:value)
{
	if (1 <= pActivator <= MAX_CLIENTS && g_bIsBot[pActivator])
		return HAM_IGNORED
	
	if (pHostage <= 0 || get_pdata_int(pHostage, m_bRescueMe))
		return HAM_SUPERCEDE

if (value == 1.0 && is_user_alive(pActivator)
		&& pev(pHostage, pev_deadflag) == DEAD_NO
		&& get_pdata_int(pActivator, m_iTeam) == 2) // only ct team can use
	{
		static Float:flCurTime
		flCurTime = get_gametime()

set_pev(pHostage, use_waittime, flCurTime + 0.2)
		
		if (pev(pHostage, hostage_target) == 0)
		{
			SendBarTime(pActivator, RESCUE_TIME)
			set_pdata_int(pHostage, m_bTouched, 1)
			set_pev(pHostage, hostage_target, pActivator)
			set_pev(pHostage, hostage_rescuetime, flCurTime + float(RESCUE_TIME))

// set_pev(pHostage, pev_movetype, MOVETYPE_NONE)
			
			if (get_pdata_int(pHostage, m_State) != HOSTAGE_FOLLOW)
			{
				ExecuteHam(Ham_Use, pHostage, pActivator, pActivator, USE_ON, 1.0)
			}
		}
	}
	else // value == 0.0
	{
		if (pev(pHostage, hostage_target) > 0)
		{
			ResetAll(pHostage, pActivator)
			// client_print(pActivator, print_chat, "CANCEL")
		}
	}

return HAM_SUPERCEDE
}

ResetAll(const pHostage, const pActivator)
{
	set_pev(pHostage, hostage_rescuetime, 0.0)
	set_pev(pHostage, hostage_target, 0)

SendBarTime(pActivator, 0)
}

SendBarTime(const pPlayer, const iSeconds)
{
	static gmsgBarTime 
	
	if (pPlayer <= 0 || !is_user_connected(pPlayer))
		return
	
	if (gmsgBarTime > 0 || (gmsgBarTime = get_user_msgid("BarTime")) > 0)
	{
		message_begin(MSG_ONE_UNRELIABLE, gmsgBarTime, .player = pPlayer)
		write_short(iSeconds)
		message_end()
	}
}

Загрузил FliNe

2020-10-25 16:56:30

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram