	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

[CS 1.6] Magic Mushrooms

Теги: Скачать плагины csЭффекты

Плагин позволяет создавать на карте грибы и задать им магические свойства.

Функциональность и возможности:
Грибы создаются через удобное меню, с выбором действия (свойства)
Можно сохранить грибы в файл, для последующей авто-расстановки после перезапуска карты.
Можно удалить как один гриб, так и сразу все на карте.
Можно перемещать грибы (по осям: x y z)
Если игрок подойдет к счастливому грибу, то получит волшебное превращение со способностями. (настройка кваром и дефайном)
Если игрок подойдет к ядовитому грибу, то произойдет отравление. (с различными эффектами, которые настраиваются кварами)
Есть возможность подключить звук при соприкосновении игрока с грибом.
Скорость не сбрасывается при смене оружия.
Можно задать рандомный режим грибу между свойствами, что-бы игрок не запоминал где какое.
Есть возможность активировать свойства гриба на время (настройка кваром)
Можно вкл/выкл сброс свойств от гриба при спавне игрока.

Компилятор: 1.8.3 Multibild +ZIP 860

Команды:

say /mr-menu - меню создания

.sma / .sp

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>
#include <fakemeta_util>

#if !defined MAX_MAPNAME_LENGTH
 #define MAX_MAPNAME_LENGTH 64
#endif

#define MULTI_DESC(%0) fmt("%L", LANG_SERVER, %0)

#define AUTO_CONFIG //создавать ли конфиг автоматически?

#define MODEL_OPERATION //работа модели (использование сторонней модели которая выдается игроку)

#define MUSHROOMS_SOUND //работа звука, когда игрок соприкасается с грибом.

#define RESETTING_PROPERTIES //Сброс свойст при спавне игрока. (закомментируйте, если не хотите сбрасывать свойства при каждом спавне, а по времени)

#define IsValidPlayer(%0) (%0 > 0 && %0 <= MaxClients)

#if defined MODEL_OPERATION
 #define BIT_VALID(%1,%2) ((%1) & (1 << ((%2) - 1)))
 #define BIT_ADD(%1,%2) ((%1) |= (1 << ((%2) - 1)))
 #define BIT_SUB(%1,%2) ((%1) &= ~(1 << ((%2) - 1)))

new const PLAYER_MODEL[] = "Mushrooms_mario";

new PlayerModel[MAX_PLAYERS+1][64], BitCustomModel;
#endif

enum _:ACTION_VALUES
{
	POISONOUS,
	HAPPY,
	RANDOM
};

enum _:COORD_DATA
{
	Float:X,
	Float:Y,
	Float:Z
};

enum any:CVARS
{
	Float:MM_BONUS_SPEED,
	Float:MM_TIME_KILL,
	Float:MM_MOVE_VALUE,
	MM_SHAKE,
	MM_SCREENFADE,
	MM_POISONING,
	MM_KILL,
	MM_HUD_INFO,
	Float:MM_TIME_POISONING,
	Float:MM_TIME_HAPPY
};

new const PLUGIN[] = "MagicMushrooms";
new const VERSION[] = "0.0.9";
new const AUTHOR[] = "wellasgood";

new const MUSHROOMS_MENU = ADMIN_RCON; //для доступа к главному меню создания грибов.

new const MUSHROOMS_DIR[] = "Mushrooms";
new const MUSHROOMS_MDL[] = "models/Mushrooms/Mushrooms.mdl";

#if defined MUSHROOMS_SOUND
 new const MUSHROOMS_SND[] = "Mushrooms/mushrooms-snd.wav";
#endif

new const Float:MUSHROOMS_MIN[COORD_DATA] =
{
	-11.0,
	-10.0,
	-1.0
};

new const Float:MUSHROOMS_MAX[COORD_DATA] =
{
	11.0,
	10.0,
	4.0
};

new const DATA_VALUES[3][] =
{
	"M",
	"P",
	"R"
};

new eCvars[CVARS], SaveDir[MAX_RESOURCE_PATH_LENGTH], MapPath[MAX_RESOURCE_PATH_LENGTH * 2], Float:PlayerSpeed[MAX_PLAYERS+1];
new MapName[MAX_MAPNAME_LENGTH], MM_BUTTON, Check[MAX_PLAYERS+1], bool:CheckPlayerUse[ACTION_VALUES][MAX_PLAYERS+1];

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	register_dictionary("Mushrooms.txt");

register_clcmd("say /mr-menu", "@OpenMenu");

register_menu("MushroomsMenu", 1023, "@Handle_MushroomsMenu", 0);
	register_menu("MoveMenu", 1023, "@Handle_MoveMenu", 0);

RegisterHam(Ham_CS_Player_ResetMaxSpeed, "player", "@CheckSpeed", 0);

#if defined RESETTING_PROPERTIES
	RegisterHam(Ham_Spawn, "player", "@Ham_PlayerSpawn_Post", 1);
	#endif

register_forward(FM_Touch, "@fwdTouch_Mushrooms");

#if defined MODEL_OPERATION
	register_forward(FM_SetClientKeyValue, "@FM_SetClientKeyValue_Pre", 0);
	#endif

MM_BUTTON = engfunc(EngFunc_AllocString, "func_button");

CreateCvars();

#if defined AUTO_CONFIG
	AutoExecConfig(true, "MagicMushrooms");
	#endif
}

public plugin_precache()
{
	#if defined MODEL_OPERATION
	precache_model(fmt("models/player/%s/%s.mdl", PLAYER_MODEL, PLAYER_MODEL));
	#endif

precache_model(MUSHROOMS_MDL);

#if defined MUSHROOMS_SOUND
	precache_sound(MUSHROOMS_SND);
	#endif
}

public plugin_cfg()
{
	new LocalDir[MAX_RESOURCE_PATH_LENGTH];

get_localinfo("amxx_configsdir", LocalDir, charsmax(LocalDir));
	formatex(SaveDir, charsmax(SaveDir), "%s/%s", LocalDir, MUSHROOMS_DIR);

if(!dir_exists(SaveDir))
	{
		mkdir(SaveDir);
	}

get_mapname(MapName, charsmax(MapName));
	formatex(MapPath, charsmax(MapPath), "%s/%s.cfg", SaveDir, MapName);

if(!file_exists(MapPath))
	{
		return;
	}

ReadMushrooms();
}

public client_disconnected(id)
{
	if(CheckPlayerUse[RANDOM][id])
	{
		CheckPlayerUse[RANDOM][id] = false;
	}

if(CheckPlayerUse[POISONOUS][id])
	{
		CheckPlayerUse[POISONOUS][id] = false;
	}

if(CheckPlayerUse[HAPPY][id])
	{
		#if defined MODEL_OPERATION
		BIT_SUB(BitCustomModel, id);
		#endif

CheckPlayerUse[HAPPY][id] = false;
	}
}

#if defined RESETTING_PROPERTIES
@Ham_PlayerSpawn_Post(id)
{
	if(!is_user_alive(id))
	{
		return;
	}

if(CheckPlayerUse[RANDOM][id])
	{
		CheckPlayerUse[RANDOM][id] = false;
	}

if(CheckPlayerUse[POISONOUS][id])
	{
		CheckPlayerUse[POISONOUS][id] = false;
	}

if(CheckPlayerUse[HAPPY][id])
	{
		#if defined MODEL_OPERATION
		fm_cs_reset_user_model(id);
		#endif

CheckPlayerUse[HAPPY][id] = false;
	}
}
#endif

ReadMushrooms()
{
	new Data[128], Float:Origin[COORD_DATA], f = fopen(MapPath, "rt"), Type[3], Coord_X[13], Coord_Y[13], Coord_Z[13];

while(!feof(f))
	{
		fgets(f, Data, charsmax(Data));
		trim(Data);

if(!Data[0])
		{
			continue;
		}

parse(Data, Type, charsmax(Type), Coord_X, charsmax(Coord_X), Coord_Y, charsmax(Coord_Y), Coord_Z, charsmax(Coord_Z));

Origin[X] = str_to_float(Coord_X);
		Origin[Y] = str_to_float(Coord_Y);
		Origin[Z] = str_to_float(Coord_Z);

if(equal(Type, DATA_VALUES[0]))
		{
			CreateEntity(0, "mushrooms_m", Origin);
		}
		else if(equal(Type, DATA_VALUES[1]))
		{
			CreateEntity(0, "mushrooms_p", Origin);
		}
		else if(equal(Type, DATA_VALUES[2]))
		{
			CreateEntity(0, "mushrooms_r", Origin);
		}
		else
		{
			break;
		}
	}

fclose(f);
}

@OpenMenu(id)
{
	if(~get_user_flags(id) & MUSHROOMS_MENU)
	{
		return PLUGIN_HANDLED;
	}

MushroomsMenu(id);
	return PLUGIN_HANDLED;
}

MushroomsMenu(id)
{
	new Menu[MAX_MENU_LENGTH], Keys = MENU_KEY_1|MENU_KEY_2|MENU_KEY_3|MENU_KEY_4|MENU_KEY_5|MENU_KEY_6|MENU_KEY_0;
	new Len = formatex(Menu, charsmax(Menu), "%L^n^n", id, "MM_MAIN_MENU_TITLE");

Len += formatex(Menu[Len], charsmax(Menu) - Len, "\r[1] \y# \w%L: \r[\y%L\r]^n", id, "MM_MAIN_MENU_ITEM_1", id, fmt("MM_MAIN_MENU_ITEM1_VALUE%d", Check[id] + 1));
	Len += formatex(Menu[Len], charsmax(Menu) - Len, "\r[2] \y# \w%L^n^n", id, "MM_MAIN_MENU_ITEM_2");
	Len += formatex(Menu[Len], charsmax(Menu) - Len, "\r[3] \y# \w%L^n", id, "MM_MAIN_MENU_ITEM_3");
	Len += formatex(Menu[Len], charsmax(Menu) - Len, "\r[4] \y# \w%L^n", id, "MM_MAIN_MENU_ITEM_4");
	Len += formatex(Menu[Len], charsmax(Menu) - Len, "\r[5] \y# \w%L^n", id, "MM_MAIN_MENU_ITEM_5");
	Len += formatex(Menu[Len], charsmax(Menu) - Len, "\r[6] \y# \w%L^n^n", id, "MM_MAIN_MENU_ITEM_6");

formatex(Menu[Len], charsmax(Menu) - Len, "\r[0] \y# \w%L", id, "MM_MENU_EXIT");
	return show_menu(id, Keys, Menu, -1, "MushroomsMenu");
}

@Handle_MushroomsMenu(id, Keys)
{
	switch(Keys)
	{
		case 0:
		{
			Check[id] = (Check[id] + 1) % 3;
		}
		case 1:
		{
			switch(Check[id])
			{
				case 0: CreateEntity(id, "mushrooms_p");
				case 1: CreateEntity(id, "mushrooms_m");
				case 2: CreateEntity(id, "mushrooms_r");
			}
		}
		case 2:
		{
			MoveMenu(id);
			return PLUGIN_HANDLED;
		}
		case 3:
		{
			if(file_exists(MapPath))
			{
				delete_file(MapPath);
			}

SaveAndDeleteHandler("mushrooms_m", 1, 0);
			SaveAndDeleteHandler("mushrooms_p", 1, 1);
			SaveAndDeleteHandler("mushrooms_r", 1, 2);
		}
		case 4:
		{
			new ent, body;
			get_user_aiming(id, ent, body, 9999);

new Classname[32];
			pev(ent, pev_classname, Classname, charsmax(Classname));

if(equal(Classname, "mushrooms_m") || equal(Classname, "mushrooms_p") || equal(Classname, "mushrooms_r"))
			{
				set_pev(ent, pev_flags, FL_KILLME);
			}
		}
		case 5:
		{
			SaveAndDeleteHandler("mushrooms_m", 2, 0);
			SaveAndDeleteHandler("mushrooms_p", 2, 0);
			SaveAndDeleteHandler("mushrooms_r", 2, 0);
		}
		case 9:
		{
			return PLUGIN_HANDLED;
		}
	}

MushroomsMenu(id);
	return PLUGIN_HANDLED;
}

SaveAndDeleteHandler(const classname[], num, value)
{
	new Data[128], ent, Float:Origin[COORD_DATA];

while((ent = engfunc(EngFunc_FindEntityByString, ent, "classname", classname)))
	{
		switch(num)
		{
			case 1:
			{
				pev(ent, pev_origin, Origin);

formatex(Data, charsmax(Data), fmt("%s %f %f %f", DATA_VALUES[value], Origin[X], Origin[Y], Origin[Z]));
				write_file(MapPath, Data);
			}
			case 2:
			{
				set_pev(ent, pev_flags, FL_KILLME);
			}
		}
	}
}

CreateEntity(id, const Classname[], Float:Origin[COORD_DATA]={0.0, 0.0, 0.0})
{
	new ent = engfunc(EngFunc_CreateNamedEntity, MM_BUTTON);

if(!pev_valid(ent))
	{
		return PLUGIN_HANDLED;
	}

set_pev(ent, pev_classname, Classname);
	set_pev(ent, pev_solid, SOLID_BBOX);
	set_pev(ent, pev_movetype, MOVETYPE_NONE);
	set_pev(ent, pev_target);

engfunc(EngFunc_SetModel, ent, MUSHROOMS_MDL);
	engfunc(EngFunc_SetSize, ent, MUSHROOMS_MIN, MUSHROOMS_MAX);

if(id)
	{
		fm_get_aim_origin(id, Origin);
	}

engfunc(EngFunc_SetOrigin, ent, Origin);

return PLUGIN_HANDLED;
}

MoveMenu(id)
{
	new Menu[MAX_MENU_LENGTH], Keys = MENU_KEY_1|MENU_KEY_2|MENU_KEY_3|MENU_KEY_4|MENU_KEY_5|MENU_KEY_6|MENU_KEY_0;
	new Len = formatex(Menu, charsmax(Menu), "%L^n^n", id, "MM_MOVE_MENU_TITLE");

Len += formatex(Menu[Len], charsmax(Menu) - Len, "\r[1] \y# \wX++^n");
	Len += formatex(Menu[Len], charsmax(Menu) - Len, "\r[2] \y# \wX--^n");
	Len += formatex(Menu[Len], charsmax(Menu) - Len, "\r[3] \y# \wY++^n");
	Len += formatex(Menu[Len], charsmax(Menu) - Len, "\r[4] \y# \wY--^n");
	Len += formatex(Menu[Len], charsmax(Menu) - Len, "\r[5] \y# \wZ++^n");
	Len += formatex(Menu[Len], charsmax(Menu) - Len, "\r[6] \y# \wZ--^n^n");

formatex(Menu[Len], charsmax(Menu) - Len, "\r[0] \y# \w%L", id, "MM_MENU_BACK");
	return show_menu(id, Keys, Menu, -1, "MoveMenu");
}

@Handle_MoveMenu(id, Keys)
{
	switch(Keys)
	{
		case 9:
		{
			MushroomsMenu(id);
			return PLUGIN_HANDLED;
		}
		default:
		{
			MoveEntity(id, Keys);
		}
	}

MoveMenu(id);
	return PLUGIN_HANDLED;
}

MoveEntity(id, mode)
{
	new ent, body;
	get_user_aiming(id, ent, body, 9999);

new Classname[32];
	pev(ent, pev_classname, Classname, charsmax(Classname));

if(equal(Classname, "mushrooms_m") || equal(Classname, "mushrooms_p") || equal(Classname, "mushrooms_r"))
	{
		new Float:DataCoord[COORD_DATA];
		pev(ent, pev_origin, DataCoord);

switch(mode)
		{
			case 0: DataCoord[X] += eCvars[MM_MOVE_VALUE];
			case 1: DataCoord[X] -= eCvars[MM_MOVE_VALUE];
			case 2: DataCoord[Y] += eCvars[MM_MOVE_VALUE];
			case 3: DataCoord[Y] -= eCvars[MM_MOVE_VALUE];
			case 4: DataCoord[Z] += eCvars[MM_MOVE_VALUE];
			case 5: DataCoord[Z] -= eCvars[MM_MOVE_VALUE];
		}

engfunc(EngFunc_SetOrigin, ent, DataCoord);
	}

return PLUGIN_HANDLED;
}

@CheckSpeed(id)
{
	if(CheckPlayerUse[HAPPY][id])
	{
		return HAM_SUPERCEDE;
	}

return HAM_IGNORED;
}

@fwdTouch_Mushrooms(ent, id)
{
	if(!IsValidPlayer(id))
	{
		return FMRES_IGNORED;
	}

new Classname[32];
	pev(ent, pev_classname, Classname, charsmax(Classname));

if(equal(Classname, "mushrooms_r") && !CheckPlayerUse[RANDOM][id])
	{
		arrayset(Classname, 0, charsmax(Classname));

new Num = random_num(0, 1);

formatex(Classname, charsmax(Classname), Num == 0 ? "mushrooms_p" : "mushrooms_m");

CheckPlayerUse[RANDOM][id] = true;

if(CheckPlayerUse[Num][id])
		{
			return FMRES_IGNORED;
		}
	}

if(equal(Classname, "mushrooms_p") && !CheckPlayerUse[POISONOUS][id] || equal(Classname, "mushrooms_m") && !CheckPlayerUse[HAPPY][id])
	{
		if(equal(Classname, "mushrooms_p"))
		{
			if(eCvars[MM_SHAKE])
			{
				ScreenShake(id, (1 << 12), (1 << 12), (1 << 12));
			}

if(eCvars[MM_SCREENFADE])
			{
				ScreenFade(id, 2);
			}

if(eCvars[MM_KILL])
			{
				set_task_ex(eCvars[MM_TIME_KILL], "@EventKill", id);
			}

if(eCvars[MM_POISONING])
			{
				new array[1];
				array[0] = 0;

@EventPoisoning(array, id);

if(eCvars[MM_TIME_POISONING] > 0.0)
				{
					array[0] = 1;
					set_task_ex(eCvars[MM_TIME_POISONING], "@EventPoisoning", id, array, sizeof array);
				}
			}

CheckPlayerUse[POISONOUS][id] = true;
		}
		else if(equal(Classname, "mushrooms_m"))
		{
			new array[1];
			array[0] = 0;

pev(id, pev_maxspeed, PlayerSpeed[id]);
			@EventHappy(array, id);

if(eCvars[MM_TIME_HAPPY] > 0.0)
			{
				array[0] = 1;
				set_task_ex(eCvars[MM_TIME_HAPPY], "@EventHappy", id, array, sizeof array);
			}

CheckPlayerUse[HAPPY][id] = true;
		}

#if defined MUSHROOMS_SOUND
		SendAudio(id, MUSHROOMS_SND, PITCH_NORM);
		#endif

if(eCvars[MM_HUD_INFO])
		{
			set_hudmessage(random_num(150, 255), random_num(150, 255), random_num(150, 255), -1.0, -0.50, 0, _, 1.0, _, 1.5, -1);
			show_hudmessage(id, "%L", id, !equal(Classname, "mushrooms_m") ? "MM_HUD_INFO_1" : "MM_HUD_INFO_2");
		}
	}

return FMRES_IGNORED;
}

@EventKill(id)
{
	user_kill(id, 0);
}

@EventPoisoning(value[], id)
{
	new check = value[0];

message_begin(MSG_ONE, get_user_msgid("SetFOV"), { 0, 0, 0 }, id);

write_byte(check == 1 ? 0 : 180);

message_end();

if(check == 1)
	{
		CheckPlayerUse[POISONOUS][id] = false;

if(CheckPlayerUse[RANDOM][id])
		{
			CheckPlayerUse[RANDOM][id] = false;
		}
	}
}

@EventHappy(value[], id)
{
	new check = value[0];

#if defined MODEL_OPERATION
	check == 0 ? fm_cs_set_user_model(id, PLAYER_MODEL) : fm_cs_reset_user_model(id);
	#endif

if(check == 1)
	{
		CheckPlayerUse[HAPPY][id] = false;

if(CheckPlayerUse[RANDOM][id])
		{
			CheckPlayerUse[RANDOM][id] = false;
		}
	}

check == 0 ? set_pev(id, pev_maxspeed, eCvars[MM_BONUS_SPEED]) : set_pev(id, pev_maxspeed, PlayerSpeed[id]);
}

CreateCvars()
{
	bind_pcvar_float(create_cvar(
		.name = "mr_move_value",
		.string = "10.0",
		.description = MULTI_DESC("MM_DESC_MOVE_VALUE")),
		eCvars[MM_MOVE_VALUE]
	);

bind_pcvar_float(create_cvar(
		.name = "mr_time_kill",
		.string = "3.0",
		.description = MULTI_DESC("MM_DESC_TIME_KILL")),
		eCvars[MM_TIME_KILL]
	);

bind_pcvar_float(create_cvar(
		.name = "mr_bonus_speed",
		.string = "1500.0",
		.description = MULTI_DESC("MM_DESC_BONUS_SPEED")),
		eCvars[MM_BONUS_SPEED]
	);

bind_pcvar_num(create_cvar(
		.name = "mr_shake",
		.string = "1",
		.description = MULTI_DESC("MM_DESC_SHAKE"),
		.has_min = true,
		.min_val = 0.0,
		.has_max = true,
		.max_val = 1.0),
		eCvars[MM_SHAKE]
	);

bind_pcvar_num(create_cvar(
		.name = "mr_screenfade",
		.string = "1",
		.description = MULTI_DESC("MM_DESC_SCREENFADE"),
		.has_min = true,
		.min_val = 0.0,
		.has_max = true,
		.max_val = 1.0),
		eCvars[MM_SCREENFADE]
	);

bind_pcvar_num(create_cvar(
		.name = "mr_poisoning",
		.string = "1",
		.description = MULTI_DESC("MM_DESC_POISONING"),
		.has_min = true,
		.min_val = 0.0,
		.has_max = true,
		.max_val = 1.0),
		eCvars[MM_POISONING]
	);

bind_pcvar_num(create_cvar(
		.name = "mr_kill",
		.string = "1",
		.description = MULTI_DESC("MM_DESC_KILL"),
		.has_min = true,
		.min_val = 0.0,
		.has_max = true,
		.max_val = 1.0),
		eCvars[MM_KILL]
	);

bind_pcvar_num(create_cvar(
		.name = "mr_hud_info",
		.string = "1",
		.description = MULTI_DESC("MM_DESC_HUD_INFO"),
		.has_min = true,
		.min_val = 0.0,
		.has_max = true,
		.max_val = 1.0),
		eCvars[MM_HUD_INFO]
	);

bind_pcvar_float(create_cvar(
		.name = "mr_time_poisoning",
		.string = "15.0",
		.description = MULTI_DESC("MM_DESC_TIME_POISONING")),
		eCvars[MM_TIME_POISONING]
	);

bind_pcvar_float(create_cvar(
		.name = "mr_time_happy",
		.string = "20.0",
		.description = MULTI_DESC("MM_DESC_TIME_HAPPY")),
		eCvars[MM_TIME_HAPPY]
	);
}

#if defined MODEL_OPERATION
@FM_SetClientKeyValue_Pre(id, const Infobuffer[], const Key[])
{
	if(BIT_VALID(BitCustomModel, id) && equal(Key, "model"))
	{
		static CurrentModel[32];
		fm_cs_get_user_model(id, CurrentModel, charsmax(CurrentModel));

if(!equal(CurrentModel, PlayerModel[id]))
		{
			fm_cs_set_user_model(id, PlayerModel[id]);
		}

return FMRES_SUPERCEDE;
	}

return FMRES_IGNORED;
}

stock fm_cs_get_user_model(id, Model[], Len)
{
	engfunc(EngFunc_InfoKeyValue, engfunc(EngFunc_GetInfoKeyBuffer, id), "model", Model, Len);
}

stock fm_cs_set_user_model(id, const ModelName[])
{
	engfunc(EngFunc_SetClientKeyValue, id, engfunc(EngFunc_GetInfoKeyBuffer, id), "model", ModelName);
	copy(PlayerModel[id], charsmax(PlayerModel[]), ModelName);

BIT_ADD(BitCustomModel, id);
}

stock fm_cs_reset_user_model(id)
{
	BIT_SUB(BitCustomModel, id);

dllfunc(DLLFunc_ClientUserInfoChanged, id, engfunc(EngFunc_GetInfoKeyBuffer, id));
}
#endif

stock ScreenFade(id, fade)
{
	new time, hold, flags;
	static msg_screenfade;

if(!msg_screenfade)
	{
		msg_screenfade = get_user_msgid("ScreenFade");
	}

switch(fade)
	{
		case 1: { time = 1; hold = 1; flags = 4; }
		case 2: { time = 4096; hold = 1024; flags = 1; }
		default: { time = 4096; hold = 1024; flags = 2; }
	}

message_begin(MSG_ONE, msg_screenfade, _, id);

write_short(time);
	write_short(hold);
	write_short(flags);
	write_byte(random_num(0, 100));
	write_byte(random_num(100, 200));
	write_byte(random_num(200, 255));
	write_byte(255);

message_end();
}

stock ScreenShake(id, Amplitude, Duration, Frequency, Reliable = 0)
{
	message_begin(Reliable ? MSG_ONE : MSG_ONE_UNRELIABLE, 97, { 0.0, 0.0, 0.0 }, id);

write_short(Amplitude);
	write_short(Duration);
	write_short(Frequency);

message_end();
}

#if defined MUSHROOMS_SOUND
stock SendAudio(id, const audio[], pitch)
{
	static MsgSendAudio;

if(!MsgSendAudio)
	{
		MsgSendAudio = get_user_msgid("SendAudio");
	}

message_begin(id ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, MsgSendAudio, _, id);

write_byte(id);
	write_string(audio);
	write_short(pitch);

message_end();
}
#endif

Загрузил FliNe

2021-01-07 14:23:45

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг Касса	Fast DL Backup	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram