	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

[CS 1.6] Personal combat missions

Теги: Скачать плагины csОстальные

Плагин создает Личные Боевые Задания для игроков.
Этот плагин состоит из 4-ёх заданий, в каждом из заданий по 4 миссии и соответствующая награда.
В плагине 3 задания обычных, с вполне себе легкими миссиями, и 4 задание - "спец задание" в нем уже идут более сложные миссии и достойная награда.
Данный плагин подойдет для серверов с модом "Public".
* Все награды\миссии привязываются по steam_id.
** В таблице в базе,можно самому прописать/удалить кому угодно миссии\задания.

Компилятор: 1.8.3 Multibild +ZIP 1213

Команды:

say /lbz - Открывается само motd или меню с просмотром заданий.

lbz_sgl_host "127.0.0.1" // - Имя/Адрес хоста БД.

• lbz_sgl_user "root" // - Ваш логин к БД.

• lbz_sgl_pwd "vertrigo" // - Ваш пароль к БД.

• lbz_sgl_db "test" // - Название используемой БД.

• lbz_hud_color_r "0" // - Цвет HUD - сообщения

• lbz_hud_color_g "255" // - Цвет HUD - сообщения

• lbz_hud_color_b "255" // - Цвет HUD - сообщения

• lbz_hud_pos_x "0.02" // - Координаты HUD - сообщения "x"

• lbz_hud_pos_y "0.18" // - Координаты HUD - сообщения "y"

• lbz_min_players "6" // - Сколько игроков нужно что бы миссии/задания работали.

• lbz_bonus_money "700" // - Сколько давать денег при убийстве в 2 награде.

• lbz_bonus_money_max "16000" // - Лимит выдачи денег.

• lbz_bonus_health "15" // - Сколько хп давать при убийстве в 1 награде.

• lbz_bonus_health_max "105" // - Макимальное количество хп от вампиризма в 1 награде.

• lbz_maps_blocks "awp_ ," // - Карты,на которых не будут работать награды(файл создается сам)

• lbz_bonus_scout_spd "0.5" // - Скорость стрельбы "Скорострельного скаута" в 4 награде.

.sma / .sp

#include <amxmodx>
#include <amxmisc>
#include <sqlx>
#include <fakemeta>
#include <cstrike>
#include <hamsandwich>
#include <fun>

#define VERSION "1.0"
#define TAG "^4[LBZ]^1"

#if AMXX_VERSION_NUM < 183
	#include <colorchat>
	#include <dhudmessage>
#else
	#define DontChange print_team_default
	#define Blue print_team_blue
	#define Red print_team_red
	#define Grey print_team_grey
#endif

enum 
{
	VAMPIRE = 1,
	MONEY,
	HEALTH,
	SCOUT
}

enum
{
	DOUBLE_WEAPON,
	DOUBLE_GRENADE,
	KNIFE,
	M249,
	NODMG,
	HOSTAGE,
	MOSTDMG,
	FRAGS,
	DMG_DGL,
	DMG_AK47,
	DMG_M4A1,
	DMG_FAMAS,
	DEFUSED,
	NODEATH,
	HEADSHOT,
	KNIFEKILL
}

enum _:eType
{
	_DMG,
	_HOSTAGE,
	_MOSTDMG,
	_FRAGS,
	_WEAPONDMG,
	_DEFUSED,
	_NODEATH
}

new g_eData[33][eType]

new const g_iMission[][][] =
{
	{
		"Задание 1(Награда: +15 за каждое убийство)",
		"Задание 2(Награда: +1000$ за каждое убийство)",
		"Задание 3(Награда: 120 xp каждый раунд)",
		"Задание 4(Награда: Скорострельный SCOUT + HE)"
	},
	{
		"Убить 2 противников 1 выстрелом",
		"Убить 2 противников 1-ой гранатой",
		"Убить 2 противников с ножа (раунд)",
		"Убить 4 противников с пулемета (раунд)"
	},
	{
		"Не повредить себя (раунд)",
		"Спасти всех (4) заложников (раунд)",
		"Нанести больше всех урона (раунд)",
		"Сделать 7 фрагов (раунд)"
	},
	{
		"Нанести 400 урона с deagle(раунд)",
		"Нанести 700 урона с ak47(раунд)",
		"Нанести 650 урона с m4a1(раунд)",
		"Нанести 600 урона с famas(раунд)"
	},
	{
		"Обезвредить 3 раз бомбу (карта)",
		"Не умирать 3 раунда подряд",
		"Набить 6 HeadShot (раунд)",
		"Убить с ножа 4-ых (раунд)"
	}
}

new Handle:g_hSQLTuple, g_szQuery[2048]

new pCvarSqlHost, pCvarSqlUser, pCvarSqlPwd, pCvarSqlDb
new pCvarHudColor[3], pCvarHudCoord[2], pCvarMinPlayers
new pCvarBonusMoney, pCvarBonusMoneyMax, pCvarBonusHealth, pCvarBonusHealthMax 
new pCvarScoutSpd, pCvarMenu

new g_CacheHudColor[3], Float:g_CacheHudCoord[2]

new g_ShowMenu[33]

new g_Mission[33], g_Bonus[33]

new g_iMaxPlayers

new g_LbzEnable, g_BlockMap
new g_Map[128][32], g_MapNum

public plugin_init() 
{
	register_plugin("LBZ", VERSION, "ill")
	
	register_clcmd("say /lbz", "ClcShowMenu")
	
	register_menu("Lbz Menu", 1023, "lbz_menu")
	
	register_logevent("event_Hostage", 3, "2=Rescued_A_Hostage")
	register_event("HLTV", "event_RoundStart", "a", "1=0", "2=0")
	register_logevent("logevent_RoundEnd", 2, "1=Round_End")
	register_event("TextMsg", "event_RestartGame", "a", "2=#Game_Commencing", "2=#Game_will_restart_in")
	
	RegisterHam(Ham_Killed, "player", "fw_HamKilled")
	RegisterHam(Ham_Spawn, "player", "fw_HamSpawnPost", 1)
	RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
	RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_scout", "fw_PrimaryAttack_Post", 1)
	
	pCvarSqlHost = register_cvar("lbz_sgl_host", "127.0.0.1")
	pCvarSqlUser = register_cvar("lbz_sgl_user", "root")
	pCvarSqlPwd = register_cvar("lbz_sgl_pwd", "vertrigo")
	pCvarSqlDb = register_cvar("lbz_sgl_db", "test")
	
	pCvarHudColor[0] = register_cvar("lbz_hud_color_r", "0")
	pCvarHudColor[1] = register_cvar("lbz_hud_color_g", "255")
	pCvarHudColor[2] = register_cvar("lbz_hud_color_b", "255")
	pCvarHudCoord[0] = register_cvar("lbz_hud_pos_x", "0.02")
	pCvarHudCoord[1] = register_cvar("lbz_hud_pos_y", "0.18")
	
	pCvarMinPlayers = register_cvar("lbz_min_players", "1")
	
	pCvarBonusMoney = register_cvar("lbz_bonus_money", "700")
	pCvarBonusMoneyMax = register_cvar("lbz_bonus_money_max", "16000")
	pCvarBonusHealth = register_cvar("lbz_bonus_health", "15")
	pCvarBonusHealthMax = register_cvar("lbz_bonus_health_max", "105")
	
	pCvarScoutSpd = register_cvar("lbz_bonus_scout_spd", "0.5")

pCvarMenu = register_cvar("lbz_menu", "1")
	
	g_iMaxPlayers = get_maxplayers()
	
	set_task(0.1, "SQL_Init_Connect")
	set_task(0.5, "Cache_Cvars")
	
	check_block_maps()	
}

public plugin_precache() 
{
	new iConfigsDir[64]
	get_configsdir(iConfigsDir, charsmax(iConfigsDir))
	server_cmd("exec %s/lbz.cfg", iConfigsDir)
	
	new iMapList[128], i, iLen
	formatex(iMapList, charsmax(iMapList), "%s/lbz_blockmaps.ini", iConfigsDir)
	if(file_exists(iMapList)) 
	{
		i = 0
		iLen = 0
		while(i < 128 && read_file(iMapList, i, g_Map[g_MapNum], charsmax(g_Map), iLen)) 
		{
			i++
			if(g_Map[g_MapNum][0] == ';' || !iLen) continue
			g_MapNum++
		}
	} 
	else write_file(iMapList, "; Block maps")
}

public client_putinserver(id)
{
	for(new i = 0; i < eType; i++)
	{
		g_eData[id][i] = 0
	}

g_Mission[id] = 0
	g_Bonus[id] = 0
	
	new authid[32]
	get_user_authid(id, authid, charsmax(authid))
	
	formatex(g_szQuery, charsmax(g_szQuery), "SELECT `MISSION` , `BONUS` FROM `lbz_users` WHERE `AUTHID` = '%s'", authid)
	
	new cData[1]
	cData[0] = id
	SQL_ThreadQuery(g_hSQLTuple, "LoadData_QueryHandler", g_szQuery, cData, 1)
}

public LoadData_QueryHandler(iFailState, Handle:hQuery, szError[], iErrnum, cData[], iSize, Float:fQueueTime) 
{
	if(iFailState != TQUERY_SUCCESS) 
	{
		log_amx("LoadData_QueryHandler(): SQL Error #%d - %s", iErrnum, szError)
		return
	}
	new id = cData[0]
	
	if(!is_user_connected(id)) 
	{
		return
	}
	
	if(SQL_NumResults(hQuery))
	{
		g_Mission[id] = SQL_ReadResult(hQuery, 0)
		g_Bonus[id] = SQL_ReadResult(hQuery, 1)
	}
	
	set_task(1.0, "Show_Hud", id, _, _, "b")
}

public bomb_defused(defuser) 
{
	if(!g_LbzEnable || g_BlockMap) return
	
	if(g_Mission[defuser] == DEFUSED)
	{ 
		g_eData[defuser][_DEFUSED]++
		if(g_eData[defuser][_DEFUSED] == 3)
		{
			mission_complite(defuser)
		}
	}
}

public event_RoundStart()
{
	get_game_players() < get_pcvar_num(pCvarMinPlayers) ? (g_LbzEnable = false) : (g_LbzEnable = true)
	
	if(g_BlockMap)
	{
		client_print_color(0, DontChange, "%s На данной карте задания и миссии отключены", TAG)
	}
	else if(!g_LbzEnable)
	{
		client_print_color(0, DontChange, "%s На карте менее %d игроков, задания и миссии не начисляются", TAG, get_pcvar_num(pCvarMinPlayers))
	}
	
	for(new id = 1; id <= g_iMaxPlayers; id++)
	{
		g_eData[id][_DMG] = 0
		g_eData[id][_HOSTAGE] = 0
		g_eData[id][_MOSTDMG] = 0
		g_eData[id][_FRAGS] = 0
		g_eData[id][_HOSTAGE] = 0
		g_eData[id][_WEAPONDMG] = 0
	}
}

public event_RestartGame()
{
	for(new id = 1; id <= g_iMaxPlayers; id++)
	{
		g_eData[id][_NODEATH] = 0
	}
}

public logevent_RoundEnd()
{
	if(!g_LbzEnable || g_BlockMap)
	{
		return
	}
	
	static iBest, id
	iBest = 0
	
	for(id = 1; id <= g_iMaxPlayers; id++)
	{
		if(is_user_connected(id))
		{
			switch(g_Mission[id])
			{
				case NODMG:
				{
					if(!g_eData[id][_DMG])
					{
						mission_complite(id)
					}
				}
				case NODEATH:
				{
					if(is_user_alive(id))
					{
						g_eData[id][_NODEATH]++
						if(g_eData[id][_NODEATH] == 3)
						{
							mission_complite(id)
						}
					}
				}
			}
			
			if(g_eData[id][_MOSTDMG] > g_eData[iBest][_MOSTDMG])
			{
				iBest = id
			}
		}
	}
	
	if(g_Mission[iBest] == MOSTDMG && g_eData[iBest][_MOSTDMG])
	{
		mission_complite(iBest)
	}
}

public event_Hostage(id) 
{
	if(!g_LbzEnable || g_BlockMap) return
	
	new id = get_loguser_index()
	
	if(g_Mission[id] == HOSTAGE)
	{
		g_eData[id][_HOSTAGE]++
		
		if(g_eData[id][_HOSTAGE] == 4)
		{
			mission_complite(id)
		}
	}
}

public fw_HamSpawnPost(id)
{
	if(!g_LbzEnable || g_BlockMap)
		return HAM_IGNORED
	
	if(!is_user_alive(id))
	{
		return HAM_IGNORED
	}
	
	if(g_Bonus[id] >= HEALTH)
	{
		set_user_health(id, 120)
	}
	if(g_Bonus[id] >= SCOUT)
	{
		give_item(id, "weapon_hegrenade")
	}
	
	return HAM_IGNORED
}

public fw_TakeDamage(victim, inflictor, attacker, Float:damage, damage_type) 
{
	if(!g_LbzEnable || g_BlockMap)
		return HAM_IGNORED
	
	if(!is_user_connected(victim) || !is_user_connected(attacker) || victim == attacker)
		return HAM_IGNORED
	
	if(get_user_team(victim) == get_user_team(attacker))
		return HAM_IGNORED
		
	if(g_Mission[victim] == NODMG)
	{
		g_eData[victim][_DMG] += floatround(damage)
	}
	
	switch(g_Mission[attacker])
	{
		case DMG_DGL:
		{
			if(get_user_weapon(attacker) == CSW_DEAGLE)
			{
				g_eData[attacker][_WEAPONDMG] += floatround(damage) 
				if(g_eData[attacker][_WEAPONDMG] >= 400)
				{
					mission_complite(attacker)
					g_eData[attacker][_WEAPONDMG] = 0
				}
			}
		}
		case DMG_AK47:
		{
			if(get_user_weapon(attacker) == CSW_AK47)
			{
				g_eData[attacker][_WEAPONDMG] += floatround(damage) 
				if(g_eData[attacker][_WEAPONDMG] >= 700)
				{
					mission_complite(attacker)
					g_eData[attacker][_WEAPONDMG] = 0
				}
			}
		}
		case DMG_M4A1:
		{
			if(get_user_weapon(attacker) == CSW_M4A1)
			{
				g_eData[attacker][_WEAPONDMG] += floatround(damage) 
				if(g_eData[attacker][_WEAPONDMG] >= 650)
				{
					mission_complite(attacker)
					g_eData[attacker][_WEAPONDMG] = 0
				}
			}
		}
		case DMG_FAMAS:
		{
			if(get_user_weapon(attacker) == CSW_FAMAS)
			{
				g_eData[attacker][_WEAPONDMG] += floatround(damage) 
				if(g_eData[attacker][_WEAPONDMG] >= 600)
				{
					mission_complite(attacker)
					g_eData[attacker][_WEAPONDMG] = 0
				}
			}
		}	
	}
	g_eData[attacker][_MOSTDMG] += floatround(damage)

return HAM_IGNORED	
}
		
public fw_HamKilled(victim, attacker, shouldgib) 
{
	if(!g_LbzEnable || g_BlockMap)
		return HAM_IGNORED
		
	if(!is_user_connected(victim) || !is_user_connected(attacker) || victim == attacker)
		return HAM_IGNORED
	
	static Float:iTime, Float:iKillTime, iKiller
	iTime = get_gametime()
	
	static iWpnName[24]
	
	switch(g_Mission[attacker])
	{
		case DOUBLE_GRENADE:
		{
			get_killer_weapon(attacker, pev(victim, pev_dmg_inflictor), iWpnName, charsmax(iWpnName))
			if(equal(iWpnName, "grenade")) 
			{
				if (iKillTime == iTime && iKiller == attacker) 
				{
					mission_complite(attacker)
				}
				iKillTime = iTime
				iKiller = attacker
			}
		}
		case DOUBLE_WEAPON:
		{
			if (iKillTime == iTime && iKiller == attacker) 
			{
				mission_complite(attacker)
			}
			iKillTime = iTime
			iKiller = attacker
		}
		case KNIFE:
		{
			if(get_user_weapon(attacker) == CSW_KNIFE)
			{
				g_eData[attacker][_FRAGS]++
				if(g_eData[attacker][_FRAGS] == 2)
				{
					mission_complite(attacker)
					g_eData[attacker][_FRAGS] = 0
				}
			}
		}
		case M249:
		{
			if(get_user_weapon(attacker) == CSW_M249)
			{
				g_eData[attacker][_FRAGS]++
				if(g_eData[attacker][_FRAGS] == 4)
				{
					mission_complite(attacker)
					g_eData[attacker][_FRAGS] = 0
				}
			}
		}
		case FRAGS:
		{
			g_eData[attacker][_FRAGS]++ 
			if(g_eData[attacker][_FRAGS] == 7)
			{
				mission_complite(attacker)
				g_eData[attacker][_FRAGS] = 0
			}
		}
		case HEADSHOT:
		{
			static iHS
			iHS = get_pdata_int(victim, 75, 5) == HIT_HEAD ? 1 : 0
			if(iHS)
			{
				g_eData[attacker][_FRAGS]++
				if(g_eData[attacker][_FRAGS] == 6)
				{
					mission_complite(attacker)
					g_eData[attacker][_FRAGS] = 0
				}
			}
		}
		case KNIFEKILL:
		{
			if(get_user_weapon(attacker) == CSW_KNIFE)
			{
				g_eData[attacker][_FRAGS]++
				if(g_eData[attacker][_FRAGS] == 4)
				{
					mission_complite(attacker)
					g_eData[attacker][_FRAGS] = 0
				}
			}
		}
	}
	
	// Reset
	g_eData[victim][_FRAGS] = 0
	g_eData[victim][_WEAPONDMG] = 0
	g_eData[victim][_NODEATH] = 0
	
	// Bonus
	new iMax, iValue
	if(g_Bonus[attacker] >= VAMPIRE)
	{
		iMax = get_pcvar_num(pCvarBonusHealthMax)
		iValue = get_user_health(attacker)
		if(iValue + get_pcvar_num(pCvarBonusHealth) > iMax)
		{
			set_user_health(attacker, iMax)
		}
		else
		{
			set_user_health(attacker, iValue + get_pcvar_num(pCvarBonusHealth))
		}
	}
	if(g_Bonus[attacker] >= MONEY)
	{
		iMax = get_pcvar_num(pCvarBonusMoneyMax)
		iValue = cs_get_user_money(attacker)
		if(iValue + get_pcvar_num(pCvarBonusMoney) > iMax)
		{
			cs_set_user_money(attacker, iMax)
		}
		else
		{
			cs_set_user_money(attacker, iValue + get_pcvar_num(pCvarBonusMoney))
		}
	}
	return HAM_IGNORED
}

public Cache_Cvars()
{
	g_CacheHudColor[0] = get_pcvar_num(pCvarHudColor[0])
	g_CacheHudColor[1] = get_pcvar_num(pCvarHudColor[1])
	g_CacheHudColor[2] = get_pcvar_num(pCvarHudColor[2])
	g_CacheHudCoord[0] = get_pcvar_float(pCvarHudCoord[0])
	g_CacheHudCoord[1] = get_pcvar_float(pCvarHudCoord[1])
}

public Show_Hud(id)
{
	set_hudmessage(g_CacheHudColor[0], g_CacheHudColor[1], g_CacheHudColor[2], g_CacheHudCoord[0], g_CacheHudCoord[1], 0, 0.1, 1.0, 0.05, 0.05)
	show_hudmessage(id, "Введите /lbz^nМиссий выполнено: [%d\16]^nЗаданий выполнено: [%d\4]", g_Mission[id], g_Bonus[id])
}

public ClcShowMenu(id)
{
	if(!get_pcvar_num(pCvarMenu))
	{
		return PLUGIN_HANDLED
	}
	g_ShowMenu[id] = 0
	show_lbz_menu(id)
	
	return PLUGIN_HANDLED
}

public show_lbz_menu(id)
{
	new menu[512], len, i
	new keys = MENU_KEY_0
	
	new iMenu = g_ShowMenu[id]
	
	new iMisNum = g_Mission[id] - (g_Bonus[id] * 4)
	
	if(iMenu)
	{
		len += formatex(menu[len], charsmax(menu) - len, "\y%s^n^n", g_iMission[0][iMenu-1])
	}
	else
	{
		len += formatex(menu[len], charsmax(menu) - len, "\yМеню заданий^n\wТекущее для вас:^n")
		if(g_Mission[id] < 16)
			len += formatex(menu[len], charsmax(menu) - len, "\y%s^n^n", g_iMission[g_Bonus[id]+1][iMisNum])
		else
			len += formatex(menu[len], charsmax(menu) - len, "\rВсе миссии выполнены!^n^n")
			
		keys = MENU_KEY_1|MENU_KEY_2|MENU_KEY_3|MENU_KEY_4|MENU_KEY_0
	}
	
	for(i = 0; i < 4; i++)
	{
		if(iMenu)
		{
			len += formatex(menu[len], charsmax(menu) - len, "\y%d. \w%s^n", i+1, g_iMission[iMenu][i])
		}
		else
		{
			len += formatex(menu[len], charsmax(menu) - len, "\y%d. \w%s%s^n", i+1, g_iMission[iMenu][i], g_Bonus[id] > i ? " \r(выполнено)" : "")
		}
	}

len += formatex(menu[len], charsmax(menu) - len, "^n\y0. \w%s^n", iMenu ? "Назад" : "Выход")
	
	show_menu(id, keys, menu, -1, "Lbz Menu")
}

public lbz_menu(id, key)
{
	switch(key)
	{
		case 9:
		{
			if(g_ShowMenu[id])
			{
				g_ShowMenu[id] = 0
				show_lbz_menu(id)
			}
		}
		default:
		{
			g_ShowMenu[id] = key+1
			show_lbz_menu(id)
		}
	}
}

public fw_PrimaryAttack_Post(Weapon)
{
	new id = get_pdata_cbase(Weapon, 41, 4)

if(pev_valid(id) != 2)
		return HAM_IGNORED
		
	if(g_Bonus[id] >= SCOUT)
	{
		set_pdata_float(Weapon, 46, get_pcvar_float(pCvarScoutSpd), 4)
	}

return HAM_IGNORED
}

mission_complite(id)
{
	new iMisNum = g_Mission[id] - (g_Bonus[id] * 4)

new szName[32]
	get_user_name(id, szName, charsmax(szName))
	
	set_dhudmessage(0, 255, 0, -1.0, -0.25, 2, 0.02, 8.0, 0.03, 0.2)
	show_dhudmessage(id, "Вы выполнили миссию: %s", g_iMission[g_Bonus[id]+1][iMisNum])
	
	client_print_color(0, DontChange, "%s ^1Игрок ^4%s ^1выполнил миссию: ^3%s", TAG, szName, g_iMission[g_Bonus[id]+1][iMisNum])
	
	g_Mission[id]++
	
	if(g_Mission[id] == 4 || g_Mission[id] == 8 || g_Mission[id] == 12 || g_Mission[id] == 16)
	{
		g_Bonus[id]++
	}
	
	new authid[32]
	get_user_authid(id, authid, charsmax(authid))
	
	formatex(g_szQuery, charsmax(g_szQuery),
	"INSERT INTO `lbz_users` SET `AUTHID`='%s', `MISSION`='%d', `BONUS`='%d' ON DUPLICATE KEY UPDATE `MISSION`='%d', `BONUS`='%d'",
	authid, g_Mission[id], g_Bonus[id], g_Mission[id], g_Bonus[id]) 
	
	SQL_ThreadQuery(g_hSQLTuple, "QueryHandler", g_szQuery)
	
	log_to_file("lbz_logs.log", "%s (%s) completed mission %d", szName, authid, g_Mission[id])
}

get_game_players() 
{
	static count, i
	count = 0
	for(i = 1; i <= g_iMaxPlayers; i++) 
	{
		if(is_user_connected(i)) 
		{
			if(get_user_team(i) == 1 || get_user_team(i) == 2)
				count++
		}
	}
	return count
}

public SQL_Init_Connect() 
{
	new iHost[64], iUser[64], iPwd[64], iDB[64]
	
	get_pcvar_string(pCvarSqlHost, iHost, charsmax(iHost))
	get_pcvar_string(pCvarSqlUser, iUser, charsmax(iUser))
	get_pcvar_string(pCvarSqlPwd, iPwd, charsmax(iPwd))
	get_pcvar_string(pCvarSqlDb, iDB, charsmax(iDB))
	
	SQL_SetAffinity("mysql")
	g_hSQLTuple = SQL_MakeDbTuple(iHost, iUser, iPwd, iDB)
	
	SQL_Table()
}

SQL_Table() 
{
	formatex(g_szQuery, charsmax(g_szQuery),"\
	CREATE TABLE IF NOT EXISTS `lbz_users` (\
	`AUTHID` varchar(32) NOT NULL,\
	`MISSION` int(1) NOT NULL,\
	`BONUS` int(1) NOT NULL,\
	PRIMARY KEY (`AUTHID`))")
	
	SQL_ThreadQuery(g_hSQLTuple, "QueryHandler", g_szQuery)
}

public QueryHandler(iFailState, Handle:hQuery, szError[], iErrnum, iData[], iSize, Float:fQueueTime) 
{
	if(iFailState != TQUERY_SUCCESS) 
	{
		log_amx("QueryHandler(): SQL Error #%d - %s", iErrnum, szError)
		return
	}
}

public plugin_end() 
{
	if (g_hSQLTuple) 
	{
		SQL_FreeHandle(g_hSQLTuple)
	}
}

check_block_maps() 
{
	new MapName[64], i
	get_mapname(MapName, charsmax(MapName))
	while(i < g_MapNum)
	{
		if(containi(MapName, g_Map[i++]) != -1) 
		{
			g_BlockMap = true
		}
	}
}

stock get_loguser_index()
{
	new loguser[80], name[32]
	read_logargv(0, loguser, charsmax(loguser))
	parse_loguser(loguser, name, 31)
	return get_user_index(name)
}

stock get_killer_weapon(killer,inflictor,retVar[],retLen) {
	static killer_weapon_name[32]
	killer_weapon_name = "world"

if(pev_valid(killer) && (pev(killer,pev_flags) & FL_CLIENT)) {
		if(pev_valid(inflictor)) {
			if(inflictor == killer) {
				new weapon = get_user_weapon(killer)
				get_weaponname(weapon,killer_weapon_name,31)
			}
			else pev(inflictor,pev_classname,killer_weapon_name,31)
		}
	} else {
		if(pev_valid(killer)) pev(inflictor,pev_classname,killer_weapon_name,31)
		else if(killer == 0) killer_weapon_name = "worldspawn"
	}
	if(equal(killer_weapon_name,"weapon_",7)) copy(killer_weapon_name,31,killer_weapon_name[7])
	else if(equal(killer_weapon_name,"monster_",8))	copy(killer_weapon_name,31,killer_weapon_name[8])
	else if(equal(killer_weapon_name,"func_",5)) copy(killer_weapon_name,31,killer_weapon_name[5])

copy(retVar,retLen,killer_weapon_name)
}

Загрузил FliNe

2019-03-18 20:53:45

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram