	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

[CS 1.6] Private Message

Теги: Скачать плагины csОстальные

Плагин позволяющий общаться на сервере индивидуально с выбранным игроком, есть два варианта, через удобное меню и через команду в чате. По мимо всего при открытии меню Private Message вы увидите последних трёх получателей. Так же присутствует функция блокировки игрока, а Администраторы могут полностью заблокировать отправку им сообщений.

Компилятор: 1.8.3 +ZIP 1087

Команды:

/pm - открыть меню с личными сообщениями

/pm ник сообщение - отправить сообщение через чат (ник с учетом регистра букв)

pmblock, /pmblock - полностью заблокировать личные сообщения (для администраторов)

.sma / .sp

#include <amxmodx>

#pragma semicolon 1

#define PLUGIN_NAME "Private Message"
#define PLUGIN_VERSION "1.0"
#define PLUGIN_AUTHOR "Denzer"

// EN: Prefix in chat
// RU: Префикс в чат
new const PREFIX[] = "[^4PM^1]";

// EN: List of commands to cancel
// RU: Список команд для отмены
new const BLOCK_CMD[] =
{
    "cancel",
    "otmena",
    "отмена"
};

new const g_szLogFile[] = "private_message.log";

new g_iType;
new bool: g_bBlock;
new Float: g_fDelay;
new g_sAccess[24];
new bool: g_bLogging;
new g_iPlayer[MAX_PLAYERS + 1];
new bool: g_bChatBlocked;
new bool: g_bHookSay[MAX_PLAYERS + 1];
new bool: g_bType[MAX_PLAYERS + 1];
new bool: g_bPlayerBlocked[MAX_PLAYERS + 1][MAX_PLAYERS + 1];
new Float: g_fChattingDelay[MAX_PLAYERS + 1];
new Array: g_aIndex[MAX_PLAYERS + 1];

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR);

new pCvar;
    pCvar = create_cvar("pm_type", "1", FCVAR_NONE, "All can write messages each other, 2 - messages can write only: alive to alive, deat for dead, 3 - only to teammates", true, 1.0, true, 3.0);
    bind_pcvar_num(pCvar, g_iType);

pCvar = create_cvar("pm_delay", "2.5", FCVAR_NONE, "Time between messages", true, 0.0, true, 10.0);
    bind_pcvar_float(pCvar, g_fDelay);

pCvar = create_cvar("pm_access", "m", FCVAR_NONE, "Access flag to function of chat blocking");
    bind_pcvar_string(pCvar, g_sAccess, charsmax(g_sAccess));

AutoExecConfig(true, "private_message");

pCvar = create_cvar("pm_block", "1", FCVAR_NONE, "Allows admin to block PM-system", true, 0.0, true, 1.0);
    g_bBlock = bool:get_pcvar_num(pCvar);

pCvar = create_cvar("pm_logging", "1", FCVAR_NONE, "Message logging", true, 0.0, true, 1.0);
    g_bLogging = bool:get_pcvar_num(pCvar);

register_clcmd("say", "CmdSay");
    register_clcmd("say_team", "CmdSay");

for(new i = 0; i < sizeof(BLOCK_CMD); i++)
        register_saycmd(BLOCK_CMD[i], "CmdCancel");

if(g_bBlock)
    {
        register_clcmd("say /pmblock", "CmdMessagesBlock");
        register_clcmd("pmblock", "CmdMessagesBlock");
    }

register_dictionary("private_message.txt");
}

public client_putinserver(id)
{
    g_bHookSay[id] = false;
    g_bType[id] = false;
    g_aIndex[id] = ArrayCreate();
}

public client_disconnected(id)
{
    g_aIndex[id] = Invalid_Array;
    for(new i = 0; i < MAX_PLAYERS; i++)
    {
        if(!g_aIndex[i])
            continue;

new found = ArrayFindValue(g_aIndex[i], id);
        if(found != -1)
        {
            ArrayDeleteItem(g_aIndex[i], found);
        }
    }
    ArrayDestroy(g_aIndex[id]);
}

public CmdSay(id)
{    
    new szArgs[140];
    read_argv(1, szArgs, charsmax(szArgs));
    remove_quotes(szArgs);
    trim(szArgs);

switch(g_bHookSay[id])
    {
        case true:
        {
            new iPlayer = g_iPlayer[id];
            if(!is_user_connected(iPlayer))
                return PLUGIN_CONTINUE;
            
            replace_wrong_simbols(szArgs);
            g_bHookSay[id] = false;
            g_fChattingDelay[id] = get_gametime() + g_fDelay;
            client_print_color(id, print_team_default, "%L", LANG_SERVER, "PM_MESSAGE_TO", iPlayer, szArgs);
            client_print_color(iPlayer, print_team_default, "%L", LANG_SERVER, "PM_MESSAGE_FROM", id, szArgs);

if(g_bLogging)
                log_to_file(g_szLogFile, "%L", LANG_SERVER, "PM_WROTE_PLAYER", id, iPlayer, szArgs);
            
            return PLUGIN_HANDLED;
        }
        case false:
        {
            new szName[32], szSaveArgs[140];
            copy(szSaveArgs, charsmax(szSaveArgs), szArgs);
            parse(szArgs, \
                szArgs, charsmax(szArgs), \
                szName, charsmax(szName));

if(equali(szArgs, "/pm"))
            {
                if(!szName[0])
                {
                    CmdMain(id);
                    return PLUGIN_HANDLED;
                }

new found_id = find_player("b", szName);
                if(found_id)
                {
                    if(id == found_id || is_user_bot(found_id) || is_user_hltv(found_id))
                        return PLUGIN_HANDLED;

if(g_fChattingDelay[id] > get_gametime())
                    {
                        client_print_color(id, print_team_default, "%s %L", PREFIX, LANG_SERVER, "PM_FLOOD");
                        return PLUGIN_HANDLED;
                    }
                    
                    new szReplace[64];
                    g_fChattingDelay[id] = get_gametime() + g_fDelay;

formatex(szReplace, charsmax(szReplace), "/pm %s ", szName);
                    replace(szSaveArgs, sizeof(szSaveArgs), szReplace, "");
                    replace_wrong_simbols(szSaveArgs);

client_print_color(id, print_team_default, "%L", LANG_SERVER, "PM_MESSAGE_TO", found_id, szSaveArgs);
                    client_print_color(found_id, print_team_default, "%L", LANG_SERVER, "PM_MESSAGE_FROM", id, szSaveArgs);

ArrayPushCell(g_aIndex[id], found_id);
                    if(ArraySize(g_aIndex[id]) > 3)
                    {
                        ArrayDeleteItem(g_aIndex[id], 0);
                    }

if(g_bLogging)
                        log_to_file(g_szLogFile, "%L", LANG_SERVER, "PM_WROTE_PLAYER", id, found_id, szArgs);

return PLUGIN_HANDLED;
                }
                else
                {
                    CmdMain(id);
                    return PLUGIN_HANDLED;
                }
            }
        }
    }
    return PLUGIN_CONTINUE;
}

public CmdCancel(id)
{
    if(!g_bHookSay[id])
        return PLUGIN_HANDLED;
    
    g_bHookSay[id] = false;
    client_print_color(id, print_team_default, "%s %L", PREFIX, LANG_SERVER, "PM_CANCEL");
    return PLUGIN_HANDLED;
}

public CmdMessagesBlock(id)
{        
    if(~get_user_flags(id) & read_flags(g_sAccess))
        return PLUGIN_HANDLED;

g_bChatBlocked = !g_bChatBlocked;
    client_print_color(0, print_team_default, "%s %L", PREFIX, LANG_SERVER, "PM_BLOCKED_ADMIN", id, LANG_SERVER, g_bChatBlocked ? "PM_BLOCKED_FOR" : "PM_BLOCKED_COUNT");
    return PLUGIN_CONTINUE;
}

public CmdMain(id)
{
    new menu = menu_create(fmt("%L", LANG_SERVER, "PM_TITLE_MESSAGES"), "MainHandler");

menu_additem(menu, fmt("%L", LANG_SERVER, "PM_WRITE"));
    menu_additem(menu, fmt("%L", LANG_SERVER, "PM_BLOCK"));

menu_addtext2(menu, ArraySize(g_aIndex[id]) ? fmt("%L", LANG_SERVER, "PM_RECIPIENT") : fmt("%L", LANG_SERVER, "PM_RECIPIENT_NONE"));

if(ArraySize(g_aIndex[id]))
    {
        new save_index[MAX_PLAYERS + 1][MAX_PLAYERS + 1];
        new szPlayer[10];
        for(new i = 0; i < ArraySize(g_aIndex[id]); i++)
        {
            new get = ArrayGetCell(g_aIndex[id], i);
            if(save_index[id][get] == get || !is_user_connected(get))
                continue;

num_to_str(get, szPlayer, charsmax(szPlayer));
            menu_additem(menu, fmt("%n", get), szPlayer);
            save_index[id][get] = get;
        }
    }

menu_setprop(menu, MPROP_NEXTNAME, fmt("%L", LANG_SERVER, "PM_NEXT"));
    menu_setprop(menu, MPROP_BACKNAME, fmt("%L", LANG_SERVER, "PM_BACK"));
    menu_setprop(menu, MPROP_EXITNAME, fmt("%L", LANG_SERVER, "PM_EXIT"));
    menu_setprop(menu, MPROP_NUMBER_COLOR, "\y");

menu_display(id, menu, 0);
    return PLUGIN_HANDLED;
}

public MainHandler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    
    if(g_bChatBlocked)
    {
        client_print_color(id, print_team_default, "%s %L", PREFIX, LANG_SERVER, "PM_BLOCKED");
        return PLUGIN_HANDLED;
    }
    
    new s_Data[6], s_Name[64], i_Access, i_Callback;
    menu_item_getinfo(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback);
    new tempid = str_to_num(s_Data);
    new iPlayer = g_iPlayer[id] = tempid;

switch(item)
    {
        case 0:
            CmdSend(id);
        case 1:
            CmdBlock(id);
        case 2:
        {
            g_bType[id] = !g_bType[id];
            CmdMain(id);
        }
        default:
        {
            if(!ArraySize(g_aIndex[id]))
                return PLUGIN_HANDLED;

if(g_fChattingDelay[id] > get_gametime())
            {
                client_print_color(id, print_team_default, "%s %L", PREFIX, LANG_SERVER, "PM_FLOOD");
                return PLUGIN_HANDLED;
            }

if(g_bPlayerBlocked[iPlayer][id])
            {
                client_print_color(id, print_team_default, "%s %L", PREFIX, LANG_SERVER, "PM_PLAYER_BLOCKED", iPlayer);
                return PLUGIN_HANDLED;
            }
            g_bHookSay[id] = true;
            client_print_color(id, print_team_default, "%s %L", PREFIX, LANG_SERVER, "PM_OPEN_CHAT");
        }
    }
    menu_destroy(menu);
    return PLUGIN_HANDLED;
}

CmdSend(id, page = 0)
{
    new iPlayers[MAX_PLAYERS], iNum, szPlayer[10], iPlayer;
    get_players(iPlayers, iNum, "ch");

new menu = menu_create(fmt("%L", LANG_SERVER, "PM_TITLE_WRITE"), "SendHandler");

for (new i; i < iNum; i++)
    {
        iPlayer = iPlayers[i];

if(id == iPlayer)
            continue;

num_to_str(iPlayer, szPlayer, charsmax(szPlayer));

switch(g_iType)
        {
            case 1: menu_additem(menu, fmt("%n", iPlayer), szPlayer);
            case 2:
            {
                if(is_user_alive(id) == is_user_alive(iPlayer))
                    menu_additem(menu, fmt("%n", iPlayer), szPlayer);
            }
            case 3:
            {
                if(get_user_team(id) == get_user_team(iPlayer))
                    menu_additem(menu, fmt("%n", iPlayer), szPlayer);
            }
        }
    }

menu_display(id, menu, page);
    return PLUGIN_CONTINUE;
}

public SendHandler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        CmdMain(id);
        return PLUGIN_HANDLED;
    }

new s_Data[6], s_Name[64], i_Access, i_Callback;
    menu_item_getinfo(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback);

new tempid = str_to_num(s_Data);
    new iPlayer = g_iPlayer[id] = tempid;

if(g_fChattingDelay[id] > get_gametime())
    {
        client_print_color(id, print_team_default, "%s %L", PREFIX, LANG_SERVER, "PM_FLOOD");
        return PLUGIN_HANDLED;
    }

if(g_bPlayerBlocked[iPlayer][id])
    {
        client_print_color(id, print_team_default, "%s %L", PREFIX, LANG_SERVER, "PM_PLAYER_BLOCKED", iPlayer);
        return PLUGIN_HANDLED;
    }
    
    client_print_color(id, print_team_default, "%s %L", PREFIX, LANG_SERVER, "PM_OPEN_CHAT");
    g_bHookSay[id] = true;

ArrayPushCell(g_aIndex[id], iPlayer);
    if(ArraySize(g_aIndex[id]) > 3)
    {
        ArrayDeleteItem(g_aIndex[id], 0);
    }
    CmdSend(id, item / 7);

menu_destroy(menu);
    return PLUGIN_HANDLED;
}

CmdBlock(id, page = 0)
{
    new iPlayers[MAX_PLAYERS], iNum, szPlayer[10], iPlayer;
    get_players(iPlayers, iNum, "ch");

new menu = menu_create(fmt("%L", LANG_SERVER, "PM_TITLE_BLOCK"), "BlockHandler");

for(new i; i < iNum; i++)
    {
        iPlayer = iPlayers[i];

if(id == iPlayer)
            continue;

num_to_str(iPlayer, szPlayer, charsmax(szPlayer));

if(g_bPlayerBlocked[id][iPlayer])
            menu_additem(menu, fmt("%n %L", iPlayer, LANG_SERVER, "PM_MENU_BLOCKED"), szPlayer);
        else
            menu_additem(menu, fmt("%n", iPlayer), szPlayer);
    }

menu_display(id, menu, page);
    return PLUGIN_CONTINUE;
}

public BlockHandler(id, menu, item)
{
    if(item == MENU_EXIT)
    {
        CmdMain(id);
        return PLUGIN_HANDLED;
    }

new s_Data[6], s_Name[64], i_Access, i_Callback;
    menu_item_getinfo(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback);

new tempid = str_to_num(s_Data);
    new iPlayer = g_iPlayer[id] = tempid;

g_bPlayerBlocked[id][iPlayer] = !g_bPlayerBlocked[id][iPlayer];
    CmdBlock(id, item / 7);

menu_destroy(menu);
    return PLUGIN_HANDLED;
}

// mx?!
stock register_saycmd(const szSayCmd[], szFunc[])
{
    new const szPrefix[][] = { "say /", "say_team /", "say .", "say_team ." };
    for(new i; i < sizeof(szPrefix); i++)
        register_clcmd(fmt("%s%s", szPrefix[i], szSayCmd), szFunc);
}

stock replace_wrong_simbols(string[])
{
    new len = 0;
    for(new i; string[i] != EOS; i++)
    {
        if(string[i] == '%' || string[i] == '#' || 0x01 <= string[i] <= 0x04)
            continue;
        string[len++] = string[i];
    }
    string[len] = EOS;
}

Загрузил FliNe

2020-01-26 21:16:46

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram