	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

[CS 1.6] Stop SpamBots

Теги: Скачать плагины csСерверные

Плагин ограничивает новичкам доступ к чату, микрофону, и спрею до ввода в чат заданной команды. Команду необходимо ввести один раз, и далее метка игрока записывается в хранилище (по SteamID). Имеется поддержка динамической команды разблокировки.

Компилятор: 1.8.3 Multibild +ZIP 1002

Команды:

say /unlock - разблокировать чат, микрофон, и спрей

.sma / .sp

new const PLUGIN_VERSION[] = "0.3"

#include <amxmodx>
#include <nvault>
#include <time>

#tryinclude <reapi>

#if !defined _reapi_included
	#include <fakemeta>
	#include <engine>
	#define _SEND_AUDIO func_SendAudio
#else
	#define _SEND_AUDIO rg_send_audio
#endif

#if AMXX_VERSION_NUM < 183
	#include <colorchat>
	#define MAX_PLAYERS 32
	#define client_disconnected client_disconnect
#endif

#define chx charsmax

new const SOUND__ERROR[] = "buttons/button2.wav"
new const SOUND__BLIP2[] = "buttons/blip2.wav"

const IMPULSE__SPRAY = 201

enum {
	HAS_AUTH,
	IS_CONNECTED,
	IS_VERIFIED
}

new g_hVault, g_szAuthID[24], g_iPlayerFlags[MAX_PLAYERS + 1], g_szBuffer[32]
stock g_msgSendAudio, g_szUnlockWord[MAX_PLAYERS + 1][WORD_LEN + 1]

/* -------------------- */

public plugin_init() {
	register_plugin("Stop SpamBots [Chat]", PLUGIN_VERSION, "mx?!")

register_dictionary("stop_spambots.txt")

g_hVault = nvault_open("stop_spambots")

if(g_hVault == INVALID_HANDLE) {
		pause("ad")
		return
	}

nvault_prune(g_hVault, 0, get_systime() - (PRUNE_DAYS * SECONDS_IN_DAY))

#if defined CONST_UNLOCK_CMD
	formatex(g_szBuffer, chx(g_szBuffer), "say %s", CONST_UNLOCK_CMD)
	register_clcmd(g_szBuffer, "clcmd_Unlock")
	formatex(g_szBuffer, chx(g_szBuffer), "say_team %s", CONST_UNLOCK_CMD)
	register_clcmd(g_szBuffer, "clcmd_Unlock")
#endif

register_clcmd("say", "func_HookSay")
	register_clcmd("say_team", "func_HookSay")

#if defined _reapi_included
	RegisterHookChain(RG_CSGameRules_CanPlayerHearPlayer, "CanPlayerHearPlayer_Pre")
	RegisterHookChain(RG_CBasePlayer_ImpulseCommands, "OnImpulseCommands_Pre")
#else
	register_forward(FM_Voice_SetClientListening, "OnSetClientListening_Pre")
	register_impulse(IMPULSE__SPRAY, "hook_Spray")
	g_msgSendAudio = get_user_msgid("SendAudio")
#endif
}

/* -------------------- */

#if defined _reapi_included
	public CanPlayerHearPlayer_Pre(iReceiver, iSender) {
		if(!CheckFlag(iSender, IS_VERIFIED)) {
			SetHookChainReturn(ATYPE_INTEGER, false)
			return HC_SUPERCEDE
		}

return HC_CONTINUE
	}
#else
	public OnSetClientListening_Pre(iReceiver, iSender, bool:bCanHear) {
		if(!CheckFlag(iSender, IS_VERIFIED)) {
			engfunc(EngFunc_SetClientListening, iReceiver, iSender, false)
			return FMRES_SUPERCEDE
		}

return FMRES_IGNORED
	}
#endif

/* -------------------- */

public func_HookSay(pPlayer) {
	if(CheckFlag(pPlayer, IS_VERIFIED)) {
		return PLUGIN_CONTINUE
	}

#if !defined CONST_UNLOCK_CMD
	read_args(g_szBuffer, chx(g_szBuffer))
	remove_quotes(g_szBuffer)

if(equali(g_szBuffer, g_szUnlockWord[pPlayer])) {
		return func_Unlock(pPlayer)
	}
#endif

_SEND_AUDIO(pPlayer, SOUND__ERROR)
#if defined CONST_UNLOCK_CMD
	client_print_color(pPlayer, print_team_red, "%L", pPlayer, "SSB__BLOCK_INFO", CONST_UNLOCK_CMD)
#else
	client_print_color(pPlayer, print_team_red, "%L", pPlayer, "SSB__BLOCK_INFO", g_szUnlockWord[pPlayer])
#endif
	return PLUGIN_HANDLED
}

/* -------------------- */

#if defined _reapi_included
	public OnImpulseCommands_Pre(pPlayer) {
		if(CheckFlag(pPlayer, IS_VERIFIED) || get_entvar(pPlayer, var_impulse) != IMPULSE__SPRAY) {
			return HC_CONTINUE
		}

return HC_SUPERCEDE
	}
#else
	public hook_Spray(pPlayer) {
		if(CheckFlag(pPlayer, IS_VERIFIED)) {
			return PLUGIN_CONTINUE
		}

return PLUGIN_HANDLED
	}
#endif

/* -------------------- */

#if defined CONST_UNLOCK_CMD
	public clcmd_Unlock(pPlayer) {
		if(!CheckFlag(pPlayer, IS_VERIFIED)) {
			return func_Unlock(pPlayer)
		}

_SEND_AUDIO(pPlayer, SOUND__ERROR)
		client_print_color(pPlayer, print_team_red, "%L", pPlayer, "SSB__ALREADY")
		return PLUGIN_HANDLED
	}
#endif

/* -------------------- */

stock func_Unlock(pPlayer) {
	SetFlag(pPlayer, IS_VERIFIED)
	get_user_authid(pPlayer, g_szAuthID, chx(g_szAuthID))
	nvault_set(g_hVault, g_szAuthID, "1")
	_SEND_AUDIO(pPlayer, SOUND__BLIP2)
	client_print_color(pPlayer, print_team_default, "%L", pPlayer, "SSB__UNLOCKED")
	return PLUGIN_HANDLED
}

/* -------------------- */

public client_authorized(pPlayer) {
	SetFlag(pPlayer, HAS_AUTH)

if(CheckFlag(pPlayer, IS_CONNECTED)) {
		func_AgregatePlayer(pPlayer)
	}
}

/* -------------------- */

public client_putinserver(pPlayer) {
	SetFlag(pPlayer, IS_CONNECTED)

if(CheckFlag(pPlayer, HAS_AUTH)) {
		func_AgregatePlayer(pPlayer)
	}
}

/* -------------------- */

stock func_AgregatePlayer(pPlayer) {
	get_user_authid(pPlayer, g_szAuthID, chx(g_szAuthID))

if(!nvault_get(g_hVault, g_szAuthID)) {
	#if !defined CONST_UNLOCK_CMD
		for(new i; i < WORD_LEN; i++) {
			g_szUnlockWord[pPlayer][i] = CHARS_TABLE[random_num(0, sizeof(CHARS_TABLE) - 1)]
		}
	#endif
		return
	}

SetFlag(pPlayer, IS_VERIFIED)
	nvault_touch(g_hVault, g_szAuthID)
}

/* -------------------- */

public client_disconnected(pPlayer) {
	g_iPlayerFlags[pPlayer] = 0
}

/* -------------------- */

stock func_SendAudio(pPlayer, const szSample[]) {
	message_begin(MSG_ONE_UNRELIABLE, g_msgSendAudio, .player = pPlayer)
	write_byte(pPlayer)
	write_string(szSample)
	write_short(PITCH_NORM)
	message_end()
}

/* -------------------- */

public plugin_end() {
	nvault_close(g_hVault)
}

/* -------------------- */

stock SetFlag(id, iFlag) (g_iPlayerFlags[id] |= (1 << iFlag))
stock ClearFlag(id, iFlag) (g_iPlayerFlags[id] &= ~(1 << iFlag))
stock CheckFlag(id, iFlag) return (g_iPlayerFlags[id] & (1 << iFlag))

Загрузил FliNe

2019-02-11 19:28:20

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram