	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

[CS 1.6][ZP] Addon Ammo Box

Теги: Скачать плагины csОстальные

Плагин добавляет в игру ящик с патронами, который можно расставлять по картам, как вам угодно. У каждого ящика патрон есть свой лимит, а именно 500 шт. патрон в одном ящике. Чтобы взять патроны, надо достать оружие, для которого вы хотите брать патроны и зажать кнопку Е, после чего раз в пол секунды вам будут давать патроны по 1 магазину. Данный плагин работает как и с дефолтными оружиями, так и с кастомными.

Компилятор: 1.8.3 Multibild +ZIP 764

Команды:

open_ammobox_menu - вводить в консоль

.sma / .sp

#include <amxmodx>
#include <amxmisc>
#include <fakemeta_util>
#include <hamsandwich>
#include <zombieplague>
#include <dhudmessage>

#define pev_ammo pev_iuser3 // Сколько патрон осталось

#define PDATA_SAFE 2
#define MAX_CLIENTS 32
#define TASKID_AMMOBOX_HUD 3800

stock MAXBPAMMO[ ] = // Сколько максимум выдавать патрон для стандартных пушек
{
	-1, 52, -1, 90, 1, 70, 1, 100, 90, 1, // n, p228, n, scout, n, xm1014, n, mac10, aug, n
	120, 100, 100, 90, 90, 90, 100, 120, // elite, fiveseven, ump45, sg550, galil, famas, usp, glock
	50, 120, 200, 80, 180, 120, 90, 2, // awp, mp5navy, m249, m3, m4a1, tmp, g3sg1, n
	70, 120, 180, -1, 100 // deagle, sg552, ak47, n, p90
};

stock OFFSET_AMMO[ ] =
{
	0, 385, 0, 378, 0, 381, 0, 382,
	380, 0, 386, 383, 382, 380, 380, 380,
	382, 386, 377, 386, 379, 381, 380, 386,
	378, 0, 384, 380, 378, 0, 383
};

stock BUYAMMO[ ] =
{
	-1, 13, -1, 30, -1, 8, -1, 12,
	30, -1, 30, 50, 12, 30, 30, 30,
	12, 30, 10, 30, 30, 8, 30, 30,
	30, -1, 7, 30, 30, -1, 50
};

stock AMMOTYPE[ ][ ] =
{
	"", "357sig", "", "762nato", "", "buckshot", "", "45acp",
	"556nato", "", "9mm", "57mm", "45acp", "556nato", "556nato", "556nato",
	"45acp", "9mm", "338magnum", "9mm", "556natobox", "buckshot", "556nato", "9mm",
	"762nato", "", "50ae", "556nato", "762nato", "", "57mm"
};

#define linux_diff_weapon 4
#define linux_diff_player 5
#define m_iId 43
#define m_iMenu 205
#define m_pActiveItem 373

new const CHAT_PREFIX[] = "!g[X|Ammo Box]";
new const ENTITY_REFERENCE[] = "info_target";
new const ENTITY_AMMOBOX_CLASSNAME[] = "ent_xammobox";
new const ENTITY_AMMOBOX_MODEL[] = "models/x/bg_ammobox_group.mdl"; // Модель ящика
const ENTITY_AMMOBOX_MAX_AMMO = 500; // Сколько максимально патрон в ящике
const DISTANCE_FOR_GETTING_AMMO = 100; // Дистанция, чтобы получить патроны
const Float: AMMO_GETTING_DELAY = 0.5; // Задержка получения патрон
const Float: SHOW_AMMOBOX_HUD_DISTANCE = 150.0; // Дистанция, с которой виден HUD ящика

new gl_fwAmmoBuyPre;

new gl_iAct = 0,
	gl_iAmmoBox_Count,
	gl_iForwardResult,
	gl_iItem_MaxClip[MAX_CLIENTS + 1],
	gl_iItem_MaxAmmo[MAX_CLIENTS + 1],
	gl_iszAllocString_InfoTarget;

new gl_szMapFile_AmmoBoxes[128];

new Float: gl_flGetAmmoDelay[MAX_CLIENTS + 1],
	Float: gl_flBias = 0.5;

public plugin_init()
{
	register_plugin("[ZP] Addon: Ammo Box", "1.1 | 2019", "xUnicorn");

register_event("HLTV", "EV_RoundStart", "a", "1=0", "2=0");

register_forward(FM_PlayerPreThink, "FM_Hook_PlayerPreThink_Pre", false);

register_clcmd("open_ammobox_menu", "Command__AmmoBoxMenu")

register_menucmd(register_menuid("Menu_AmmoBox"), 1023, "MenuAmmoBox_Handler");
	register_menucmd(register_menuid("Menu_Settings"), 1023, "MenuSettings_Handler");
}

public plugin_precache()
{
	// Register forwards
	gl_fwAmmoBuyPre = CreateMultiForward("zp_weapon_buyammo", ET_CONTINUE, FP_CELL, FP_CELL);

// Precache models
	engfunc(EngFunc_PrecacheModel, ENTITY_AMMOBOX_MODEL);

// Precache sounds
	engfunc(EngFunc_PrecacheSound, "items/9mmclip1.wav");

// Other
	gl_iszAllocString_InfoTarget = engfunc(EngFunc_AllocString, ENTITY_REFERENCE);
}

public plugin_cfg()
{
	set_task(random_float(1.0, 3.0), "load_ammoboxes");
}

public plugin_natives()
{
	register_native("zp_set_item_max_clip", "_native_set_item_max_clip", 1);
	register_native("zp_set_item_max_ammo", "_native_set_item_max_ammo", 1);
}

public _native_set_item_max_clip(iPlayer, iValue) gl_iItem_MaxClip[iPlayer] = iValue;
public _native_set_item_max_ammo(iPlayer, iValue) gl_iItem_MaxAmmo[iPlayer] = iValue;

// [ Events ]
public EV_RoundStart()
{
	refill_ammobox();
}

// [ Fakemeta ]
public FM_Hook_PlayerPreThink_Pre(iPlayer)
{
	if(!is_user_alive(iPlayer) || zp_get_user_zombie(iPlayer) || zp_get_user_survivor(iPlayer)) return FMRES_IGNORED;

new iEntity, iDummy; get_user_aiming(iPlayer, iEntity, iDummy, DISTANCE_FOR_GETTING_AMMO);
	if(!pev_valid(iEntity)) return FMRES_IGNORED;

new szClassName[32]; pev(iEntity, pev_classname, szClassName, charsmax(szClassName));
	if(equal(szClassName, ENTITY_AMMOBOX_CLASSNAME))
	{
		new iButton = pev(iPlayer, pev_button);
		if(iButton & IN_USE)
		{
			new Float: flGameTime = get_gametime();
			if(gl_flGetAmmoDelay[iPlayer] <= flGameTime)
			{
				Player_FillAmmo(iEntity, iPlayer);
				gl_flGetAmmoDelay[iPlayer] = flGameTime + AMMO_GETTING_DELAY;
			}
		}
	}

return FMRES_IGNORED;
}

// [ AMXX ]
public client_putinserver(iPlayer)
{
	set_task(1.0, "CTask__AmmoBox_Hud", TASKID_AMMOBOX_HUD + iPlayer, _, _, "b");
}

public client_disconnect(iPlayer)
{
	remove_task(TASKID_AMMOBOX_HUD + iPlayer);
}

public CTask__AmmoBox_Hud(iTask)
{
	new iPlayer = iTask - TASKID_AMMOBOX_HUD;
	if(!is_user_connected(iPlayer))
	{
		remove_task(iTask);
		return;
	}

new iEntity, iDummy; get_user_aiming(iPlayer, iEntity, iDummy, 150);
	new szClassName[32]; pev(iEntity, pev_classname, szClassName, charsmax(szClassName));
	if(is_user_alive(iPlayer) && !zp_get_user_zombie(iPlayer) && !zp_get_user_survivor(iPlayer) &&
		pev_valid(iEntity) && equal(szClassName, ENTITY_AMMOBOX_CLASSNAME))
	{
		new iColor[3], iClipRemained = pev(iEntity, pev_ammo);
		if(iClipRemained) iColor = { 63, 255, 79 };
		else iColor = { 255, 0, 0 };

set_dhudmessage(iColor[0], iColor[1], iColor[2], -1.0, 0.675, 1, 6.0, 1.1, 0.0, 0.0);
		show_dhudmessage(iPlayer, "[ Ящик с патронами ]^nОсталось: %i/%i пт.", iClipRemained, ENTITY_AMMOBOX_MAX_AMMO);
	}
}

public Command__AmmoBoxMenu(iPlayer)
{
	if(!is_user_alive(iPlayer)) return PLUGIN_HANDLED;
	MenuAmmoBox_Show(iPlayer);

return PLUGIN_HANDLED;
}

public MenuAmmoBox_Show(iPlayer)
{
	if(!is_user_alive(iPlayer) || ~get_user_flags(iPlayer) & ADMIN_BAN) return;

new szMenu[512], iKeys = MENU_KEY_0;
	new iLen = 0;

new szMapName[64]; get_mapname(szMapName, charsmax(szMapName));

iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\
		\yМеню создания ящика с патронами^n\
		\dКарта: \w%s \d| Ящиков: \w%i^n^n", szMapName, gl_iAmmoBox_Count);

iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y1. \wПоставить ящик^n");
	iKeys += MENU_KEY_1;

iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y2. \wУдалить ящик^n");
	iKeys += MENU_KEY_2;

iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y3. \wНастроить ящик^n");
	iKeys += MENU_KEY_3;

iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n\y8. \wПополнить запасы^n");
	iKeys += MENU_KEY_8;

iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y9. \wСохранить^n");
	iKeys += MENU_KEY_9;

iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n\y0. \wВыход");

if(pev_valid(iPlayer) == PDATA_SAFE)
		set_pdata_int(iPlayer, m_iMenu, 0, linux_diff_player);
	
	show_menu(iPlayer, iKeys, szMenu, -1, "Menu_AmmoBox");

return;
}

public MenuAmmoBox_Handler(iPlayer, iMenuKey)
{
	if(!is_user_alive(iPlayer) || ~get_user_flags(iPlayer) & ADMIN_BAN) return;

switch(iMenuKey)
	{
		case 0:
		{
			new Float: vecOrigin[3]; fm_get_aim_origin(iPlayer, vecOrigin);
			new Float: vecAngles[3];
			CreateAmmoBox(vecOrigin, vecAngles);
			gl_iAmmoBox_Count++;

UTIL_ColorChat(iPlayer, "%s !yВы успешно добавили ящик!", CHAT_PREFIX);
			MenuAmmoBox_Show(iPlayer);
		}
		case 1:
		{
			MenuAmmoBox_Show(iPlayer);

new iEntity, iDummy; get_user_aiming(iPlayer, iEntity, iDummy);
			if(!pev_valid(iEntity)) return;

new szClassName[32]; pev(iEntity, pev_classname, szClassName, charsmax(szClassName));
			if(equal(szClassName, ENTITY_AMMOBOX_CLASSNAME))
			{
				set_pev(iEntity, pev_flags, FL_KILLME);
				gl_iAmmoBox_Count--;

UTIL_ColorChat(iPlayer, "%s !yВы успешно удалили ящик!", CHAT_PREFIX);
			}

MenuAmmoBox_Show(iPlayer);
		}
		case 2:
		{
			UTIL_DestroyMenu(iPlayer);
			MenuSettings_Show(iPlayer);
		}
		case 7:
		{
			refill_ammobox();

UTIL_ColorChat(iPlayer, "%s !yВсе ящики вновь заполнены!", CHAT_PREFIX);
			MenuAmmoBox_Show(iPlayer);
		}
		case 8:
		{
			save_ammoboxes();

UTIL_ColorChat(iPlayer, "%s !yВсе ящики на карте были сохранены!", CHAT_PREFIX);
			MenuAmmoBox_Show(iPlayer);
		}
	}

return;
}

public MenuSettings_Show(iPlayer)
{
	if(!is_user_alive(iPlayer) || ~get_user_flags(iPlayer) & ADMIN_BAN) return;

new szAct[512], szMenu[512], iKeys = MENU_KEY_0;
	new iLen = 0;

iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\yМеню настроек ящика^n^n");

iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y1. \wВыполнить действие^n");
	iKeys += MENU_KEY_1;

switch(gl_iAct)
	{
		case 0: formatex(szAct, charsmax(szAct), "Поднимать");
		case 1: formatex(szAct, charsmax(szAct), "Отпускать");
		case 2: formatex(szAct, charsmax(szAct), "Повернуть по оси \dX\y");
		case 3: formatex(szAct, charsmax(szAct), "Повернуть по оси \dY\y");
		case 4: formatex(szAct, charsmax(szAct), "Повернуть по оси \dZ\y");
	}
	iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y2. \wДействие \y[%s]^n", szAct);
	iKeys += MENU_KEY_2;

iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "\y3. \wСмещение \y[%.1f]^n", gl_flBias);
	iKeys += MENU_KEY_3;

iLen += formatex(szMenu[iLen], charsmax(szMenu) - iLen, "^n\y0. \wНазад");

if(pev_valid(iPlayer) == PDATA_SAFE)
		set_pdata_int(iPlayer, m_iMenu, 0, linux_diff_player);
	
	show_menu(iPlayer, iKeys, szMenu, -1, "Menu_Settings");

return;
}

public MenuSettings_Handler(iPlayer, iMenuKey)
{
	if(!is_user_alive(iPlayer) || ~get_user_flags(iPlayer) & ADMIN_BAN) return;

switch(iMenuKey)
	{
		case 0:
		{
			MenuSettings_Show(iPlayer);

new iEntity, iDummy; get_user_aiming(iPlayer, iEntity, iDummy);
			if(!pev_valid(iEntity)) return;

new szClassName[32]; pev(iEntity, pev_classname, szClassName, charsmax(szClassName));
			if(!equal(szClassName, ENTITY_AMMOBOX_CLASSNAME)) return;

if(0 <= gl_iAct <= 1) // Поднять/Отпустить
			{
				new Float: vecOrigin[3]; pev(iEntity, pev_origin, vecOrigin);
				if(gl_iAct) vecOrigin[2] -= gl_flBias;
				else vecOrigin[2] += gl_flBias;
				set_pev(iEntity, pev_origin, vecOrigin);
			}

if(2 <= gl_iAct <= 4) // Повернуть XYZ
			{
				new Float: vecAngles[3]; pev(iEntity, pev_angles, vecAngles);
				if(vecAngles[gl_iAct - 2] >= (360.0 - gl_flBias))
					vecAngles[gl_iAct - 2] = 0.0;
				else vecAngles[gl_iAct - 2] += gl_flBias;
				set_pev(iEntity, pev_angles, vecAngles);
			}
		}
		case 1:
		{
			if(gl_iAct == 4) gl_iAct = 0;
			else gl_iAct++;

MenuSettings_Show(iPlayer);
		}
		case 2:
		{
			switch(gl_flBias)
			{
				case 0.5: gl_flBias = 1.0;
				case 1.0: gl_flBias = 15.0;
				case 15.0: gl_flBias = -0.5;
				case -0.5: gl_flBias = -1.0;
				case -1.0: gl_flBias = -15.0;
				case -15.0: gl_flBias = 0.5;
			}

MenuSettings_Show(iPlayer);
		}
		case 9:
		{
			UTIL_DestroyMenu(iPlayer);
			MenuAmmoBox_Show(iPlayer);
		}
	}

return;
}

public Player_FillAmmo(iEntity, iPlayer)
{
	if(!is_user_alive(iPlayer) || zp_get_user_zombie(iPlayer) || zp_get_user_survivor(iPlayer)) return;

new iClipRemained = pev(iEntity, pev_ammo);
	if(iClipRemained <= 0) return;

new iItem = get_pdata_cbase(iPlayer, m_pActiveItem, linux_diff_player);
	new iId = get_pdata_int(iItem, m_iId, linux_diff_weapon);
	new iCurrentAmmo = get_pdata_int(iPlayer, OFFSET_AMMO[iId], linux_diff_player);
	new iBuyAmmo, iMaxAmmo;

if(pev(iItem, pev_impulse) == 0) // Дефолтные стволы
	{
		iMaxAmmo = MAXBPAMMO[iId];
		if(iCurrentAmmo >= iMaxAmmo) return;

if(iClipRemained > (MAXBPAMMO[iId] - iCurrentAmmo) && (MAXBPAMMO[iId] - iCurrentAmmo) < BUYAMMO[iId])
			iBuyAmmo = MAXBPAMMO[iId] - iCurrentAmmo;
		else if(iClipRemained < BUYAMMO[iId])
		{
			if(iClipRemained > (MAXBPAMMO[iId] - iCurrentAmmo))
				iBuyAmmo = MAXBPAMMO[iId] - iCurrentAmmo;
			else iBuyAmmo = iClipRemained;
		}
		else iBuyAmmo = BUYAMMO[iId];
	}
	else // Кастомные стволы
	{
		ExecuteForward(gl_fwAmmoBuyPre, gl_iForwardResult, iPlayer, iItem);
		
		iMaxAmmo = gl_iItem_MaxAmmo[iPlayer];
		if(iCurrentAmmo >= iMaxAmmo) return;

if(iClipRemained > (gl_iItem_MaxAmmo[iPlayer] - iCurrentAmmo) && (gl_iItem_MaxAmmo[iPlayer] - iCurrentAmmo) < gl_iItem_MaxClip[iPlayer])
			iBuyAmmo = gl_iItem_MaxAmmo[iPlayer] - iCurrentAmmo;
		else if(iClipRemained < gl_iItem_MaxClip[iPlayer])
		{
			if(iClipRemained > (gl_iItem_MaxAmmo[iPlayer] - iCurrentAmmo))
				iBuyAmmo = gl_iItem_MaxAmmo[iPlayer] - iCurrentAmmo;
			else iBuyAmmo = iClipRemained;
		}
		else iBuyAmmo = gl_iItem_MaxClip[iPlayer];
	}

ExecuteHamB(Ham_GiveAmmo, iPlayer, iBuyAmmo, AMMOTYPE[iId], iMaxAmmo);
	emit_sound(iPlayer, CHAN_BODY, "items/9mmclip1.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM);

set_pev(iEntity, pev_ammo, iClipRemained - iBuyAmmo);
}

public CreateAmmoBox(Float: vecOrigin[3], Float: vecAngles[3])
{
	new iEntity = engfunc(EngFunc_CreateNamedEntity, gl_iszAllocString_InfoTarget);
	if(!iEntity) return FM_NULLENT;

engfunc(EngFunc_SetModel, iEntity, ENTITY_AMMOBOX_MODEL);

set_pev(iEntity, pev_classname, ENTITY_AMMOBOX_CLASSNAME);
	set_pev(iEntity, pev_movetype, MOVETYPE_TOSS);
	set_pev(iEntity, pev_solid, SOLID_BBOX);
	set_pev(iEntity, pev_angles, vecAngles);
	set_pev(iEntity, pev_ammo, ENTITY_AMMOBOX_MAX_AMMO);

engfunc(EngFunc_SetSize, iEntity, Float: {-20.0, -20.0, 0.0}, Float: {20.0, 20.0, 50.0});
	vecOrigin[2] += 25.0;
	engfunc(EngFunc_SetOrigin, iEntity, vecOrigin);

return iEntity;
}

// [ Other ]
public load_ammoboxes()
{
	new szMapName[32], szFilePath[128];
	
	get_mapname(szMapName, charsmax(szMapName));
	get_configsdir(szFilePath, charsmax(szFilePath));

new szData[64], iLen;
	new iLine = 0;

format(gl_szMapFile_AmmoBoxes, charsmax(gl_szMapFile_AmmoBoxes), "%s/ammobox/", szFilePath);

if(!dir_exists(gl_szMapFile_AmmoBoxes))
		mkdir(gl_szMapFile_AmmoBoxes);

format(gl_szMapFile_AmmoBoxes, charsmax(gl_szMapFile_AmmoBoxes), "%s/ammobox/%s.txt", szFilePath, szMapName);

if(file_exists(gl_szMapFile_AmmoBoxes))
	{
		new szOrigin[3][8], szAngles[3][8];
		new Float: vecOrigin[3], Float: vecAngles[3];

while((iLine = read_file(gl_szMapFile_AmmoBoxes, iLine, szData, charsmax(szData), iLen)))
		{
			if(iLen < 2 || szData[0] == ';' || szData[0] == '/')
				continue;

parse(szData, szOrigin[0], 7, szOrigin[1], 7, szOrigin[2], 7,
				szAngles[0], 7, szAngles[1], 7, szAngles[2], 7);

vecOrigin[0] = str_to_float(szOrigin[0]);
			vecOrigin[1] = str_to_float(szOrigin[1]);
			vecOrigin[2] = str_to_float(szOrigin[2]);

vecAngles[0] = str_to_float(szAngles[0]);
			vecAngles[1] = str_to_float(szAngles[1]);
			vecAngles[2] = str_to_float(szAngles[2]);

CreateAmmoBox(vecOrigin, vecAngles);
		}
	}

gl_iAmmoBox_Count = get_ammobox_count();
}

public save_ammoboxes()
{
	delete_file(gl_szMapFile_AmmoBoxes);

new iEntity = FM_NULLENT;

new iOrigin[3], iAngles[3]
	new szLine[64];
	new Float: vecOrigin[3], Float: vecAngles[3];

while((iEntity = engfunc(EngFunc_FindEntityByString, iEntity, "classname", ENTITY_AMMOBOX_CLASSNAME))) 
	{
		pev(iEntity, pev_origin, vecOrigin);
		pev(iEntity, pev_angles, vecAngles);

FVecIVec(vecOrigin, iOrigin);
		FVecIVec(vecAngles, iAngles);

formatex(szLine, charsmax(szLine), "%i %i %i %i %i %i", iOrigin[0], iOrigin[1], iOrigin[2], iAngles[0], iAngles[1], iAngles[2]);
		write_file(gl_szMapFile_AmmoBoxes, szLine);
	}
}

public refill_ammobox()
{
	new iEntity;
	while((iEntity = engfunc(EngFunc_FindEntityByString, iEntity, "classname", ENTITY_AMMOBOX_CLASSNAME)))
	{
		if(pev_valid(iEntity))
			set_pev(iEntity, pev_ammo, ENTITY_AMMOBOX_MAX_AMMO);
	}
}

public get_ammobox_count()
{
	new Array: aEntityCount = ArrayCreate(1, 32); 
	new iEntity;
	while((iEntity = engfunc(EngFunc_FindEntityByString, iEntity, "classname", ENTITY_AMMOBOX_CLASSNAME)))
	{
		if(pev_valid(iEntity))
			ArrayPushCell(aEntityCount, iEntity); 
	}

return ArraySize(aEntityCount);
}

// [ Stocks ]
stock UTIL_ColorChat(iPlayer, const szInput[], any:...)
{
    new iCount = 1, iPlayers[32];
    static szMessage[188];
    vformat(szMessage, charsmax(szMessage), szInput, 3);
    
    replace_all(szMessage, charsmax(szMessage), "!g", "^4");
    replace_all(szMessage, charsmax(szMessage), "!y", "^1");
    replace_all(szMessage, charsmax(szMessage), "!t", "^3");
    
    if(iPlayer) iPlayers[0] = iPlayer; else get_players(iPlayers, iCount, "ch");
    {
        for(new i = 0; i < iCount; i++)
        {
            if(is_user_connected(iPlayers[i]))
            {
                message_begin(MSG_ONE, get_user_msgid("SayText"), _, iPlayers[i]);
                write_byte(iPlayers[i]);
                write_string(szMessage);
                message_end();
            }
        }
    }
    
    return true;
}

stock UTIL_DestroyMenu(iPlayer)
{
	show_menu(iPlayer, 0, "^n", 1);
	menu_cancel(iPlayer);
}

Загрузил FliNe

2020-10-27 18:52:08

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram