	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

[DR] CheckPoints

Теги: Скачать плагины csСерверные

ПЛАГИН ДЛЯ DEATHRUN СЕРВЕРОВ. ДОБАВИТ К ВАМ НА СЕРВЕР ЧЕКПОИНТЫ.
//Другое
ИМЕЮЩИЕСЯ ЧЕКПОИНТЫ:
- ДЕНЕЖНЫЙ ЧЕКПОИНТ - ПРИ ПЕРЕСЕЧЕНИИ ИГРОК ПОЛУЧАЕТ ДЕНЬГИ.
- СПАСАЮЩИЙ ЧЕКПОИНТ - ПРИ ПЕРЕСЕЧЕНИИ ИГРОК ПОЛУЧАЕТ "СОХРАНЕНИЕ" - ВОЗМОЖНОСТЬ ПРИ ПАДЕНИИ ПРИ ПРОХОЖДЕНИИ ЛОВУШКИ ВЫЖИТЬ И ПЕРЕМЕСТИТЬСЯ НА МЕСТО ПОСЛЕДНЕГО СОХРАНЯЮЩЕГОСЯ ЧЕКПОИНТА (1 ЧЕКПОИНТ МОЖЕТ СПАСТИ ТОЛЬКО 1 РАЗ).
- ФИНИШНЫЙ ЧЕКПОИНТ - ПРИ ПЕРЕСЕЧЕНИИ ИГРОК ДОЛЖЕН ПРОЙТИ ВСЕ СОХРАНЯЮЩИЕ ЧЕКПОИНТЫ, ПРИ УСПЕШНОМ ВЫПОЛНЕНИИ ЭТОГО УСЛОВИЯ ИГРОК ПОЛУЧАЕТ БАСНОСЛОВНОЕ ВОЗНАГРАЖДЕНИЕ И ВОЗМОЖНОСТЬ ИДТИ И УБИТЬ ТЕРРОРИСТА.

Компилятор: 1.8.2 917

Команды:

say /cp - Открыть меню создания чекпоинтов

//Настройки в исходнике

#DEFINE ACCESS_FLAG ADMIN_IMMUNITY // ФЛАГ ДОСТУПА К МЕНЮ РАССТАНОВКИ ЧЕКПОИНТОВ

CONST NUM_CP_MONEY = 20; // КОЛ-ВО ДЕНЕЖНЫХ ЧЕКПОИНТОВ

CONST NUM_CP_SAVE = 5; // КОЛ-ВО СОХРАНЯЮЩИХ ЧЕКПОИНТОВ

CONST NUM_CP_FINISH = 1; // КОЛ-ВО ФИНИШНЫХ ЧЕКПОИНТОВ (ПО ЛОГИКЕ ОН ОДИН, ИЗВРАЩЕНЦЫ МОГУТ СТАВИТЬ БОЛЬШЕ)

CONST AWARD_CP_MONEY = 10; // НАЧАЛЬНАЯ НАГРАДА ЗА ПЕРЕСЕЧЕНИЕ ДЕНЕЖНОГО ЧЕКПОИНТА (ДАЛЕЕ АЛГЕБРАИЧЕСКАЯ ПРОГРЕССИЯ: 10, 20, 30...)

CONST AWARD_CP_FINISH = 2000; // НАГРАДА ЗА ПЕРЕСЕЧЕНИЕ ФИНИШНОГО ЧЕКПОИНТА

.sma / .sp

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <colorchat>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN "CheckPoints"
#define VERSION "1.0"
#define AUTHOR "6u3oH"

const g_szBytsKeys = MENU_KEY_1|MENU_KEY_2|MENU_KEY_3|MENU_KEY_4|MENU_KEY_0;

#define ACCESS_FLAG ADMIN_IMMUNITY

const NUM_CP_MONEY = 20; // Кол-во денежных чекпоинтов
const NUM_CP_SAVE = 5; // Кол-во сохраняющих чекпоинтов
const NUM_CP_FINISH = 1; // Кол-во финишных чекпоинтов (по логике он один, извращенцы могут ставить больше)

const AWARD_CP_MONEY = 10; // Начальная награда за пересечение денежного чекпоинта (далее алгебраическая прогрессия: 10, 20, 30...)
const AWARD_CP_FINISH = 2000; // Награда за пересечение финишного чекпоинта

new const CLASSNAME_CP[] = "info_cp";
new const CLASSNAME_DEF[] = "info_null";
new const MODEL_CP[] = "models/checkpoints/checkpoint.mdl";

new const SOUND_CP_TOUCH[] = "checkpoints/checkpoint_touch"
new const SOUND_CP_TELEPORT[] = "checkpoints/checkpoint_teleport"

new const MENU_INFO[][] =
{
	"Меню расстановки чекпоинтов",
	"Денежный чекпоинт",
	"Спасающий чекпоинт",
	"Финишный чекпоинт",
	"Удалить все чекпоинты"
};

new g_iMaxPlayers;
new g_iCounter[33];
new Float: g_fOrigin[33][3];
new bool: g_bReOrigin[33];
new bool: g_bHasFinish[33];
new g_iFinishCheck[33];
new Float: g_fTimeStart;
new g_iNumCpMoney
new g_iNumCpSave;
new g_iNumCpFinish;
new bool: g_bHasTouch[33][1024];
new g_sPathFile[256];
	
public plugin_precache()
{
	new sPath[256];
	engfunc(EngFunc_PrecacheModel, MODEL_CP);
	
	format(sPath, charsmax(sPath), "%s.wav", SOUND_CP_TOUCH);
	engfunc(EngFunc_PrecacheSound, sPath);
	
	format(sPath, charsmax(sPath), "%s.wav", SOUND_CP_TELEPORT);
	engfunc(EngFunc_PrecacheSound, sPath);	
}

public plugin_cfg()
{
	if(!dir_exists("addons/amxmodx/configs/dr_checkpoints"))
		mkdir("addons/amxmodx/configs/dr_checkpoints");

g_iNumCpMoney = g_iNumCpSave = g_iNumCpFinish = 0;
		
	new sMapName[32], iLine = 1, iLen, sData[64], iData[4], sOrigin[4][8], iOrigin[3], Float: fOrigin[3];
	get_mapname(sMapName, charsmax(g_sPathFile));
	
	format(g_sPathFile, charsmax(g_sPathFile), "addons/amxmodx/configs/dr_checkpoints/%s.dat", sMapName);
	write_file(g_sPathFile, "[Plugins Store] [Author: 6u3oH]", 0);
	
	while((iLine = read_file(g_sPathFile, iLine, sData, charsmax(sData), iLen)))
	{
		parse(sData, sOrigin[0], 7, sOrigin[1], 7, sOrigin[2], 7, sOrigin[3], 7);
		
		for(new i; i < 4; i++)
			iData[i] = str_to_num(sOrigin[i]);
			
		for(new i; i < 3; i++)
			iOrigin[i] = iData[i];	
		
		switch(iData[3])
		{
			case 0: g_iNumCpMoney++;
			case 1: g_iNumCpSave++;
			case 2: g_iNumCpFinish++;
		}
		
		new iEnt = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, CLASSNAME_DEF))
		
		IVecFVec(iOrigin, fOrigin);
		fOrigin[2] += 60.0;
		
		set_pev(iEnt, pev_classname, CLASSNAME_CP);
		set_pev(iEnt, pev_origin, fOrigin);
		engfunc(EngFunc_SetModel, iEnt, MODEL_CP);
	
		set_pev(iEnt, pev_solid, SOLID_TRIGGER);
		engfunc(EngFunc_SetSize, iEnt, Float:{-40.0, -40.0, -40.0}, Float:{40.0, 40.0, 40.0});
		
		set_pev(iEnt, pev_skin, random_num(1, 5));
		set_pev(iEnt, pev_euser4, iData[3]);
		
		PlayAnimation(iEnt);
	}
}

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	
	register_clcmd("say /cp", "Clcmd_CheckpointsMenu");
	register_clcmd("say_team /cp", "Clcmd_CheckpointsMenu");
	register_clcmd("say /checkpoints", "Clcmd_CheckpointsMenu");
	register_clcmd("say_team /checkpoints", "Clcmd_CheckpointsMenu");
	register_clcmd("cp_menu", "Clcmd_CheckpointsMenu");
	register_clcmd("say /checkpoints", "Clcmd_CheckpointsMenu");
	
	register_menu("Menu Checkpoints", g_szBytsKeys, "CheckpointsMenu_Handler");
	
	RegisterHam(Ham_TakeDamage, "player", "HamHook_PlayerTakeDamage", .Post = false);
	RegisterHam(Ham_Touch, CLASSNAME_DEF, "HamHook_TouchCheckPoint", .Post = true);
	
	register_event("HLTV", "Event_StartRound", "a", "1=0", "2=0");
	
	g_iMaxPlayers = get_maxplayers();
}

public Event_StartRound()
{
	g_fTimeStart = get_gametime();
	
	for(new id = 1; id <= g_iMaxPlayers; id++)
	{
		if(get_user_team(id) != 2)
		continue;
		
		g_iCounter[id] = 0;
		g_iFinishCheck[id] = 0;
		
		g_bReOrigin[id] = false;
		g_bHasFinish[id] = false;
		
		for(new iEnt = 33; iEnt < 512; iEnt++)
			g_bHasTouch[id][iEnt] = false;
	}
}

public Clcmd_CheckpointsMenu(id)
{
	if(~get_user_flags(id) & ACCESS_FLAG)
	{
		client_print_color(id, NORMAL, "[^4Чекопинты^1] У вас нет доступа");
		return;
	}
	
	static iMenu[650], iLen; iLen = 0;
       
	iLen = formatex(iMenu[iLen], charsmax(iMenu) - iLen, "\r%s^n^n", MENU_INFO[0]);
	
	iLen += formatex(iMenu[iLen], charsmax(iMenu) - iLen, "\r1. \w%s \d[\y%i\d/\r%i\d]^n", MENU_INFO[1], g_iNumCpMoney, NUM_CP_MONEY);
	iLen += formatex(iMenu[iLen], charsmax(iMenu) - iLen, "\r2. \w%s \d[\y%i\d/\r%i\d]^n", MENU_INFO[2], g_iNumCpSave, NUM_CP_SAVE);
	iLen += formatex(iMenu[iLen], charsmax(iMenu) - iLen, "\r3. \w%s \d[\y%i\d/\r%i\d]^n", MENU_INFO[3], g_iNumCpFinish, NUM_CP_FINISH);
	iLen += formatex(iMenu[iLen], charsmax(iMenu) - iLen, "\r4. \w%s^n^n", MENU_INFO[4]);
	
	iLen = formatex(iMenu[iLen], charsmax(iMenu) - iLen, "\r0. \wВыход");
	
	show_menu(id, g_szBytsKeys, iMenu, -1, "Menu Checkpoints");
}

public CheckpointsMenu_Handler(id, iItem)
{
	switch(iItem)
	{
		case 0:
		{
			if(g_iNumCpMoney == NUM_CP_MONEY)
			{
				client_print_color(id, NORMAL, "[^4Чекопинты^1] достигнут ^3лимит ^4денежных чекпоинтов");
				return;
			}
			
			g_iNumCpMoney++;
			Create_CheckPoint(id, iItem);
			
			Clcmd_CheckpointsMenu(id);
		}
		
		case 1:
		{
			if(g_iNumCpSave == NUM_CP_SAVE)
			{
				client_print_color(id, NORMAL, "[^4Чекпоинты^1] достигнут ^3лимит ^4сохраняющих чекпоинтов");
				return;
			}
			
			g_iNumCpSave++;
			Create_CheckPoint(id, iItem);
			
			Clcmd_CheckpointsMenu(id);
		}
		
		case 2:
		{
			if(g_iNumCpFinish == NUM_CP_FINISH)
			{
				client_print_color(id, NORMAL, "[^4Чекопинты^1] достигнут ^3лимит ^4финишных чекпоинтов");
				return;
			}
			
			g_iNumCpFinish++;
			Create_CheckPoint(id, iItem);
			
			Clcmd_CheckpointsMenu(id);
		}
		
		case 3:
		{
			if(g_iNumCpMoney == 0 && g_iNumCpSave == 0 && g_iNumCpFinish == 0)
			{
				client_print_color(id, NORMAL, "[^4Чекпоинты^1] Ни одного ^4чекпоинта ^1не найдено!");
				return;
			}
			
			new iEnt = FM_NULLENT;
			while ((iEnt = engfunc(EngFunc_FindEntityByString, iEnt, "classname", CLASSNAME_CP)))
			{
				set_pev(iEnt, pev_flags, FL_KILLME);
				g_bHasTouch[id][iEnt] = false;
			}
			
			g_iNumCpMoney = 0;
			g_iNumCpSave = 0;
			g_iNumCpFinish = 0;
			
			g_bReOrigin[id] = false;
			
			delete_file(g_sPathFile);
			write_file(g_sPathFile, "[Plugins Store] [Author: 6u3oH]", 0);
			
			client_print_color(id, NORMAL, "[^4Чекпоинты^1] Все ^3чекпоинты ^1успешно удалены!");
			
			Clcmd_CheckpointsMenu(id);
		}
	}
}

public Create_CheckPoint(id, iType)
{
	new iOrigin[3], Float: fOrigin[3], sData[32];
	
	new iEnt = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, CLASSNAME_DEF))
	
	get_user_origin(id, iOrigin, 3);
	IVecFVec(iOrigin, fOrigin);
	fOrigin[2] += 60.0;
	
	set_pev(iEnt, pev_classname, CLASSNAME_CP);
	set_pev(iEnt, pev_origin, fOrigin);
	engfunc(EngFunc_SetModel, iEnt, MODEL_CP);

set_pev(iEnt, pev_solid, SOLID_TRIGGER);
	engfunc(EngFunc_SetSize, iEnt, Float:{-40.0, -40.0, -40.0}, Float:{40.0, 40.0, 40.0});
	
	set_pev(iEnt, pev_skin, random_num(1, 5));
	set_pev(iEnt, pev_euser4, iType);
	
	PlayAnimation(iEnt);
	
	format(sData, charsmax(sData), "%i %i %i %i", iOrigin[0], iOrigin[1], iOrigin[2], iType);
	write_file(g_sPathFile, sData, -1);
}

public HamHook_PlayerTakeDamage(iVictim, iWeapon, iAttacker, Float: fDmg, szBytsDmg)
{
	if(IsPlayer(iAttacker))
	return HAM_IGNORED;
	
	if(iVictim == iAttacker)
	return HAM_IGNORED;
	
	if(szBytsDmg == DMG_FALL)
	return HAM_IGNORED;
	
	if(!g_bReOrigin[iVictim])
	return HAM_IGNORED;
	
	if(fDmg >= pev(iVictim, pev_health))
	{
		set_pev(iVictim, pev_velocity, {0.0, 0.0, 0.0});
		set_pev(iVictim, pev_origin, g_fOrigin[iVictim]);
		
		client_print_color(iVictim, NORMAL, "[^4Чекпоинты^1] Вы перемещены на точку ^4сохраняющего чекпоинта");
		
		g_bReOrigin[iVictim] = false;
		client_cmd(iVictim, "spk %s", SOUND_CP_TELEPORT);
		
		return HAM_SUPERCEDE;
	}
	
	return HAM_IGNORED;
}

public HamHook_TouchCheckPoint(iEnt, id)
{
	static sClassName[32];
	pev(iEnt, pev_classname, sClassName, charsmax(sClassName));
	
	if(!equal(sClassName, CLASSNAME_CP))
	return;

if(!is_user_alive(id))
	return;
	
	if(g_bHasTouch[id][iEnt])
	return;
	
	switch(pev(iEnt, pev_euser4))
	{
		case 0:
		{
			g_iCounter[id]++;
			cs_set_user_money(id, cs_get_user_money(id) + g_iCounter[id] * AWARD_CP_MONEY);
			
			client_print_color(id, NORMAL, "[^4Чекпоинты^1] Вы пересекли ^3денежный чекпоинт^1 [^4%i$^1]", g_iCounter[id] * AWARD_CP_MONEY);
		}
		
		case 1:
		{
			g_bReOrigin[id] = true;
			pev(id, pev_origin, g_fOrigin[id]);
			
			g_iFinishCheck[id]++;
			
			client_print_color(id, NORMAL, "[^4Чекпоинты^1] Вы пересекли ^3сохраняющий чекпоинт^1 [^4позиция сохранена^1]");
		}
		
		case 2:
		{
			if(g_iFinishCheck[id] != g_iNumCpSave)
			{
				ExecuteHamB(Ham_CS_RoundRespawn, id);
				
				client_print_color(id, NORMAL, "[^4Чекпоинты^1] Вы пересекли не все ^4сохраняющие чекпоинты");
				client_print_color(id, NORMAL, "[^4Чекпоинты^1] Вы были телепортированы на ^4спавн");
				
				return;
			}
			
			if(g_bHasFinish[id])
			return;

g_bHasFinish[id] = true;
			
			cs_set_user_money(id, cs_get_user_money(id) + AWARD_CP_FINISH);
			
			new sName[32];
			get_user_name(id, sName, charsmax(sName));
			
			new Float: fTimePoint = get_gametime() - g_fTimeStart;
			
			if(fTimePoint > 60.0)
				client_print_color(0, NORMAL, "[^4Чекпоинты^1] Игрок ^4%s ^1прошёл карту за ^3%i ^1мин. и ^3%i ^1сек", sName, floatround(fTimePoint) / 60, floatround(fTimePoint) % 60);
			else
				client_print_color(0, NORMAL, "[^4Чекпоинты^1] Игрок ^4%s ^1прошёл карту за ^3%i ^1сек", sName, floatround(fTimePoint) % 60);
		}
	}
	
	client_cmd(id, "spk %s", SOUND_CP_TOUCH);
	g_bHasTouch[id][iEnt] = true;
}

stock IsPlayer(id)
{
	if(1 <= id <= g_iMaxPlayers)
		return true;
		
	return false;
}

stock PlayAnimation(iEnt)
{
	set_pev(iEnt, pev_sequence, 0);
	set_pev(iEnt, pev_animtime, 2.0);
	set_pev(iEnt, pev_framerate, 1.0);
	set_pev(iEnt, pev_frame, 0.0);	
}

Загрузил exec208

2019-01-05 20:09:26

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram