	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

DR Life System [+SQL]

Теги: Скачать плагины csАдминские

Плагин для Deathrun серверов, позволяющий игрокам возрождаться за деньги.
Что-то типа банка жизней.
(не знаю актуально сие, не актуально, но сделал, вот)
По дефу, на всеми любимом реапи.

Сохранение в мускул, лимит по флагам доступа.
Подробнее в исходнике.

Квары:
dr_life_cost - за сколько покупаются жизни
dr_life_cost_sell - за сколько их можно продать
dr_life_default - дефолтное кол-во жизней (выдаются после входа на сервер)
dr_life_min_ct - минимальное кол-во живых кт для доступа к возрождению.
dr_life_host - хост для коннекта к базе
dr_life_user - пользователь для коннекта к базе
dr_life_pass - пароль для коннекта к базе
dr_life_db - название базы для коннекта к базе
dr_life_table - таблица для записи данных

Компилятор: 1.8.2 REapi +ZIP 745

Команды:

Доступ к меню только у КТ, хех.

Команда /life в чат откроет меню.

.sma / .sp

/*
	*for cs-amba.ru
	*by vk.com/pomka_bernov
*/
#include < amxmodx >
#include < reapi >

#if AMXX_VERSION_NUM  < 183
	#include < colorchat >
	#define MAX_PLAYERS 32
	#define client_disconnected client_disconnect
#endif

//Если не нужна какая-либо из функций - закоментируйте
#define SAVE_SQL				//Нужно ли сохранение в БД?
#define AUTO_OPEN				//Открывать меню с жизнями после смерти?
#define AUTO_USE				//Функция автоматического использования доп. жизни после смерти [если в запасе нет доп. жизней - возрождать не будет (в связке с авто покупкой работает нормально)]
#define AUTO_BUY				//Функция автоматической покупки доп. жизни после смерти [купит доп. жизнь только если в запасе их 0]
#define TRANSFER				//Функция передачи жизней
#define MIN_ALIVE_CT			//Проверка на живых кт
#define LIMIT					//Лимит на кол-во жизней по флагам доступа

#if defined LIMIT
enum LIMITS {	sFlag, sLimit	}
new const sLimits[][LIMITS] = {		//Флаг, допустимый лимит
	{ADMIN_BAN, 15},
	{ADMIN_LEVEL_H, 10},
	{ADMIN_USER, 5}					//Обычный пользователь
}

new gLimit[MAX_PLAYERS + 1];
#endif

#if defined SAVE_SQL
	#include < sqlx >
#endif

enum {	TBUY, TSELL, TUSE }
enum ECVARS {
	LIFE_COST, 
	LIFE_SELL,
	DEF_LIFES
	#if defined MIN_ALIVE_CT
	,CT_ALIVE
	#endif
	#if defined SAVE_SQL
	,SQL_HOST,
	SQL_USER,
	SQL_PASS,
	SQL_DB,
	SQL_TABLE
	#endif
}
new sLifes[MAX_PLAYERS + 1], gCvar[ECVARS], gSet[ECVARS];
#if defined AUTO_BUY
new bool:gAuto[MAX_PLAYERS + 1];
#endif
#if defined AUTO_USE
new bool:gUse[MAX_PLAYERS + 1];
#endif
#if defined SAVE_SQL
enum {	SQL_INIT, SQL_NLOAD, SQL_LOAD	}
enum _: ROWS {
	ID,
	STEAM,
	LIFES,
	ABUY,
	AUSE
}
new const sRows[ROWS][] = {
	"id",
	"steam",
	"lifes",
	"abuy",
	"ause"
}

#define QLENGTH 512
new Handle: sTuple = Empty_Handle, sTable[16], bool:sqlWork;
#endif

public plugin_init(){
	register_plugin("[DR] Life System", "1.0", "PAffAEJIkA :3");
	
	register_dictionary("dr_life_system.txt");
	
	register_clcmd("say /life", "clcmd");
	register_clcmd("say_team /life", "clcmd");
	
	register_srvcmd("dr_life_reload", "load_cvars");
	
	gCvar[LIFE_COST] = register_cvar("dr_life_cost", "5000");
	gCvar[LIFE_SELL] = register_cvar("dr_life_cost_sell", "2500");
	gCvar[DEF_LIFES] = register_cvar("dr_life_default", "2");
	#if defined MIN_ALIVE_CT
	gCvar[CT_ALIVE] = register_cvar("dr_life_min_ct", "4");
	#endif
	#if defined SAVE_SQL
	gCvar[SQL_HOST] = 		register_cvar("dr_life_host", "127.0.0.1", FCVAR_PROTECTED);
	gCvar[SQL_USER] = 		register_cvar("dr_life_user", "root", FCVAR_PROTECTED);
	gCvar[SQL_PASS] = 		register_cvar("dr_life_pass", "password", FCVAR_PROTECTED);
	gCvar[SQL_DB]   = 		register_cvar("dr_life_db", "database", FCVAR_PROTECTED);
	gCvar[SQL_TABLE] =		register_cvar("dr_life_table", "life_sys", FCVAR_PROTECTED);
	#endif

#if defined AUTO_BUY || defined AUTO_OPEN || defined AUTO_USE
	RegisterHookChain(RG_CBasePlayer_Killed, "PlayerKilled");
	#endif
}

public plugin_cfg(){
	#if AMXX_VERSION_NUM < 183
	server_exec();
	#endif
	load_cvars();
}

#if defined SAVE_SQL
public plugin_end()
	SQL_FreeHandle(sTuple);
#endif

public load_cvars(){
	gSet[LIFE_COST] = get_pcvar_num(gCvar[LIFE_COST]);
	gSet[LIFE_SELL] = get_pcvar_num(gCvar[LIFE_SELL]);
	gSet[DEF_LIFES] = get_pcvar_num(gCvar[DEF_LIFES]);
	#if defined MIN_ALIVE_CT
	gSet[CT_ALIVE] = get_pcvar_num(gCvar[CT_ALIVE]);
	#endif
	
	#if defined SAVE_SQL	
	new host[64], user[64], pass[64], db[32], query[QLENGTH], data[1];
	get_pcvar_string(gCvar[SQL_HOST], host, charsmax(host));
	get_pcvar_string(gCvar[SQL_USER], user, charsmax(user));
	get_pcvar_string(gCvar[SQL_PASS], pass, charsmax(pass));
	get_pcvar_string(gCvar[SQL_DB], db, charsmax(db));
	get_pcvar_string(gCvar[SQL_TABLE], sTable, charsmax(sTable));
	
	if(sTuple != Empty_Handle){
		sqlWork = false;
		SQL_FreeHandle(sTuple);
	}
		
	sTuple = SQL_MakeDbTuple(host, user, pass, db);
	
	data[0] = SQL_INIT;
	format(query, charsmax(query), "CREATE TABLE IF NOT EXISTS `%s` (\
		  `%s` int(11) NOT NULL AUTO_INCREMENT,\
		  `%s` varchar(35) CHARACTER SET utf8 COLLATE utf8_unicode_ci NOT NULL,\
		  `%s` int(6) NOT NULL,\
		  `%s` int(2) NOT NULL,\
		  `%s` int(2) NOT NULL,\
		  PRIMARY KEY (`%s`)\
		) ENGINE=InnoDB DEFAULT CHARSET=utf8 AUTO_INCREMENT=1 ;", sTable, sRows[ID], sRows[STEAM], sRows[LIFES], sRows[ABUY], sRows[AUSE], sRows[ID]
	);
	SQL_ThreadQuery(sTuple, "SQL_Handler", query, data, sizeof data);
	#endif
	
	log_amx("Cvars have been loaded!");
}

public client_putinserver(id){
	if(is_user_bot(id) || is_user_hltv(id))
		return;
		
	#if defined AUTO_BUY
	gAuto[id] = false;
	#endif
	#if defined AUTO_USE
	gUse[id] = false;
	#endif
	#if defined LIMIT
	LimitLoad(id)
	#endif
	sLifes[id] = gSet[DEF_LIFES];
	
	#if defined SAVE_SQL
	if(sqlWork)
		load_lifes(id);
	#endif
}

#if defined LIMIT
public LimitLoad(id){
	new flag = get_user_flags(id);
	for(new i; i < sizeof sLimits; i ++){
		if(sLimits[i][sFlag] != ADMIN_USER && ~flag & sLimits[i][sFlag])
			continue;
		
		gLimit[id] = sLimits[i][sLimit];
		break;
	}
}
#endif

#if defined SAVE_SQL
public client_disconnected(id){
	if(!sqlWork || is_user_bot(id) || is_user_hltv(id))
		return;
	save_lifes(id);
}
#endif

public clcmd(id){
	if(get_member(id, m_iTeam) != TEAM_CT){
		client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_ONLY_CT");
		return;
	}
	
	OpenMenu(id);
}

public OpenMenu(id){	
	new caption[128];
	format(caption, charsmax(caption), "%L", LANG_SERVER, "MENU_MAIN_HANDLER", sLifes[id], get_text(sLifes[id]));
	
	new menu = menu_create(caption, "handler");
	
	new item[64];	
	format(item, charsmax(item), "%L", LANG_SERVER, "MENU_MAIN_ITEM1", get_member(id, m_iAccount) < gSet[LIFE_COST] ? "d" : "w", gSet[LIFE_COST]);
	menu_additem(menu, item, "0");
	
	format(item, charsmax(item), "%L", LANG_SERVER, "MENU_MAIN_ITEM2", sLifes[id] ? "w" : "d", gSet[LIFE_SELL]);
	menu_additem(menu, item, "1");
	
	format(item, charsmax(item), "%L", LANG_SERVER, "MENU_MAIN_ITEM3", sLifes[id] ? "w" : "d");
	#if !defined TRANSFER 
	add(item, charsmax(item), "^n");
	#endif
	menu_additem(menu, item, "2");
	
	#if defined TRANSFER
	format(item, charsmax(item), "%L", LANG_SERVER, "MENU_MAIN_ITEM4", sLifes[id] ? "w" : "d");
	menu_additem(menu, item, "3");
	#endif
	
	//menu_addblank(menu, false);		//Он збс работает, но только если пунктов в меню > 5
	
	#if defined AUTO_BUY
	format(item, charsmax(item), "%L", LANG_SERVER, "MENU_MAIN_ITEM5", LANG_SERVER, gAuto[id] ? "MENU_MAIN_ITEM5_ON" : "MENU_MAIN_ITEM5_OFF");
	menu_additem(menu, item, "4");
	#endif
	
	#if defined AUTO_USE
	format(item, charsmax(item), "%L", LANG_SERVER, "MENU_MAIN_ITEM6", LANG_SERVER, gUse[id] ? "MENU_MAIN_ITEM6_ON" : "MENU_MAIN_ITEM6_OFF");
	menu_additem(menu, item, "5");
	#endif
	
	menu_setprop(menu, MPROP_EXITNAME, "\rВыход");
	menu_display(id, menu);
}

public handler(id, menu, item){	
	if(item == MENU_EXIT){
		menu_destroy(menu);
		return;
	}
	
	new data[30], iName[64], access, callback;			//Из-за дейфайнов пришлось делать уот так уот вместо юзания item :c
	menu_item_getinfo(menu, item, access, data, charsmax(data), iName, charsmax(iName), callback);
	menu_destroy(menu);
	new key = str_to_num(data);
	
	switch(key){
		case 0:	DoThis(id, TBUY);
		case 1:	DoThis(id, TSELL);
		case 2: DoThis(id, TUSE);
		#if defined TRANSFER
		case 3:{
			if(sLifes[id]){
				TransferLife(id);
				return;
			}
		}
		#endif
		#if defined AUTO_BUY
		case 4:{
			gAuto[id] =! gAuto[id];
			client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_AUTO_BUY", LANG_SERVER, gAuto[id] ? "CHAT_AUTO_BUY_ON" : "CHAT_AUTO_BUY_OFF");
		}
		#endif
		#if defined AUTO_USE
		case 5:{
			gUse[id] =! gUse[id];
			client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_AUTO_USE", LANG_SERVER, gUse[id] ? "CHAT_AUTO_USE_ON" : "CHAT_AUTO_USE_OFF");
		}
		#endif
	}
	
	OpenMenu(id);
}

#if defined TRANSFER
public TransferLife(id){
	new pl[32], cnt;
	get_players(pl, cnt, "ch");
	
	new caption[128];	format(caption, charsmax(caption), "%L", LANG_SERVER, "MENU_PLAYER_HANDLER");
	new menu = menu_create(caption, "handler2");
	
	for(new i, player, name[32], temp[4]; i < cnt; i ++){
		player = pl[i];
		if(player == id)
			continue;
			
		get_user_name(player, name, charsmax(name));
		num_to_str(player, temp, charsmax(temp));
		menu_additem(menu, name, temp);
	}
	
	if(!menu_items(menu)){
		client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_NONE_PLAYERS");
		OpenMenu(id);
		menu_destroy(menu);
		return;
	}
	
	menu_setprop(menu, MPROP_NEXTNAME, "Дальше");
	menu_setprop(menu, MPROP_BACKNAME, "Назад");
	menu_setprop(menu, MPROP_EXITNAME, "\rВыход");
	
	menu_display(id, menu);
}

public handler2(id, menu, item){	
	if(item == MENU_EXIT){
		menu_destroy(menu);
		return;
	}
	
	new data[30], iName[64], access, callback;	
	menu_item_getinfo(menu, item, access, data, charsmax(data), iName, charsmax(iName), callback);
	menu_destroy(menu);
	
	new player = str_to_num(data), name[32];
	if(is_user_connected(player)){		
		sLifes[id] --;
		sLifes[player] ++;
		
		get_user_name(player, name, charsmax(name));
		client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_GIVE_LIFE", name);
		
		get_user_name(id, name, charsmax(name));
		client_print_color(player, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_GIVE_LIFE2", name);
	}else
		client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_PL_DISC");
		
	TransferLife(id);
}
#endif

#if defined SAVE_SQL
public get_all(){
	new pl[32], cnt;
	get_players(pl, cnt, "ch");
	
	for(new i; i < cnt; i ++)
		client_putinserver(pl[i]);
}

public load_lifes(id){
	new query[QLENGTH], data[2], steam[35];
	get_user_authid(id, steam, charsmax(steam));
	
	data[0] = SQL_LOAD;
	data[1] = id;
	
	format(query, charsmax(query), "SELECT * FROM `%s` WHERE `%s` = '%s'", sTable, sRows[STEAM], steam);
	SQL_ThreadQuery(sTuple, "SQL_Handler", query, data, sizeof data);
}

public create_new(id){
	new query[QLENGTH], data[1], steam[35];
	get_user_authid(id, steam, charsmax(steam));
	
	data[0] = SQL_NLOAD;
	
	format(query, charsmax(query), "INSERT INTO `%s`(`%s`) VALUES ('%s')", sTable, sRows[STEAM], steam);
	SQL_ThreadQuery(sTuple, "SQL_Handler", query, data, sizeof data);	
}

public save_lifes(id){
	new query[QLENGTH], len, data[1], steam[35];
	get_user_authid(id, steam, charsmax(steam));
	
	data[0] = SQL_NLOAD;
	
	len = format(query, charsmax(query), "UPDATE `%s` SET `%s` = '%i'", sTable, sRows[LIFES], sLifes[id]);	
	#if defined AUTO_BUY
	len += format(query[len], charsmax(query) - len, ", `%s` = '%i'", sRows[ABUY], gAuto[id]);
	#endif
	#if defined AUTO_USE
	len += format(query[len], charsmax(query) - len, ", `%s` = '%i'", sRows[AUSE], gUse[id]);
	#endif	
	format(query[len], charsmax(query) - len, "WHERE `%s` = '%s'", sRows[STEAM], steam);
	
	SQL_ThreadQuery(sTuple, "SQL_Handler", query, data, sizeof data);	
}

public SQL_Handler(failstate, Handle:query, const error[], errornum, data[]){
	switch(failstate){
		case TQUERY_CONNECT_FAILED:{
			log_amx("[Error] Connection error: %s (%d)", error, errornum);
			return;
		}
		case TQUERY_QUERY_FAILED:{
			log_amx("[Error] Query error: %s (%d)", error, errornum);
			return;
		}	 
	}
	
	switch(data[0]){
		case SQL_INIT:{
			sqlWork = true;
			log_amx("Mysql connect is OK");
			get_all();
		}
		case SQL_LOAD:{
			new id = data[1];
			if(!is_user_connected(id))
				return;
			
			if(!SQL_NumResults(query)){
				create_new(id);
				return;
			}
			
			sLifes[id] = SQL_ReadResult(query, LIFES);
			
			#if defined LIMIT
			if(sLifes[id] > gLimit[id])		//Вдруг он заходил раньше с флагом, а тут все кончилось?
				sLifes[id] = gLimit[id];
			#endif			
			#if defined AUTO_BUY
			gAuto[id] = bool:SQL_ReadResult(query, ABUY);
			#endif
			#if defined AUTO_USE
			gUse[id] = bool:SQL_ReadResult(query, AUSE);
			#endif
		}
	}	
}
#endif

#if defined AUTO_BUY || defined AUTO_OPEN || defined AUTO_USE
public PlayerKilled(victim, killer, gib){
	if(!(0 < victim <= MAX_PLAYERS) || get_member(victim, m_iTeam) != TEAM_CT)
		return;
	
	#if defined AUTO_BUY
	if(gAuto[victim] && !sLifes[victim])
		DoThis(victim, TBUY);
	#endif	
	
	#if defined AUTO_USE
	if(gUse[victim] && sLifes[victim])
		DoThis(victim, TUSE);
	#endif	
	
	#if defined AUTO_OPEN
	OpenMenu(victim);
	#endif
}
#endif

public DoThis(id, type){
	if(type > TBUY && !sLifes[id]){
		client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_NONE_LIFE");
		return;
	}
	
	switch(type){
		case TBUY:{
			new sMoney = get_member(id, m_iAccount);			
			if(sMoney < gSet[LIFE_COST]){
				client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_NONE_MONEY");
				return;
			}
			
			#if defined LIMIT
			if(sLifes[id] >= gLimit[id]){
				client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_LIMIT");
				return;
			}
			#endif
			
			sLifes[id] ++;
			rg_add_account(id, sMoney - gSet[LIFE_COST], AS_SET);
			client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_BUY_LIFE");
		}
		case TSELL:{
			sLifes[id] --;
			rg_add_account(id, gSet[LIFE_SELL], AS_ADD);
			client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_SELL_LIFE");
		}
		case TUSE:{			
			#if defined MIN_ALIVE_CT
			if(get_ct() < gSet[CT_ALIVE]){
				client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_CT");
				return;
			}
			#endif
			
			if(is_user_alive(id)){
				client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_ALIVE");
				return;
			}
			
			sLifes[id] --;
			rg_round_respawn(id);
			
			new name[32];	
			get_user_name(id, name, charsmax(name));
			client_print_color(id, false, "%L %L", LANG_SERVER, "CHAT_PREFIX", LANG_SERVER, "CHAT_A_ALIVE", name);
		}
	}
}

stock get_text(tm){
	new ost = tm % 10, ost2 = tm % 100, buff[14];
	
	if(ost2 >= 5 && ost2 <= 20)
		buff = "жизней";
	else{
		switch(ost){
			case 1:			buff = "жизнь";
			case 2..4:		buff = "жизни";
			case 0, 5..9:	buff = "жизней";
		}
	}
	return buff;
}

stock get_ct(){		//Не придумал как лучше релизнуть получение кол-ва живых кт, думал еще в памяти хранить, но чёт не
	new pl[32], cnt, ac;
	get_players(pl, cnt, "ach");		//"ache" - может криво поулчать инфу, посему уот так уот
	
	for(new i = 0; i < cnt; i ++){
		if(get_member(pl[i], m_iTeam) == TEAM_CT)
			ac ++;
	}
	return ac;
}

Загрузил ADEPT

2020-03-01 18:25:31

Скачать

195.211.60.213:27015

УКРАЇНА - Б А Н Д Е Р Ш Т А Т - [2000 FPS] 18+

195.211.60.213:27018

В І Л Ь Н А - У К Р А Ї Н А [ RYZEN 9 - 5.7 GHZ ]

195.211.60.213:27016

(Д) (І) (В) (О) (Ч) (А) - (В) (Л) (А) (Д) (А) | 18+

195.211.60.213:27017

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram