Grenade Explode Modes

// Copyright © 2016 Vaqtincha

​

//============================ CONFIG START ===========================//

​

// #define ONLY_ONE_GRENADE "weapon_hegrenade" // set grenade name (commentable)

​

#define EXPLODE_TIME_1  5.0

#define EXPLODE_TIME_2  10.0        // (commentable)

// #define EXPLODE_TIME_3   20.0        // (commentable)

​

//============================= CONFIG END ============================//

​

#define VERSION "0.0.1"

​

#include <amxmodx>

#include <fakemeta>

#include <hamsandwich>

// #include <csx>       // not necessary

​

#define MAX_PLAYERS 32

​

#define get_weapon_owner(%1)        get_pdata_cbase(%1, m_pPlayer, XO_WEAPON)

​

// offsets

#if AMXX_VERSION_NUM < 183

    const m_bHasShield = 1<<24

    const m_iUserPrefs = 510

    #define HasShield(%1)           (get_pdata_int(%1, m_iUserPrefs) & m_bHasShield)

#else

    const m_bHasShield = 2043

    #define HasShield(%1)           get_pdata_bool(%1, m_bHasShield)

#endif

const m_pPlayer = 41

const m_flNextAttack = 83

const m_flNextSecondaryAttack = 47

const XO_WEAPON = 4

​

enum _:GrenadeType{

    NORMAL,

    MODE_1,

    MODE_2,

    MODE_3

}

​

new g_iMode[MAX_PLAYERS + 1] = {GrenadeType}

#if !defined ONLY_ONE_GRENADE

new const g_szGrenadeName[][] = {

    "weapon_flashbang", 

    "weapon_hegrenade", 

    "weapon_smokegrenade"

}

#endif

​

​

public plugin_init()

{

    register_plugin("Grenade Explode Modes", VERSION, "Vaqtincha")

​

    #if defined ONLY_ONE_GRENADE

        RegisterHam(Ham_Weapon_SecondaryAttack, ONLY_ONE_GRENADE, "Ham_SecAttack_Post", true)

        RegisterHam(Ham_Item_Deploy, ONLY_ONE_GRENADE, "Ham_ItemDeploy_Post", true)

    #else

    for(new i = 0; i < sizeof(g_szGrenadeName); ++i)

    {

        RegisterHam(Ham_Weapon_SecondaryAttack, g_szGrenadeName[i], "Ham_SecAttack_Post", true)

        RegisterHam(Ham_Item_Deploy, g_szGrenadeName[i], "Ham_ItemDeploy_Post", true)

    }

    #endif

}

​

public Ham_ItemDeploy_Post(wEnt)

{

    new id = get_weapon_owner(wEnt)

    if(id > 0)

    {

        switch(g_iMode[id])

        {

            case NORMAL: return HAM_IGNORED

            case MODE_1: client_print(id, print_center, "Explode after %0.f seconds", EXPLODE_TIME_1)

            #if defined EXPLODE_TIME_2

            case MODE_2: client_print(id, print_center, "Explode after %0.f seconds", EXPLODE_TIME_2)

            #endif

            #if defined EXPLODE_TIME_3

            case MODE_3: client_print(id, print_center, "Explode after %0.f seconds", EXPLODE_TIME_3)

            #endif

            default: return HAM_IGNORED

        }

    }

    return HAM_IGNORED

}

​

public Ham_SecAttack_Post(wEnt)

{

    new id = get_weapon_owner(wEnt)

    if(id > 0 && wEnt > 0 && !HasShield(id))

    {

        ++g_iMode[id]

        switch(g_iMode[id])

        {

            case NORMAL: client_print(id, print_center, "Explode Normal")

            case MODE_1: client_print(id, print_center, "Explode after %0.f seconds", EXPLODE_TIME_1)

            #if defined EXPLODE_TIME_2

            case MODE_2: client_print(id, print_center, "Explode after %0.f seconds", EXPLODE_TIME_2)

            #endif

            #if defined EXPLODE_TIME_3

            case MODE_3: client_print(id, print_center, "Explode after %0.f seconds", EXPLODE_TIME_3)

            #endif

            default:{

                g_iMode[id] = NORMAL

                client_print(id, print_center, "Explode Normal")

            }

        }

        set_pdata_float(id, m_flNextAttack, 0.5)

        set_pdata_float(wEnt, m_flNextSecondaryAttack, 0.5, XO_WEAPON)

    }

    return HAM_IGNORED

}

​

public grenade_throw(id, wEnt, iId)

{

    #if defined ONLY_ONE_GRENADE

    if(iId != get_weaponid(ONLY_ONE_GRENADE))

        return

    #endif

    switch(g_iMode[id])

    {

        case NORMAL: return

        case MODE_1: set_pev(wEnt, pev_dmgtime, get_gametime() + EXPLODE_TIME_1)

        #if defined EXPLODE_TIME_2

        case MODE_2: set_pev(wEnt, pev_dmgtime, get_gametime() + EXPLODE_TIME_2)

        #endif

        #if defined EXPLODE_TIME_3

        case MODE_3: set_pev(wEnt, pev_dmgtime, get_gametime() + EXPLODE_TIME_3)

        #endif

        default: return

    }

}