	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Injector

Теги: Скачать плагины csОстальные

Данный плагин позволяет ввести инъекцию в руку, таким образом пополнив здоровье.
Настройки в исходнике:

#define HEAL 25.0 //Количество здоровья, которое будет восстановлено
#define MAXHEALTH 100.0 //Порог здоровья
#define VIP_AMMO 2 //Количество шприцов для VIP'a
#define PLR_AMMO 1 //Количество шприцов для обычного игрока
#define FLAG ADMIN_LEVEL_H // Флаг VIP'a

Компилятор: 1.8.2 +ZIP 1615

Команды:

Выбрать нож и жать букву G

.sma / .sp

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#pragma semicolon 1

//Настройки
#define HEAL		25.0	//Количество здоровья, которое будет восстановлено
#define MAXHEALTH	100.0	//Порог здоровья
#define VIP_AMMO	2		//Количество шприцов для VIP'a 
#define PLR_AMMO	1		//Количество шприцов для обычного игрока
#define FLAG	ADMIN_LEVEL_H	// Флаг VIP'a

#define ANIM_USE		0
#define OLD_KN_DRAW		3
#define TIME_ANIM_HEAL	2.0
#define TIME_DRAW_KNF	1.1

#define TASK_HEAL		25071973

#define is_valid_player(%0)     (1 <= %0 <= g_maxplayers)
const m_flNextAttack = 83;

new const v_injectorX[]	= "models/v_injectorX.mdl"; // v_ модель шприца
new const p_injectorX[]	= "models/p_injectorX.mdl"; // p_ модель шприца

new const v_old_knife[]	= "models/v_knife.mdl"; // v_ модель ножа, которая возвращается после использования 
new const p_old_knife[]	= "models/p_knife.mdl"; // p_ модель ножа, которая возвращается после использования
											   // Если несколько моделей ножа, то возвращайте модель через натив!
new const heal_sound[]	= { "items/medshot4.wav" };	// Звук при лечении

new shpr_ammo[33];
new g_maxplayers;

public plugin_init()
{	
	register_plugin("Injector X", "1.0", "Deadly|Darkness");
	register_clcmd("drop", "use_inj");
	
	RegisterHam(Ham_Spawn, "player", "ham_spawn_post", 1);
	RegisterHam(Ham_Item_Holster, "weapon_knife", "fw_Knife_Holstered", 1);
	
	g_maxplayers = get_maxplayers();
}

public plugin_precache() 
{
	precache_model(v_injectorX);
	precache_model(p_injectorX);
	precache_model(v_old_knife);
	precache_model(p_old_knife);
	precache_sound(heal_sound);

}

public ham_spawn_post(id)
{
	if(get_user_flags(id) & FLAG)
		shpr_ammo[id] = VIP_AMMO;
		
	else shpr_ammo[id] = PLR_AMMO;
}

public use_inj(id)
{
	if(!is_user_alive(id))
		return;

if(get_user_weapon(id) != CSW_KNIFE || !shpr_ammo[id])
		return;
		
	remove_task(id+TASK_HEAL);
	set_pdata_float(id, m_flNextAttack, TIME_ANIM_HEAL+0.1, 5);

set_pev(id, pev_viewmodel2, v_injectorX);
	set_pev(id, pev_weaponmodel2, p_injectorX);

play_weapon_animation(id, ANIM_USE);
	set_task(TIME_ANIM_HEAL, "use_inj2", id+TASK_HEAL);
	
}

public use_inj2(id)
{
	id -= TASK_HEAL;

if(is_user_alive(id))
	{
		shpr_ammo[id]--;
		set_pev(id, pev_viewmodel2, v_old_knife);
		set_pev(id, pev_weaponmodel2, p_old_knife);
		set_pdata_float(id, m_flNextAttack, TIME_DRAW_KNF, 5);
		play_weapon_animation(id, OLD_KN_DRAW);
		set_hp(id);
	}
}

public fw_Knife_Holstered(weapon)
{
	new id = get_pdata_cbase(weapon, 41, 4);
	
	if(!pev_valid(weapon))
		return HAM_IGNORED;

if(is_valid_player(id))
		remove_task(id+TASK_HEAL);
	
	return HAM_IGNORED;

}

stock set_hp(plr)
{
	new hp = pev(plr, pev_health);

if(hp < MAXHEALTH)
	{
		if(hp + HEAL > MAXHEALTH)
			set_pev(plr, pev_health, MAXHEALTH);
		else set_pev(plr, pev_health, hp + HEAL);
		emit_sound(plr, CHAN_BODY, heal_sound, 1.0, ATTN_NORM, 0, PITCH_NORM);
	}
}

stock play_weapon_animation(const Player, const Sequence)
{
	set_pev(Player, pev_weaponanim, Sequence);
	
	message_begin(MSG_ONE_UNRELIABLE, SVC_WEAPONANIM, .player = Player);
	write_byte(Sequence);
	write_byte(pev(Player, pev_body));
	message_end();
}

Загрузил Vladislav2004

2022-03-27 00:03:42

433

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram