	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Kill Assist

Теги: Скачать плагины cs

Добавляет на сервер возможность стать ассистентом при убийстве и получить за это фраги/деньги.
Чтобы стать ассистентом, нужно нанести по жертве больше урона, чем убийца.
Пример: Вася убил Федю. Рядом стоял тиммейт Петя и тоже стрелял по Феде. Если Вася нанёс 40 урона, а Петя 60, то считается убийство как совместное. А вот если Вася нанёс 70 урона, а Петя только 30, то Петя в пролёте.
Выглядит уведомление о совместном убийстве тоже по-человечески. В правом верхнем углу экрана, где показывается кто кого убил, ассистент будет дописан через плюс.

Компилятор: 1.8.2 Multibild REapi 1633

Команды:

Настройки в исходнике:

PHP:

#define MONEY 300 // Выдавать $$

#define FRAG // +1 фраг

//#define SUPPORT_CSSTATS_MYSQL // Защитать фраг в статистику плагина от скальпеля

//#define SUPPORT_AES_EXP // Выдавать опыт

.sma / .sp

#include <amxmodx>
#include <reapi>

#define MONEY 300		// Выдавать $$
#define FRAG			// +1 фраг
//#define SUPPORT_CSSTATS_MYSQL	// Защитать фраг в статистику плагина от скальпеля
//#define SUPPORT_AES_EXP	// Выдавать опыт

#if !defined MAX_PLAYERS
	const MAX_PLAYERS = 32;
#endif
#if !defined MAX_NAME_SIZE
	const MAX_NAME_SIZE = 32;
#endif
#if defined SUPPORT_CSSTATS_MYSQL
	native csstats_set_user_value(index, ident, value);
	native csstats_get_user_value(index, ident);
#endif
#if defined SUPPORT_AES_EXP
	native aes_add_player_exp(id,exp,override = 0);
#endif
	
//                            who's             whom
new Float:g_playerDamage[MAX_PLAYERS + 1][MAX_PLAYERS + 1];
new HookChain:g_deathNoticePostHook;

public plugin_init() {
	register_plugin("KiLL Assist", "poka_4to_beta", "PRoSToTeM@"); // edited by neugomon
	
//	if(!is_regamedll() || !is_rehlds())
//		set_fail_state("Needs CS ReGameDLL and ReHLDS");
   
	RegisterHookChain(RG_CBasePlayer_Spawn, "OnPlayerSpawn_Post", true);
	RegisterHookChain(RG_CBasePlayer_TakeDamage, "OnPlayerTakeDamage_Post", true);
	RegisterHookChain(RG_CSGameRules_DeathNotice, "OnDeathNotice", false);
	DisableHookChain((g_deathNoticePostHook = RegisterHookChain(RG_CSGameRules_DeathNotice, "OnDeathNotice_Post", true)));
}

public client_connect(playerEntIndex)
	arrayset(_:g_playerDamage[playerEntIndex], 0, sizeof(g_playerDamage[]));

public OnPlayerSpawn_Post(playerEntIndex)
	for(new i = 1; i <= MAX_PLAYERS; i++)
		g_playerDamage[i][playerEntIndex] = 0.0;

public OnPlayerTakeDamage_Post(playerEntIndex, inflictorEntIndex, attackerEntIndex, Float:damage, damageType)
{
	if(
		attackerEntIndex != playerEntIndex && 
		is_user_connected(attackerEntIndex) &&
		rg_is_player_can_takedamage(attackerEntIndex, playerEntIndex)
	) g_playerDamage[attackerEntIndex][playerEntIndex] += damage;
}

public OnDeathNotice(victimEntIndex, killerEntIndex, inflictorEntIndex)
{
	if(
		killerEntIndex != victimEntIndex && 
		is_user_connected(killerEntIndex) && 
		rg_is_player_can_takedamage(killerEntIndex, victimEntIndex)
	)
	{
		new bestAttackerEntIndex = 0;
		for (new i = 1, Float:maxDamage; i <= MAX_PLAYERS; i++) {
			if (g_playerDamage[i][victimEntIndex] > maxDamage) {
				maxDamage = g_playerDamage[i][victimEntIndex];
				bestAttackerEntIndex = i;
			}
		}
		// Assistant must have more damage than killer
		if(
			bestAttackerEntIndex != killerEntIndex && 
			is_user_connected(bestAttackerEntIndex) && 
			rg_is_player_can_takedamage(bestAttackerEntIndex, victimEntIndex) &&
			get_member(bestAttackerEntIndex, m_iTeam) != TEAM_SPECTATOR
		)
		{
			new name1[MAX_NAME_SIZE], name2[MAX_NAME_SIZE], name[MAX_NAME_SIZE];
			get_entvar(killerEntIndex, var_netname, name1, charsmax(name1));
			get_entvar(bestAttackerEntIndex, var_netname, name2, charsmax(name2));
		#if defined MONEY
			rg_add_account(bestAttackerEntIndex, MONEY);
		#endif
		#if defined FRAG
			set_entvar(bestAttackerEntIndex, var_frags, Float:get_entvar(bestAttackerEntIndex, var_frags) + 1.0);
		#endif
		#if defined SUPPORT_CSSTATS_MYSQL		
			csstats_set_user_value(bestAttackerEntIndex, 0, csstats_get_user_value(bestAttackerEntIndex, 0) + 1);
		#endif
		#if defined SUPPORT_AES_EXP
			aes_add_player_exp(bestAttackerEntIndex, 1);
		#endif
			// TODO: cut nicknames if big length (> 14) and add ...
			// TODO: UTF-8 cut correctly
			if(strlen(name1) + strlen(name2) > 28) {
				formatex(name, charsmax(name), "%.14s + %.14s", name1, name2);
			} else {
				formatex(name, charsmax(name), "%s + %s", name1, name2);
			}
		   
			message_begin(MSG_ALL, SVC_UPDATEUSERINFO);
			write_byte(killerEntIndex - 1);
			write_long(get_user_userid(killerEntIndex));
			write_char('\');
			write_char('n');
			write_char('a');
			write_char('m');
			write_char('e');
			write_char('\');
			write_string(name);
			for(new i = 0; i < 16; i++)
				write_byte(0);
			message_end();

EnableHookChain(g_deathNoticePostHook);
		}
	}
}

public OnDeathNotice_Post(victimEntIndex, killerEntIndex, inflictorEntIndex)
{
	rh_update_user_info(killerEntIndex);
	DisableHookChain(g_deathNoticePostHook);
}

Загрузил Varder

2018-10-25 20:05:32

190

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram