	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

KnifeBot Detector 0.9.9

Теги: Скачать плагины csАдминские

Плагин для обнаружения любого вида KnifeBot'a. Банить не умеет, только сообщение в чат.

.sma
#define INIT_RECHECK 0.5
#define CHECK_TIME 0.2
#define RECHECK_TIME 3.0 // время перепроверки игрока
#define MAX_WARNIGNS 3
#define BOT_RECREATE 20
#define BOT_RENAME 64

new const DEFAULT_NAMES[][] =
{
"" // ОБЯЗАТЕЛЬНО УСТАНОВИТЕ СВОЙ НИК!!!
//, "second name"
//, "third name"
// etc...
};

#define CHANGE_BOT_TEAM // подставление противоположной команды боту перед проверкой
#define RANDOM_ANGLES // спавнить бота в рандомном месте перед игроком

Компилятор: 1.8.2 919

Команды:

Кваров и команд нет

.sma / .sp

/*
Credits:
p3tsin - bot stuff
shel - detect idea
s1lent - help with engine
*/
#include <amxmodx>
#include <cstrike>
#include <engine>
#include <fun>
#include <fakemeta>
#include <hamsandwich>
#include <xs>

#define PLUGIN "KnifeBot Detector"
#define VERSION "0.9.9"
#define AUTHOR "Mistrick"

#pragma semicolon 1

#define INIT_RECHECK 0.5
#define CHECK_TIME 0.2
#define RECHECK_TIME 3.0
#define MAX_WARNIGNS 3
#define BOT_RECREATE 20
#define BOT_RENAME 64

new const DEFAULT_NAMES[][] =
{
	""
	//, "second name"
	//, "third name"
	// etc...
};

#define CHANGE_BOT_TEAM
//#define RANDOM_ANGLES

#define LOGFILE "knifebot_detector.log"

#define CLASS_NONE 0

new g_BotIndex, g_bInChecking, g_Target, g_iAttacks, g_iAttacks2, g_iWarnings[33];

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	RegisterHam(Ham_Spawn, "player", "Ham_PlayerSpawn_Post", .Post = true);
	RegisterHam(Ham_Classify, "player", "Ham_PlayerClassify_Pre", .Post = false);
	RegisterHam(Ham_Player_PreThink, "player", "Ham_PlayerPreThink_Pre", .Post = false);
	register_forward(FM_AddToFullPack, "FM_AddToFullPack_Pre", ._post = false);
	register_message(get_user_msgid("SayText"), "Message_SayText");
}
CreateBot()
{
	if(!DEFAULT_NAMES[0][0])
	{
		set_fail_state("Set own valid bot name!");
	}
	
	new bot = g_BotIndex = engfunc(EngFunc_CreateFakeClient, DEFAULT_NAMES);
	
	if(!bot)
	{
		return PLUGIN_HANDLED;
	}

engfunc(EngFunc_FreeEntPrivateData, bot);
	dllfunc(MetaFunc_CallGameEntity, "player", bot);
	bot_settings(bot);

new reject_reason[128];
	dllfunc(DLLFunc_ClientConnect, bot, DEFAULT_NAMES, "127.0.0.1", reject_reason);
	
	if(!is_user_connected(bot))
	{
		return PLUGIN_HANDLED;
	}

dllfunc(DLLFunc_ClientPutInServer, bot);
	cs_set_user_team(bot, CS_TEAM_SPECTATOR);
	ExecuteHamB(Ham_CS_RoundRespawn, bot);
	set_user_rendering(g_BotIndex, kRenderFxGlowShell, 0, 0, 0, kRenderTransAlpha, 0);
	
	return PLUGIN_HANDLED;
}
bot_settings(id)
{
	set_user_info(id, "bottomcolor", "6");
	set_user_info(id, "model", "gordon");
	set_user_info(id, "rate", "8000");
	set_user_info(id, "cl_updaterate", "45");
	set_user_info(id, "cl_lw", "1");
	set_user_info(id, "cl_lc", "1");
	set_user_info(id, "cl_dlmax", "128");
	set_user_info(id, "_ah", "0");
	set_user_info(id, "_cl_autowepswitch", "1");
	set_user_info(id, "_vgui_menus", "0");
}
bot_rename()
{
	#if sizeof(DEFAULT_NAMES) > 1
	static last;
	new new_name;
	while(last == (new_name = random(sizeof(DEFAULT_NAMES)))){}
	set_user_info(g_BotIndex, "name", DEFAULT_NAMES[new_name]);
	last = new_name;
	#endif
}

public client_putinserver(id)
{
	if(is_user_bot(id)) return;
	
	static connections = 0;
	
	g_iWarnings[id] = 0;
	
	if(!(connections % BOT_RECREATE))
	{
		if(is_user_connected(g_BotIndex))
		{
			server_cmd("kick #%d", get_user_userid(g_BotIndex));
			server_exec();
		}
		CreateBot();
	}
	connections++;
}

public Message_SayText(msgid, msgdest, id)
{
	if(get_msg_args() == 4 && get_msg_arg_int(1) == g_BotIndex)
	{
		return PLUGIN_HANDLED;
	}
	return PLUGIN_CONTINUE;
}

public Ham_PlayerSpawn_Post(id)
{
	if(!is_user_alive(id) || id == g_BotIndex || !is_user_connected(g_BotIndex)) return HAM_IGNORED;
	
	if(!task_exists(id))
	{
		InitChecking(id);
	}
	
	return HAM_IGNORED;
}

public Ham_PlayerClassify_Pre(id)
{
	if(id == g_BotIndex)
	{
		SetHamReturnInteger(CLASS_NONE);
		return HAM_SUPERCEDE;
	}
	return HAM_IGNORED;
}

public Ham_PlayerPreThink_Pre(id)
{
	if(g_Target != id || get_user_weapon(id) != CSW_KNIFE) return HAM_IGNORED;
	
	new buttons = pev(id, pev_button);
	new oldbuttons = pev(id, pev_oldbuttons);
	
	if(buttons & IN_ATTACK && ~oldbuttons & IN_ATTACK)
	{
		g_iAttacks++;
	}
	if(buttons & IN_ATTACK2 && ~oldbuttons & IN_ATTACK2)
	{
		g_iAttacks2++;
	}
	
	new Float:origin[3];
	#if defined RANDOM_ANGLES
	get_front_origin(id, random_float(48.0, 54.0), origin, random_float(-45.0, 45.0));
	#else
	get_front_origin(id, random_float(48.0, 54.0), origin);
	#endif // RANDOM_ANGLES
	engfunc(EngFunc_SetOrigin, g_BotIndex, origin);
	
	return HAM_IGNORED;
}

public FM_AddToFullPack_Pre(es, e, ent, host, flags, player, pSet)
{
	if(player && host != ent && host != g_Target && ent == g_BotIndex)
	{
		forward_return(FMV_CELL, 0);
		return FMRES_SUPERCEDE;
	}
	return FMRES_IGNORED;
}

public InitChecking(id)
{
	if(g_bInChecking)
	{
		//server_print("init recheck %d", id);
		set_task(INIT_RECHECK, "InitChecking", id);
		return;
	}
	if(is_near_other_player(id))
	{
		//server_print("near other player, init recheck %d", id);
		set_task(RECHECK_TIME, "InitChecking", id);
		return;
	}
	g_bInChecking = true;
	g_Target = id;
	set_task(0.1, "StartCheckKB", id);
	//server_print("init check %d", id);
}

is_near_other_player(id)
{
	new players[32], pnum;
	get_players(players, pnum, "ac");
	new alive = is_user_alive(id);
	for(new i, player; i < pnum; i++)
	{
		player = players[i];
		if(player != id && alive && get_entity_distance(id, player) < 80)
		{
			return true;
		}
	}
	return false;
}

public StartCheckKB(id)
{
	if(!is_user_alive(id))
	{
		reset_checking();
		return;
	}
	
	//server_print("start check %d", id);
	if(!is_user_alive(g_BotIndex))
	{
		ExecuteHam(Ham_CS_RoundRespawn, g_BotIndex);
	}

set_pev(g_BotIndex, pev_health, 100.0);
	set_pev(g_BotIndex, pev_solid, SOLID_SLIDEBOX);
	set_pev(g_BotIndex, pev_takedamage, DAMAGE_NO);
	set_pev(g_BotIndex, pev_movetype, MOVETYPE_PUSHSTEP);

#if defined CHANGE_BOT_TEAM
	switch(cs_get_user_team(id))
	{
		case CS_TEAM_T: cs_set_user_team(g_BotIndex, CS_TEAM_CT, CS_CT_GIGN);
		case CS_TEAM_CT: cs_set_user_team(g_BotIndex, CS_TEAM_T, CS_T_TERROR);
	}
	#endif // CHANGE_BOT_TEAM
	
	new Float:origin[3];
	#if defined RANDOM_ANGLES
	get_front_origin(id, random_float(50.0, 54.0), origin, random_float(-45.0, 45.0));
	#else
	get_front_origin(id, random_float(50.0, 54.0), origin);
	#endif // RANDOM_ANGLES
	engfunc(EngFunc_SetOrigin, g_BotIndex, origin);
	
	static rename = 0;
	if(!(++rename % BOT_RENAME))
	{
		bot_rename();
	}
	
	set_task(CHECK_TIME, "EndCheckKB", id);
}

public EndCheckKB(id)
{
	if(!is_user_alive(id))
	{
		reset_checking();
		return;
	}
	
	//server_print("ent check %d", id);
	
	if(g_iAttacks || g_iAttacks2)
	{
		UTIL_LogUser(id, "Add warn: atk1 %d, atk2 %d", g_iAttacks, g_iAttacks2);
		//server_print("add warn, hp warn %d, a1 %d, a2 %d, id %d", warn_hp, g_iAttacks, g_iAttacks2, id);
		if(++g_iWarnings[id] >= MAX_WARNIGNS)
		{
			g_iWarnings[id] = 0;
			Panishment(id);
		}
	}
	else if(g_iWarnings[id])
	{
		g_iWarnings[id]--;
	}
	
	reset_checking();
	
	set_task(random_float(RECHECK_TIME - 0.5, RECHECK_TIME + 0.5), "InitChecking", id);
}

reset_checking()
{
	g_bInChecking = false;
	g_Target = 0;
	g_iAttacks = 0;
	g_iAttacks2 = 0;

set_pev(g_BotIndex, pev_solid, SOLID_NOT);
	set_pev(g_BotIndex, pev_takedamage, DAMAGE_AIM);
	set_pev(g_BotIndex, pev_movetype, MOVETYPE_NONE);

#if defined CHANGE_BOT_TEAM
	cs_set_user_team(g_BotIndex, CS_TEAM_SPECTATOR);
	#endif // CHANGE_BOT_TEAM
}

Panishment(id)
{
	new name[32]; get_user_name(id, name, charsmax(name));
	client_print(0, print_chat, "[KBDetector] Player %s using KnifeBot!", name);
	UTIL_LogUser(id, "Player panished for knife bot!");
}

stock get_front_origin(id, Float:dist, Float:origin[3], Float:angle = 0.0)
{
	new iVectorStart[3]; get_user_origin(id, iVectorStart, 1);
	new iVectorEnd[3]; get_user_origin(id, iVectorEnd, 3);
	new Float:fVectorStart[3]; IVecFVec(iVectorStart, fVectorStart);
	new Float:fVectorEnd[3]; IVecFVec(iVectorEnd, fVectorEnd);
	
	new Float:fAddVec[3]; xs_vec_sub(fVectorEnd, fVectorStart, fAddVec);
	fAddVec[2] = 0.0;
	xs_vec_normalize(fAddVec, fAddVec);
	
	new Float: velocity[3];
	pev(id, pev_velocity, velocity);
	velocity[2] = 0.0;
	
	new Float:vec_angle = vectors_angle(fAddVec, velocity);
	if(vec_angle < 80.0)
	{
		dist += vector_length(velocity) * 0.06;
	}
	
	xs_vec_mul_scalar(fAddVec, dist, fAddVec);
	
	if(angle != 0.0)
	{
		fAddVec = vec_rotation(fAddVec, angle);
	}
	
	pev(id, pev_origin, origin);
	xs_vec_add(origin, fAddVec, origin);
}

stock Float:vec_rotation(Float:vec[3], Float:angle)
{
	new Float:out[3];
	out[0] = vec[0] * floatcos(angle, degrees) - vec[1] * floatsin(angle, degrees);
	out[1] = vec[0] * floatsin(angle, degrees) + vec[1] * floatcos(angle, degrees);
	out[2] = vec[2];
	return out;
}

stock Float:vectors_angle(Float:v1[3], Float:v2[3])
{ 
    return floatacos( (v1[0]*v2[0]+v1[1]*v2[1])/(floatsqroot(v1[0]*v1[0]+v1[1]*v1[1])*floatsqroot(v2[0]*v2[0]+v2[1]*v2[1])), degrees);
}

stock UTIL_LogUser(const id, const szCvar[], any:...)
{
	static log_file[128];
	if(!log_file[0])
	{
		get_localinfo("amxx_logs", log_file, charsmax(log_file));
		format(log_file, charsmax(log_file), "/%s/%s", log_file, LOGFILE);
	}
	new file;
	if( (file = fopen(log_file, "a")) )
	{
		new name[32], authid[32], ip[32], time[22];
		new message[128]; vformat(message, charsmax(message), szCvar, 3);
		
		get_user_name(id, name, charsmax(name));
		get_user_authid(id, authid, charsmax(authid));
		get_user_ip(id, ip, charsmax(ip), 1);
		get_time("%m/%d/%Y - %H:%M:%S", time, charsmax(time));
		
		fprintf(file, "L %s: <%s><%s><%s> %s^n", time, name, authid, ip, message);
		fclose(file);
	}
}

Загрузил ADEPT

2020-02-23 20:10:05

Скачать

91.211.118.38:27015

УКРАЇНСЬКИЙ - P U B L I C - [ UP-CS.TOP ] - [ 18+ ]

195.211.60.214:27015

195.211.60.214:27017

CSHOST.COM.UA |REHLDS|

195.211.60.214:27018

УКРАЇНА - Б А Н Д Е Р Ш Т А Т - [2000 FPS] 18+

91.211.118.156:27071

195.211.60.214:27016

УКРАЇНСЬКІ - ДІВЧАТА - [ RYZEN 9 - 5.7 GHZ ]

91.211.118.49:27030

К І Б О Р Г И - У К Р А Ї Н И [RYZEN 9 - 4.7 GHZ]

91.211.118.49:27037

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram