Look At Your Mode

#pragma semicolon 1

​

#include <sourcemod>

#include <sdktools_functions>

#include <sdktools_entinput>

#include <sdktools_engine>

​

public Plugin:myinfo = 

{

    name    = "Look At Your Model",

    author  = "wS",

    url     = "http://world-source.ru/",

    version = "1.0"

};

​

new Handle:g_hOnLookStartPre;

new Handle:g_hOnLookStartPost;

new Handle:g_hOnLookEnd;

​

new g_hRef[MAXPLAYERS + 1] = {INVALID_ENT_REFERENCE, ...};

​

public OnPluginStart()

{

    g_hOnLookStartPre  = CreateForward(ET_Event,  Param_Cell);

    g_hOnLookStartPost = CreateForward(ET_Ignore, Param_Cell);

    g_hOnLookEnd       = CreateForward(ET_Ignore, Param_Cell);

    HookEvent("player_death", StopLookEvent, EventHookMode_Post);

    HookEvent("player_team",  StopLookEvent, EventHookMode_Post);

    HookEvent("player_spawn", StopLookEvent, EventHookMode_Post);

    RegConsoleCmd("sm_look",  LookModelCmd);

}

​

public OnMapStart()

{

    PrecacheModel("models/error.mdl");

}

​

public APLRes:AskPluginLoad2(Handle:myself, bool:late, String:error[], err_max)

{

    RegPluginLibrary("look_at_your_model");

    CreateNative("HookLookModel",   HookLookModel_);

    CreateNative("LookModel",       LookModel_);

    return APLRes_Success;

}

​

public HookLookModel_(Handle:plugin, args)

{

    decl Function:func;

    if ((func = Function:GetNativeCell(1)) != INVALID_FUNCTION)

    {

        RemoveFromForward(g_hOnLookStartPre,    plugin, func);

        AddToForward(g_hOnLookStartPre,         plugin, func);

    }

    if ((func = Function:GetNativeCell(2)) != INVALID_FUNCTION)

    {

        RemoveFromForward(g_hOnLookStartPost,   plugin, func);

        AddToForward(g_hOnLookStartPost,        plugin, func);

    }

    if ((func = Function:GetNativeCell(3)) != INVALID_FUNCTION)

    {

        RemoveFromForward(g_hOnLookEnd,         plugin, func);

        AddToForward(g_hOnLookEnd,              plugin, func);

    }

}

​

public LookModel_(Handle:plugin, args)

{

    return g_hRef[GetNativeCell(1)] != INVALID_ENT_REFERENCE;

}

​

public Action:LookModelCmd(client, args)

{

    if (client > 0 && client <= MaxClients && IsPlayerAlive(client) && !StopLook(client))

    {

        new Action:result = Plugin_Continue;

        Call_StartForward(g_hOnLookStartPre);

        Call_PushCell(client);

        Call_Finish(result);

        if (result != Plugin_Continue)

            return Plugin_Handled;

​

        //

        new entity = CreateEntityByName("prop_dynamic");

        if (entity <= MaxClients)

            return Plugin_Handled;

        g_hRef[client] = EntIndexToEntRef(entity);

        DispatchKeyValue(entity, "model", "models/error.mdl");

        DispatchKeyValue(entity, "solid", "0");

        //DispatchKeyValue(entity, "spawnflags", "256");

        decl Float:v[3];

        GetClientEyePosition(client, v);

        decl Float:a[3];

        GetClientAbsAngles(client, a);

        a[0] = 0.0;

        a[2] = 0.0;

        decl Float:direction[3];

        GetAngleVectors(a, direction, NULL_VECTOR, NULL_VECTOR);

        v[0] += direction[0] * 100.0;

        v[1] += direction[1] * 100.0;

        DispatchKeyValueVector(entity, "origin", v);

        a[1] += 180.0;

        DispatchKeyValueVector(entity, "angles", a);

        DispatchSpawn(entity);

        SetEntityRenderMode(entity, RENDER_TRANSCOLOR);

        SetEntityRenderColor(entity, 255, 255, 255, 0);

        //

        SetEntPropEnt(client, Prop_Send, "m_hObserverTarget", 0);

        SetEntProp(client, Prop_Send, "m_iObserverMode", 1);

        SetEntProp(client, Prop_Send, "m_bDrawViewmodel", 0);

        SetEntProp(client, Prop_Send, "m_iFOV", 50);

        SetEntityMoveType(client, MOVETYPE_NONE);

        SetClientViewEntity(client, entity);

        //

        Call_StartForward(g_hOnLookStartPost);

        Call_PushCell(client);

        Call_Finish();

    }

    return Plugin_Handled;

}

​

stock bool:StopLook(client, bool:disconnect = false)

{

    if (g_hRef[client] == INVALID_ENT_REFERENCE)

        return false;

    if ((g_hRef[client] = EntRefToEntIndex(g_hRef[client])) > MaxClients)

        AcceptEntityInput(g_hRef[client], "Kill");

    g_hRef[client] = INVALID_ENT_REFERENCE;

    if (!disconnect)

    {

        SetClientViewEntity(client, client);

        SetEntityMoveType(client, MOVETYPE_WALK);

        SetEntPropEnt(client, Prop_Send, "m_hObserverTarget", -1);

        SetEntProp(client, Prop_Send, "m_iObserverMode", 0);

        SetEntProp(client, Prop_Send, "m_bDrawViewmodel", 1);

        SetEntProp(client, Prop_Send, "m_iFOV", 90);

    }

    Call_StartForward(g_hOnLookEnd);

    Call_PushCell(client);

    Call_Finish();

​

    return true;

}

​

public OnClientDisconnect(client)

{

    StopLook(client, true);

}

​

public StopLookEvent(Handle:event, const String:name[], bool:silent)

{

    StopLook(GetClientOfUserId(GetEventInt(event, "userid")));

}