	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Magic Heroes (Магические герои) (Privat-Приват)

Теги: Скачать плагины csМодели

Описание: плагин добавляет на сервер выбор из шести героев, каждый из которых имеет свою уникальную способность.

В течение игрового времени копится энергия, при достижении определённого её кол-ва (настраивается в исходнике) открывается возможность использовать способность, энергия продолжает расти до еще одного определённого кол-ва (также настраивается в исходнике), чем больше энергии, тем сильнее способность.

Описание героев:
1) Берсеркер (увеличивает на N сек. скорость в N раз, а также скорость атаки в N раз)
2) Друид (регенерирует здоровье в течение N секунд, а также получает иммунитет на активации некоторых способностей)
3) Череп (увеличивает свою атаку в N раз, а также ограничивает получаемый урон до N единиц)
4) Дрейк (стреляет бомбой, которая при попадании в игрока вводит его в стан, не давая двигаться и атаковать на N секунд и наносит N урона (Друид при активации своего скилла защищён от этого скилла, а также Берсеркер, активировав свою способность, разбивает узы магии Дрейка))
5) Влад Дракула (вызывает рой летучих мышей, которые кусают противников в радиусе N юнитов от игрока: наносят N урона и возвращают владельцу N/M здоровья от укусов противников).
6) Бог Грома (призывает природную стихию, после чего происходит удар молнии в область направления прицела; враги, попавшие в радиус (N) действия удара молнии, получают N урона и отбрасываются в сторону).

Каждый герой имеет свою способность, подсветку при активации способности, а также определенный звук, который сопровождает используемую способность.
Все настройки находятся в исходнике с комментариями

Компилятор: 1.8.2 +ZIP 1189

Команды:

Команды вызова смены героя:

say /hero

say_team /hero

say /heroes"

say_team /heroes

hero_menu

heroes_menu

Настройки:

[spoiler]

/* =====================================================================

************************** Общие настройки **************************

===================================================================== */

const VIP_FLAG = ADMIN_LEVEL_H; // Флаг випа

const Float: ADD_ENERGY = 1.9; // Кол-во пополняемой энергии для игроков

const Float: ADD_ENERGY_VIP = 3.8; // Кол-во пополняемой энергии для випов

const Float: PERIOD_ADD_ENERGY = 0.8; // Период пополнения энергии

const Float: ACTIVE_ENERGY = 50.4; // Кол-во энергии, при которой будет доступна способность (чем выше энергия, тем сильнее скилл)

const Float: MAX_ENERGY = 99.9; // Максимальное кол-во энергии для игроков

const Float: MAX_ENERGY_VIP = 120.5; // Максимальное кол-во энергии для випов

new const PREFIX_INFO[] = "Магические герои"; // Префикс (в меню, в чате, в худе)

new const HEROES_INFO[][] = // Названия героев

{

"Берсеркер",

"Друид",

"Череп",

"Капитан Дрейк",

"Влад Дракула",

"Бог Грома"

};

new const ABILITIES_INFO[][] = // Способности героев

{

"ускорение",

"восстановление",

"усиление",

"оглушение",

"вампиризм",

"молния"

};

/* =====================================================================

*********************************************************************

===================================================================== */

/* =====================================================================

********************** Индивидуальные настройки **********************

===================================================================== */

// Берсеркер

const Float: BERSERKER_SPEED_MUL = 1.2; // начальный множитель скорости [стандарт: 1.2]

const Float: BERSERKER_SPEED_ATTACK_MUL = 0.3; // начальный множитель скорости атаки [стандарт: 0.3]

const Float: BERSERKER_TIME_ABILITY = 3.8; // начальное время действия способности

// Друид

const Float: DRUID_REGEN_HP = 2.1; // начальный множитель пополняемого здоровья

const Float: DRUID_PERIOD_HP = 0.7; // начальный период пополнения ХП

const Float: DRUID_TIME_ABILITY = 4.7; // начальное время действия способности

// Череп

const Float: SKULL_DAMAGE_LIMIT = 20.0; // до скольки ХП ограничивается урон (начальный лимит)

const Float: SKULL_DAMAGE_ATTACK = 1.4; // начальный множитель урона

const Float: SKULL_TIME_ABILITY = 4.1; // начальное время действия способности

// Дрейк

const Float: DREIK_BOMB_VELOCITY = 1000.0; // начальная скорость броска бомбы

const Float: DREIK_BOMB_RADUIS = 100.0; // начальный радиус зоны действия бомбы

const Float: DREIK_BOMB_DAMAGE = 15.0; // начальный урон при попадании бомбой

const Float: DREIK_BOMB_STAN_TIME = 1.1; // начальный стан при попадании бомбой

// Влад Дракула

const Float: DRAKULA_BATS_LIFE = 3.9; // начальное время сущестоввания летучих мышей

const Float: DRAKULA_BATS_RADIUS = 100.0; // начальный радиус действия летучих мышей

const Float: DRAKULA_BATS_DAMAGE = 4.3; // начальный урон от действия летучих мышей (в сек)

const Float: DRAKULA_BATS_VAMPIR = 0.2; // начальный умножаемый коэффициент пополняемого здоровья (от урона летучих мышей)

// Бог грома

const Float: THUNDER_LIGHTING_RADIUS = 100.0; // начальный радиус действия атаки молнией

const Float: THUNDER_LIGHTING_DAMAGE = 19.0; // начальный урон от атаки молнией

/* =====================================================================

*********************** *********************** **********************

===================================================================== */

[/[spoiler]]

.sma / .sp

// Плагин by 6u3oH [vk.com/6u3oh]
// Актуальные новости: vk.com/plugins_store
// Magic Heroes

#include <amxmodx>
#include <colorchat>
#include <engine>
#include <fakemeta>
#include <hamsandwich>

const TASK_BERSERK = 0x13741;
const TASK_DRUID = 0x13841;
const TASK_SKULL = 0x13941;
const TASK_STAN = 0x14101;
const ACTIVE_BUTTON = IN_USE;
const WEAPON_OWNER = 41;
const WEAPON_ID = 4;
const WEAPON_ATTACK = 46;
const WEAPON_CURRENT = 373;
new const BOMB_MODEL[] = "models/magic_heroes/bomb.mdl";
new const BATS_MODEL[] = "models/magic_heroes/bats.mdl";
new const ENERGY_SOUND[] = "magic_heroes/energy";
new const BERSERK_SOUND[] = "magic_heroes/berserk.wav";
new const DRUID_SOUND[] = "magic_heroes/druid.wav";
new const SKULL_SOUND[] = "magic_heroes/skull.wav";
new const STAN_SOUND[] = "magic_heroes/stan.wav";
new const BATS_SOUND[] = "magic_heroes/bats.wav";
new const THUNDER_SOUND[] = "magic_heroes/thunder.wav";

/* =====================================================================
 **************************  Общие настройки **************************
===================================================================== */
const VIP_FLAG = ADMIN_LEVEL_H; // Флаг випа
const Float: ADD_ENERGY = 1.9; // Кол-во пополняемой энергии для игроков
const Float: ADD_ENERGY_VIP = 3.8; // Кол-во пополняемой энергии для випов
const Float: PERIOD_ADD_ENERGY = 0.8; // Период пополнения энергии
const Float: ACTIVE_ENERGY = 50.4; // Кол-во энергии, при которой будет доступна способность (чем выше энергия, тем сильнее скилл)
const Float: MAX_ENERGY = 99.9; // Максимальное кол-во энергии для игроков
const Float: MAX_ENERGY_VIP = 120.5; // Максимальное кол-во энергии для випов

new const PREFIX_INFO[] = "Магические герои"; // Префикс (в меню, в чате, в худе)

new const HEROES_INFO[][] = // Названия героев
{
	"Берсеркер",
	"Друид",
	"Череп",
	"Капитан Дрейк",
	"Влад Дракула",
	"Бог Грома"
};

new const ABILITIES_INFO[][] = // Способности героев
{
	"ускорение",
	"восстановление",
	"усиление",
	"оглушение",
	"вампиризм",
	"молния"
};

new const MODELS_KNIFE_VIEW[][] = // v_ Модели ножей
{
	"models/magic_heroes/v_berserk.mdl",
	"models/magic_heroes/v_druid.mdl",
	"models/magic_heroes/v_skull.mdl",
	"models/magic_heroes/v_dreik.mdl",
	"models/magic_heroes/v_drakula.mdl",
	"models/magic_heroes/v_thunder.mdl"
};

new const MODELS_KNIFE_WEAPON[][] = // v_ Модели ножей
{
	"models/magic_heroes/p_berserk.mdl",
	"models/magic_heroes/p_druid.mdl",
	"models/magic_heroes/p_skull.mdl",
	"models/magic_heroes/p_dreik.mdl",
	"models/magic_heroes/p_drakula.mdl",
	"models/magic_heroes/p_thunder.mdl"
};

/* =====================================================================
 **************************  *************** **************************
===================================================================== */

/* =====================================================================
 **********************  Индивидуальые настройки **********************
===================================================================== */

// Берсеркер
const Float: BERSERKER_SPEED_MUL = 1.2; // начальный множитель скорости [стандарт: 1.2]
const Float: BERSERKER_SPEED_ATTACK_MUL = 0.3; // начальный множитель скорости атаки [стандарт: 0.3]
const Float: BERSERKER_TIME_ABILITY = 3.8; // начальное время действия способности

// Друид
const Float: DRUID_REGEN_HP = 2.1; // начальный множитель пополняемого здоровья
const Float: DRUID_PERIOD_HP = 0.7; // начальный период пополнения ХП
const Float: DRUID_TIME_ABILITY = 4.7; // начальное время действия способности

// Череп
const Float: SKULL_DAMAGE_LIMIT = 20.0; // до скольки ХП ограничивается урон (начальный лимит)
const Float: SKULL_DAMAGE_ATTACK = 1.4; // начальный множитель урона
const Float: SKULL_TIME_ABILITY = 4.1; // начальное время действия способности

// Дрейк
const Float: DREIK_BOMB_VELOCITY = 1000.0; // начальная скорость броска бомбы
const Float: DREIK_BOMB_RADUIS = 100.0; // начальный радиус зоны действия бомбы
const Float: DREIK_BOMB_DAMAGE = 15.0; // начальный урон при попадании бомбой
const Float: DREIK_BOMB_STAN_TIME = 1.1; // начальный стан при попадании бомбой

// Влад Дракула
const Float: DRAKULA_BATS_LIFE = 3.9; // начальное время сущестоввания летучих мышей
const Float: DRAKULA_BATS_RADIUS = 100.0; // начальный радиус действия летучих мышей
const Float: DRAKULA_BATS_DAMAGE = 4.3; // начальный урон от действия летучих мышей (в сек)
const Float: DRAKULA_BATS_VAMPIR = 0.2; // начальный умножаемый коэффициент пополняемого здоровья (от урона летучих мышей)

// Бог грома
const Float: THUNDER_LIGHTING_RADIUS = 100.0; // начальный радиус действия атаки молнией
const Float: THUNDER_LIGHTING_DAMAGE = 19.0; // начальный урон от атаки молнией

/* =====================================================================
 *********************** *********************** **********************
===================================================================== */

new g_iMenu, g_iMaxHeroes, g_iMsgScreenFade, g_iSpriteEffect, g_iSpriteLighting, g_iEntFake, g_iHero[33];
new Float: g_fEnergy[33], Float: g_fEnergyAdd[33], Float: g_fEnergyMax[33];
new bool: g_bIsAbility[33], bool: g_bIsBerserk[33], bool: g_bIsDruid[33], bool: g_bIsSkull[33], bool: g_bIsStan[33];
new Float: g_fBerserkerSpeedAttack[33], Float: g_fDruidTime[33], Float: g_fDruidRegenHP[33], Float: g_fSkullDmgLim[33], Float: g_fSkullDmgAtk[33];

public plugin_precache()
{
	for(new i; i < sizeof(MODELS_KNIFE_VIEW); i++)
		precache_model(MODELS_KNIFE_VIEW[i]);
	
	for(new i; i < sizeof(MODELS_KNIFE_WEAPON); i++)
		precache_model(MODELS_KNIFE_WEAPON[i]);	
	
	precache_model(BOMB_MODEL);
	precache_model(BATS_MODEL);
	
	g_iSpriteEffect = precache_model("sprites/zbeam3.spr");
	g_iSpriteLighting = precache_model("sprites/lgtning.spr");
	
	precache_sound(BERSERK_SOUND);
	precache_sound(DRUID_SOUND);
	precache_sound(SKULL_SOUND);
	precache_sound(STAN_SOUND);
	precache_sound(BATS_SOUND);
	precache_sound(THUNDER_SOUND);
	
	new sSound[128];
	format(sSound, charsmax(sSound), "%s.wav", ENERGY_SOUND);
	precache_sound(sSound);
}

public plugin_cfg()
{
	if((g_iMaxHeroes = sizeof(HEROES_INFO)) != sizeof(ABILITIES_INFO))
	{
		set_fail_state("[Magic Heroes] Сritical error: inconsistency of parameters of the number of heroes");
		return;
	}
	
	new sData[128]; format(sData, charsmax(sData), "\y%s^n\rВыберите желаемого героя:", PREFIX_INFO);
	g_iMenu = menu_create(sData, "HeroChoose_Handler");
	
	for(new i; i < g_iMaxHeroes; i++)
	{
		format(sData, charsmax(sData), "\w%s \d(\y%s\d)", HEROES_INFO[i], ABILITIES_INFO[i]);
		menu_additem(g_iMenu, sData);
	}
	
	menu_setprop(g_iMenu, MPROP_BACKNAME, "\dНазад");
	menu_setprop(g_iMenu, MPROP_EXITNAME, "\dВыход");
	menu_setprop(g_iMenu, MPROP_NEXTNAME, "\dДалее");
	
	g_iMsgScreenFade = get_user_msgid("ScreenFade");
	g_iEntFake = create_entity("trigger_hurt");
}

public plugin_init()
{
	register_plugin("Magic Heroes", "1.0a", "6u3oH");
	
	register_clcmd("say /hero", "Clcmd_HeroChoose");
	register_clcmd("say_team /hero", "Clcmd_HeroChoose");
	register_clcmd("say /heroes", "Clcmd_HeroChoose");
	register_clcmd("say_team /heroes", "Clcmd_HeroChoose");
	register_clcmd("hero_menu", "Clcmd_HeroChoose");
	register_clcmd("heroes_menu", "Clcmd_HeroChoose");
	
	RegisterHam(Ham_Player_PreThink, "player", "fwHam_PreThinkPlayer_Pre");
	RegisterHam(Ham_Item_PreFrame, "player", "fwHam_PreFramePlayer_Pre");
	RegisterHam(Ham_TakeDamage, "player", "fwHam_TakeDmgPlayer_Pre");
	RegisterHam(Ham_Spawn, "player", "fwHam_SpawnPlayer_Post", true);
	RegisterHam(Ham_Killed, "player", "fwHam_KilledPlayer_Post", true);
	
	RegisterHam(Ham_Item_Deploy, "weapon_knife", "fwHam_DelpoyKnife_Post", true);
	RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_knife", "fwHam_PrimaryAttackKnife_Post", true);
	
	register_touch("dreik_bomb", "*", "Touch_DreikBomb");
	register_think("dreik_bomb", "Think_DreikBomb");
	register_think("drakula_bats", "Think_DrakulaBats");
}

public client_putinserver(id)
{
	g_iHero[id] = random_num(0, 5);
	
	if(get_user_flags(id) & VIP_FLAG)
	{
		g_fEnergyAdd[id] = ADD_ENERGY_VIP;
		g_fEnergyMax[id] = MAX_ENERGY_VIP;
	}else{
		g_fEnergyAdd[id] = ADD_ENERGY;
		g_fEnergyMax[id] = MAX_ENERGY;
	}
	
	g_bIsBerserk[id] = false;
	g_bIsDruid[id] = false;
	g_bIsSkull[id] = false;
	g_bIsStan[id] = false;
}

public client_disconnect(id)
{
	remove_task(id + TASK_BERSERK);
	remove_task(id + TASK_DRUID);
	remove_task(id + TASK_SKULL);
	remove_task(id + TASK_STAN);
}

public Clcmd_HeroChoose(id)
{
	if(!is_user_alive(id))
	{
		ColorChat(id, NORMAL, "[^4%s^1] ^3Меню выбора герой ^1недоступно ^3для мёртвых", PREFIX_INFO);
		return;
	}
		
	menu_display(id, g_iMenu);
}

public HeroChoose_Handler(id, iMenu, iItem)
{
	if(!is_user_alive(id))
	{
		ColorChat(id, NORMAL, "[^4%s^1] Меню выбора героев ^3недоступно ^4для мёртвых", PREFIX_INFO);
		return;
	}
	
	if(iItem == MENU_EXIT)
		return;
	
	if(g_iHero[id] == iItem)
	{
		ColorChat(id, NORMAL, "[^4%s^1] Выбранный герой является ^3вашим ^4текущим", PREFIX_INFO);
		return;
	}
	
	if(g_bIsBerserk[id] || g_bIsDruid[id] || g_bIsSkull[id])
	{
		ColorChat(id, NORMAL, "[^4%s^1] ^4Нельзя ^1сменить ^3героя ^1во время ^3действия ^4способности", PREFIX_INFO);
		return;
	}
	
	g_iHero[id] = iItem;
	g_fEnergy[id] = 0.0;
	
	ExecuteHamB(Ham_Item_Deploy, get_pdata_cbase(id, WEAPON_CURRENT));
	ColorChat(id, NORMAL, "[^4%s^1] Вы выбрали героя: ^4%s ^1(^3способность: ^4%s^1)", PREFIX_INFO, HEROES_INFO[iItem], ABILITIES_INFO[iItem]);
}

public fwHam_PreThinkPlayer_Pre(id)
{
	if(!is_user_alive(id))
		return;
		
	static Float: fCurTime, Float: fNextTime[33]; fCurTime = get_gametime();
	
	if(fNextTime[id] < fCurTime)
	{
		static sInfo[64];
		
		if(g_fEnergy[id] >= g_fEnergyMax[id])
		{			
			format(sInfo, charsmax(sInfo), "MAX");
			g_fEnergy[id] = g_fEnergyMax[id];
			set_hudmessage(255, 0, 0, 0.01, 0.14, 1, 0.1, PERIOD_ADD_ENERGY, 0.1, 0.1, 4);
		}
		else if(g_fEnergy[id] >= ACTIVE_ENERGY)
		{
			if(!g_bIsAbility[id])
			{
				client_cmd(id, "spk %s", ENERGY_SOUND);
				g_bIsAbility[id] = true;
			}
			
			format(sInfo, charsmax(sInfo), "Готова");
			g_fEnergy[id] += g_fEnergyAdd[id];
			set_hudmessage(252, 52, 3, 0.01, 0.14, 1, 0.1, PERIOD_ADD_ENERGY, 0.1, 0.1, 4);
		}else{
			format(sInfo, charsmax(sInfo), "%s", ABILITIES_INFO[g_iHero[id]]);
			g_fEnergy[id] += g_fEnergyAdd[id];
			set_hudmessage(0, 255, 0, 0.01, 0.14, 0, 0.1, PERIOD_ADD_ENERGY, 0.1, 0.1, 4);
		}
		
		show_hudmessage(id, "Герой: %s^nЭнергия: [%..1f/%..1f]^nСпособность (E): [%s]", HEROES_INFO[g_iHero[id]], g_fEnergy[id], g_fEnergyMax[id], sInfo);
		fNextTime[id] = fCurTime + PERIOD_ADD_ENERGY;
	}
		
	if(pev(id, pev_button) & ACTIVE_BUTTON)
	{
		if(!g_bIsAbility[id])
			return;
		
		g_bIsAbility[id] = false;
		
		switch(g_iHero[id])
		{
			case 0:
			{
				if(g_bIsBerserk[id])
					return;
				
				if(g_bIsStan[id])
				{
					g_bIsStan[id] = false;
					reset_ent_render(id);
					ExecuteHamB(Ham_Item_PreFrame, id);
					remove_task(id + TASK_STAN);
				}
				
				new Float: fData = g_fEnergy[id] / g_fEnergyMax[id];
				g_bIsBerserk[id] = true;
				g_fBerserkerSpeedAttack[id] = BERSERKER_SPEED_ATTACK_MUL - fData * 0.1;
				set_pev(id, pev_maxspeed, pev(id, pev_maxspeed) * BERSERKER_SPEED_MUL + g_fEnergy[id]);

set_screen_fade(id, 100, 10, 10);
				set_ent_render(id, 255, 10, 10);
				
				emit_sound(id, CHAN_AUTO, BERSERK_SOUND, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
				set_task(BERSERKER_TIME_ABILITY + fData, "Task_Berserk_Off", id + TASK_BERSERK);
			}
			
			case 1:
			{
				if(g_bIsDruid[id])
					return;
					
				new Float: fData = g_fEnergy[id] / g_fEnergyMax[id];
				g_bIsDruid[id] = true;
				g_fDruidTime[id] = DRUID_TIME_ABILITY + fData;
				g_fDruidRegenHP[id] = DRUID_REGEN_HP + fData;

set_screen_fade(id, 10, 100, 10);
				set_ent_render(id, 10, 255, 10);
				
				emit_sound(id, CHAN_AUTO, DRUID_SOUND, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
				set_task(DRUID_PERIOD_HP - fData * 0.1, "Task_Druid", id + TASK_DRUID, .flags = "b");
			}
			
			case 2:
			{
				if(g_bIsSkull[id])
					return;
					
				new Float: fData = g_fEnergy[id] / g_fEnergyMax[id];
				g_fSkullDmgLim[id] = SKULL_DAMAGE_LIMIT - fData;
				g_fSkullDmgAtk[id] = SKULL_DAMAGE_LIMIT + fData;
				g_bIsSkull[id] = true;
				
				set_screen_fade(id, 163, 73, 164);
				set_ent_render(id, 163, 73, 164);
				
				emit_sound(id, CHAN_AUTO, SKULL_SOUND, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
				set_task(SKULL_TIME_ABILITY + fData, "Task_Skull_Off", id + TASK_SKULL);
			}
			
			case 3:
			{
				new iEnt, Float: fOrigin[3], Float: fViewOfs[3], Float: fVelocity[3]; 
				
				pev(id, pev_origin, fOrigin);
				pev(id, pev_view_ofs, fViewOfs);
							
				for(new i; i < 3; i++)
					fOrigin[i] += fViewOfs[i];
				
				iEnt = create_entity("info_null");
				
				set_pev(iEnt, pev_classname, "dreik_bomb");
				set_pev(iEnt, pev_origin, fOrigin);
				set_pev(iEnt, pev_solid, SOLID_TRIGGER);
				set_pev(iEnt, pev_movetype, MOVETYPE_TOSS);
				set_pev(iEnt, pev_owner, id);
				engfunc(EngFunc_SetModel, iEnt, BOMB_MODEL);
				
				velocity_by_aim(id, floatround(g_fEnergy[id] * 10), fVelocity);
				set_pev(iEnt, pev_velocity, fVelocity);	
				set_pev(iEnt, pev_nextthink, get_gametime() + 5.0);
			}
			
			case 4:
			{
				new iEnt, Float: fOrigin[3];
				pev(id, pev_origin, fOrigin);
				
				iEnt = create_entity("info_null");
				
				set_pev(iEnt, pev_classname, "drakula_bats");
				set_pev(iEnt, pev_origin, fOrigin);
				set_pev(iEnt, pev_movetype, MOVETYPE_FOLLOW);
				set_pev(iEnt, pev_aiment, id);
				set_pev(iEnt, pev_owner, id);
				engfunc(EngFunc_SetModel, iEnt, BATS_MODEL);
				set_pev(iEnt, pev_fuser1, DRAKULA_BATS_LIFE + g_fEnergyMax[id] / g_fEnergy[id]);
				set_pev(iEnt, pev_nextthink, get_gametime() + 1.0);
				set_ent_animation(iEnt, 0, 1.0, 1.0);
			}
			
			case 5:
			{
				new Float: fOrigin[3], Float: fData[3], Float: fData2 = g_fEnergy[id] / g_fEnergyMax[id];
				
				pev(id, pev_origin, fOrigin);
				pev(id, pev_view_ofs, fData);
				
				for(new i; i < 3; i++)
					fOrigin[i] += fData[i];
				
				pev(id, pev_v_angle, fData);
				engfunc(EngFunc_MakeVectors, fData);
				global_get(glb_v_forward, fData);
				
				for(new i; i < 3; i++)
					fData[i] = fData[i] * 8192 + fOrigin[i];
			
				engfunc(EngFunc_TraceLine, fOrigin, fData, DONT_IGNORE_MONSTERS, id, 0);
				get_tr2(0, TR_vecEndPos, fOrigin);
				fData = fOrigin;
				fData[0] += random_num(-100, 100); fData[1] += random_num(-100, 100); fData[2] += 500;
				
				message_begin(MSG_BROADCAST, SVC_TEMPENTITY);
				write_byte(TE_BEAMPOINTS);
				engfunc(EngFunc_WriteCoord, fData[0]);
				engfunc(EngFunc_WriteCoord, fData[1]);
				engfunc(EngFunc_WriteCoord, fData[2]);
				engfunc(EngFunc_WriteCoord, fOrigin[0]);
				engfunc(EngFunc_WriteCoord, fOrigin[1]);
				engfunc(EngFunc_WriteCoord, fOrigin[2]);
				write_short(g_iSpriteLighting);
				write_byte(0);
				write_byte(10);
				write_byte(1);
				write_byte(1000);
				write_byte(1000);
				write_byte(100);
				write_byte(255);
				write_byte(255);
				write_byte(1000);
				write_byte(10);
				message_end();
				
				emit_sound(id, CHAN_AUTO, THUNDER_SOUND, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
				
				message_begin(MSG_BROADCAST, SVC_TEMPENTITY);
				write_byte(TE_WORLDDECAL);
				engfunc(EngFunc_WriteCoord, fOrigin[0]);
				engfunc(EngFunc_WriteCoord, fOrigin[1]);
				engfunc(EngFunc_WriteCoord, fOrigin[2]);
				write_byte(random_num(46, 48));
				message_end();
				
				new iVictim = FM_NULLENT;
				while((iVictim = find_ent_in_sphere(iVictim, fOrigin, THUNDER_LIGHTING_RADIUS + g_fEnergy[id])))			
				{
					if(!is_user_alive(iVictim))
						continue;
								
					if(get_user_team(iVictim) == get_user_team(id))
						continue;
						
					if(g_bIsDruid[iVictim])
						continue;
			
					fData[0] = 50.0; fData[0] = 50.0; fData[2] = 400.0;
					set_pev(iVictim, pev_velocity, fData);
			
					ExecuteHamB(Ham_TakeDamage, iVictim, g_iEntFake, id, THUNDER_LIGHTING_DAMAGE + fData2, DMG_SHOCK);
				}
			}
		}
		
		g_fEnergy[id] = 0.0;
	}
}

public Task_Berserk_Off(id)
{
	id -= TASK_BERSERK;
	
	if(!is_user_connected(id))
		return;
		
	g_bIsBerserk[id] = false;
	reset_screen_fade(id)
	reset_ent_render(id);
	ExecuteHamB(Ham_Item_PreFrame, id);
}

public Task_Druid(iTask)
{
	new id = iTask - TASK_DRUID;
	
	if(!is_user_connected(id))
		return;
		
	if((g_fDruidTime[id] -= DRUID_PERIOD_HP) < 0)
	{
		g_bIsDruid[id] = false;
		reset_screen_fade(id);
		reset_ent_render(id);
		remove_task(iTask);
	}
	else
		set_pev(id, pev_health, pev(id, pev_health) + g_fDruidRegenHP[id]);
}

public Task_Skull_Off(id)
{
	id -= TASK_SKULL;
	
	if(!is_user_connected(id))
		return;
	
	g_bIsSkull[id] = false;
	reset_screen_fade(id);
	reset_ent_render(id);
}

public Ability_Dreik(id, iEnt)
{
	new Float: fOrigin[3]; pev(iEnt, pev_origin, fOrigin);
	new Float: fData = g_fEnergy[id] / g_fEnergyMax[id];
	CreateBeamCylinder(fOrigin, DREIK_BOMB_RADUIS + fData, 30, 30, 30);
	emit_sound(id, CHAN_AUTO, STAN_SOUND, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
	
	new iVictim = FM_NULLENT;
	while((iVictim = find_ent_in_sphere(iVictim, fOrigin, DREIK_BOMB_RADUIS + fData)))			
	{
		if(!is_user_alive(iVictim))
			continue;
					
		if(get_user_team(iVictim) == get_user_team(id) && id != iVictim)
			continue;
			
		if(g_bIsStan[iVictim] || g_bIsDruid[iVictim])
			continue;

set_ent_render(iVictim, 30, 30, 30);
		ExecuteHamB(Ham_TakeDamage, iVictim, g_iEntFake, id, DREIK_BOMB_DAMAGE + fData, DMG_CRUSH);
		set_pev(iVictim, pev_maxspeed, -1.0);
		g_bIsStan[iVictim] = true;
		set_task(DREIK_BOMB_STAN_TIME + fData, "Task_Stan_Off", iVictim + TASK_STAN);
	}
}

public Task_Stan_Off(id)
{
	id -= TASK_STAN;
	
	g_bIsStan[id] = false;
	reset_ent_render(id);
	ExecuteHamB(Ham_Item_PreFrame, id);
}

public Touch_DreikBomb(iBomb, iEnt)
{
	if(!is_valid_ent(iBomb))
		return;

static iOwner;
		
	if((iOwner = entity_get_edict(iBomb, EV_ENT_owner)) == iEnt)
		return;
		
	Ability_Dreik(iOwner, iBomb);
	entity_set_int(iBomb, EV_INT_flags, entity_get_int(iBomb, EV_INT_flags) | FL_KILLME);
}

public Think_DreikBomb(iEnt)
{
	if(!is_valid_ent(iEnt))
		return;
	
	Ability_Dreik(entity_get_edict(iEnt, EV_ENT_owner), iEnt);
	entity_set_int(iEnt, EV_INT_flags, entity_get_int(iEnt, EV_INT_flags) | FL_KILLME);
}

public Think_DrakulaBats(iEnt)
{
	if(!is_valid_ent(iEnt))
		return;

new iOwner = pev(iEnt, pev_owner), Float: fData = g_fEnergyMax[iOwner] / g_fEnergy[iOwner];
	new Float: fDamage = DRAKULA_BATS_DAMAGE + fData;
	new Float: fHealth = fDamage * DRAKULA_BATS_VAMPIR;
	new Float: fOrigin[3]; pev(iOwner, pev_origin, fOrigin);
	new Float: fTime, bool: bIsBats;

if((fTime = pev(iEnt, pev_fuser1) - 1.0) > 0)
	{
		new iVictim = FM_NULLENT;
		while((iVictim = find_ent_in_sphere(iVictim, fOrigin, DRAKULA_BATS_RADIUS + fData)))			
		{
			if(!is_user_alive(iVictim))
				continue;

if(get_user_team(iVictim) == get_user_team(iOwner))
				continue;

if(!bIsBats)
			{
				emit_sound(iVictim, CHAN_AUTO, BATS_SOUND, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
				bIsBats = true;
			}

ExecuteHamB(Ham_TakeDamage, iVictim, g_iEntFake, iOwner, fDamage, DMG_PARALYZE);
			set_pev(iOwner, pev_health, pev(iOwner, pev_health) + fHealth);
		}

set_pev(iEnt, pev_fuser1, fTime);
		set_pev(iEnt, pev_nextthink, get_gametime() + 1.0);
	}
	else
		entity_set_int(iEnt, EV_INT_flags, entity_get_int(iEnt, EV_INT_flags) | FL_KILLME);
}

public fwHam_SpawnPlayer_Post(id)
{
	if(!is_user_alive(id))
		return;
	
	g_fEnergy[id] = 0.0;
}

public fwHam_KilledPlayer_Post(iVictim, iAttacker, iCorpse)
{
	if(!is_user_connected(iVictim))
		return;
	
	if(g_bIsBerserk[iVictim])
	{
		g_bIsBerserk[iVictim] = false;
		reset_screen_fade(iVictim);
		reset_ent_render(iVictim);
		remove_task(iVictim + TASK_BERSERK);
	}
	
	if(g_bIsDruid[iVictim])
	{
		g_bIsDruid[iVictim] = false;
		reset_screen_fade(iVictim);
		reset_ent_render(iVictim);
		remove_task(iVictim + TASK_DRUID);
	}
	
	if(g_bIsSkull[iVictim])
	{	
		g_bIsSkull[iVictim] = false;
		reset_screen_fade(iVictim);
		reset_ent_render(iVictim);
		remove_task(iVictim + TASK_SKULL);
	}
	
	if(g_bIsStan[iVictim])
	{
		g_bIsStan[iVictim] = false;
		reset_ent_render(iVictim);
		remove_task(iVictim + TASK_STAN);
	}
	
	g_fEnergy[iVictim] = 0.0;
}

public fwHam_PreFramePlayer_Pre(id)
{
	if(!is_user_alive(id))
		return HAM_IGNORED;
		
	if(g_bIsBerserk[id] || g_bIsStan[id])
		return HAM_SUPERCEDE;
		
	return HAM_IGNORED;
}

public fwHam_TakeDmgPlayer_Pre(iVictim, iInflictor, iAttacker, Float: fDmg, szByts)
{
	if(!is_user_alive(iVictim) || !is_user_alive(iAttacker))
		return;
		
	if(g_bIsSkull[iVictim])
	{	
		if(fDmg > g_fSkullDmgLim[iVictim])
			SetHamParamFloat(4, g_fSkullDmgLim[iVictim]);
	}
	
	if(g_bIsSkull[iAttacker])
		SetHamParamFloat(4, g_fSkullDmgAtk[iAttacker] + fDmg);
}

public fwHam_DelpoyKnife_Post(iWeapon)
{
	if(!pev_valid(iWeapon))
		return;
		
	new id = get_pdata_cbase(iWeapon, WEAPON_OWNER, WEAPON_ID);
		
	if(!is_user_alive(id))
		return;
		
	entity_set_string(id, EV_SZ_viewmodel, MODELS_KNIFE_VIEW[g_iHero[id]]);
	entity_set_string(id, EV_SZ_weaponmodel, MODELS_KNIFE_WEAPON[g_iHero[id]]);
}
	
public fwHam_PrimaryAttackKnife_Post(iWeapon)
{
	if(!pev_valid(iWeapon))
		return;
		
	new id = get_pdata_cbase(iWeapon, WEAPON_OWNER, WEAPON_ID);
		
	if(!is_user_alive(id))
		return;
		
	if(!g_bIsBerserk[id])
		return
		
	set_pdata_float(iWeapon, WEAPON_ATTACK, g_fBerserkerSpeedAttack[id], WEAPON_ID);
}

public set_screen_fade(id, r, g, b)
{
	message_begin(MSG_ONE, g_iMsgScreenFade, _, id);
	write_short(1<<12);
	write_short(1<<8);
	write_short(1<<2);
	write_byte(r);
	write_byte(g);
	write_byte(b);
	write_byte(50);
	message_end();
}

public reset_screen_fade(id)
{
	message_begin(MSG_ONE, g_iMsgScreenFade, _, id);
	write_short(1<<12);
	write_short(1<<8);
	write_short(1<<4);
	write_byte(0);
	write_byte(0);
	write_byte(0);
	write_byte(255);
	message_end();	
}

public set_ent_render(id, r, g, b)
{
	new Float: fRenderColor[3];
	fRenderColor[0] = float(r);
	fRenderColor[1] = float(g);
	fRenderColor[2] = float(b);
	
	set_pev(id, pev_renderfx, kRenderFxGlowShell);
	set_pev(id, pev_rendercolor, fRenderColor);
	set_pev(id, pev_rendermode, kRenderNormal);
	set_pev(id, pev_renderamt, 16.0);
}

public reset_ent_render(id)
{
	if(g_bIsBerserk[id] || g_bIsDruid[id] || g_bIsSkull[id] || g_bIsStan[id])
		return;
	
	set_pev(id, pev_renderfx, kRenderFxNone);
	set_pev(id, pev_rendercolor, Float: {255.0, 255.0, 255.0});
	set_pev(id, pev_rendermode, kRenderNormal);
	set_pev(id, pev_renderamt, 16.0);
}

public CreateBeamCylinder(Float: fOrigin[3], Float: fDist, r, g, b)
{
	engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, fOrigin, 0);
	write_byte(TE_BEAMCYLINDER);
	engfunc(EngFunc_WriteCoord, fOrigin[0]);
	engfunc(EngFunc_WriteCoord, fOrigin[1]);
	engfunc(EngFunc_WriteCoord, fOrigin[2]);
	engfunc(EngFunc_WriteCoord, fOrigin[0]);
	engfunc(EngFunc_WriteCoord, fOrigin[1]);
	engfunc(EngFunc_WriteCoord, fOrigin[2] + fDist);
	write_short(g_iSpriteEffect);
	write_byte(0);
	write_byte(0);
	write_byte(4);
	write_byte(60);
	write_byte(0);
	write_byte(r);
	write_byte(g);
	write_byte(b);
	write_byte(1000);
	write_byte(0);
	message_end();
}

public set_ent_animation(iEnt, iAnim, Float: fAnimTime, Float: fFrame)
{
	entity_set_int(iEnt, EV_INT_sequence, iAnim);
	entity_set_float(iEnt, EV_FL_animtime, fAnimTime);
	entity_set_float(iEnt, EV_FL_framerate, fFrame);
	entity_set_float(iEnt, EV_FL_frame, 0.0);
}

Загрузил popca2424

2018-11-22 15:02:17

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram