	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

MassBan

Теги: Скачать плагины csgoАдминские

Позволяет забанить или кикнуть сразу несколько игроков.
Вызвать плагин соответствующей командой.
Выбрать нужные цели. Если вы ошиблись и выбрали не того, выберите его еще раз, тогда [X] будет убран, а значит игрок не будет забанен|кикнут.
Нажать "Забанить выбранных игроков".
Выбрать нужное время бана. Для кика используйте пункт "Кикнуть".
Выбрать причину бана|кика.

Добавление своих причин бана и интервалов времени бана:
Осуществляется через файл .../sourcemod/configs/massban.txt, по примеру, написанному там.
Для бана: title - как будет написано в меню, time - время бана по этой причине.
Для причин: reason - отображаемая причина бана|кика.

Компилятор: 1.9.0.6281 925

Команды:

sm_massban

Флаг доступа: ADMFLAG_BAN (флаг бана).

.sma / .sp

#include <sourcemod>
#include <adminmenu>

//----------------------------------------------------------------------------------------
// К О Н С О Л Ь Н Ы Е   П Е Р Е М Е Н Н Ы Е
//----------------------------------------------------------------------------------------
// Тип продолжительности бана. 0 - секунды, 1 - минуты, 2 - часы.
new Handle:	g_hConVar_iBanLengthType		= INVALID_HANDLE;
new 		g_iBanLengthType;
// Добавлять ли пункт в админку.
new Handle:	g_hConVar_bIntegrateInAdminMenu = INVALID_HANDLE;
new bool:	g_bIntegrateInAdminMenu;

//----------------------------------------------------------------------------------------
// Г Л О Б А Л Ь Н Ы Е   П Е Р Е М Е Н Н Ы Е
//----------------------------------------------------------------------------------------
// Handle от меню причин бана|кика
new Handle:	g_hReasonMenu 		= INVALID_HANDLE;
// Handle от меню выбора времени бана|кика
new Handle:	g_hTimeMenu			= INVALID_HANDLE;
// Главное меню администратора
new Handle:	g_hTopMenu			= INVALID_HANDLE;
// TopMenuObject пункта
new TopMenuObject:g_Point;

// Через что открыли меню.
new bool:	g_bOpenThroughMenu[MAXPLAYERS+1];

// Массив для хранения всех целей на бан. Состоит из UserId.
new g_iTargetArray[MAXPLAYERS+1][MAXPLAYERS+1];
// Количество записанных целей на бан.
new g_iTargetCount[MAXPLAYERS+1];
// Выбранная продолжительность бана.
new g_iTargetTime[MAXPLAYERS+1];

// Массив множителей для времени
new g_iMultiplier[3] = {1, 60, 3600};

//----------------------------------------------------------------------------------------
// Ф О Р В А Р Д Ы
//----------------------------------------------------------------------------------------
// Вызывается при старте плагина
public OnPluginStart()
{
	// Создаем меню для времени и причин
	g_hTimeMenu = CreateMenu(Handle_TimeMenu);
	g_hReasonMenu = CreateMenu(Handle_ReasonMenu);
	// Напишем их заголовки
	SetMenuTitle(g_hTimeMenu, "Выберите время:\n \n");
	SetMenuTitle(g_hReasonMenu, "Выберите причину:\n \n");
	
	new Handle:hKeyValues = CreateKeyValues("massban");
	decl String:sPath[256];
	BuildPath(Path_SM, sPath, sizeof(sPath) - 1, "configs/massban.txt");
	
	if ( !FileToKeyValues(hKeyValues, sPath) || !KvGotoFirstSubKey(hKeyValues) )
	{
		SetFailState("%s not found or empty", sPath);
		return;
	}
	
	KvRewind(hKeyValues);
	if ( KvJumpToKey(hKeyValues, "time") && KvJumpToKey(hKeyValues, "1") )
	{
		do
		{
			decl String:sInfo[16], String:sTitle[64];
			KvGetString(hKeyValues, "time", sInfo, sizeof(sInfo) - 1);
			KvGetString(hKeyValues, "title", sTitle, sizeof(sTitle) - 1);
			
			AddMenuItem(g_hTimeMenu, sInfo, sTitle);
		} while (KvGotoNextKey(hKeyValues));
	}
	
	KvRewind(hKeyValues);
	if ( KvJumpToKey(hKeyValues, "reason") && KvJumpToKey(hKeyValues, "1") )
	{
		do
		{
			decl String:sReason[128];
			KvGetString(hKeyValues, "reason", sReason, sizeof(sReason) - 1);
			
			AddMenuItem(g_hReasonMenu, sReason, sReason);
		} while (KvGotoNextKey(hKeyValues));
	}
	
	CloseHandle(hKeyValues);
	
	// Делаем доступной кпопку назад
	SetMenuExitBackButton(g_hTimeMenu, true);
	SetMenuExitBackButton(g_hReasonMenu, true);
	
	// Регистрируем коданду для администратора на флаг ADMFLAG_BAN
	RegAdminCmd("sm_massban", Command_MassBan, ADMFLAG_BAN);
	
	// создаем консольные переменные
	g_hConVar_iBanLengthType = CreateConVar("sm_massban_banlengthtype", "1", "тип продолжительности бана.\n0 - секунды, 1 - минуты, 2 - часы");
	g_hConVar_bIntegrateInAdminMenu = CreateConVar("sm_massban_integinmenu", "1", "добавлять ли пункт в админку.\n0 - нет, 1 - да.\nУникальное имя пункта: sm_massban");
}

public ConVarChange_Callback(Handle:hConVar, const String:sOldVal[], const String:sNewVal[])
{
	if ( hConVar == g_hConVar_iBanLengthType )
	{
		g_iBanLengthType 		= GetConVarInt(g_hConVar_iBanLengthType);
	}
	else if ( hConVar == g_hConVar_bIntegrateInAdminMenu )
	{
		g_bIntegrateInAdminMenu = GetConVarBool(g_hConVar_bIntegrateInAdminMenu);
		
		if ( g_bIntegrateInAdminMenu )
		{
			AddPointToTopMenu();
		}
		else
		{
			RemoveFromTopMenu(g_hTopMenu, g_Point);
		}
	}
	
}

AddPointToTopMenu()
{
	new Handle:hTopMenu;
	if ( LibraryExists("adminmenu") && ((hTopMenu = GetAdminTopMenu()) != INVALID_HANDLE) )
	{
		if (hTopMenu == g_hTopMenu)
		{
			return;
		}
		
		g_hTopMenu = hTopMenu;
		new TopMenuObject:PlayerCommands = FindTopMenuCategory(g_hTopMenu, ADMINMENU_PLAYERCOMMANDS);
		g_Point = AddToTopMenu(g_hTopMenu, "sm_massban", TopMenuObject_Item, AdmMenu_Massban_Callback, PlayerCommands, "", ADMFLAG_BAN);  
	}
}

// Все конфиги выполнены
public OnConfigsExecuted()
{
	// Получаем значения переменных
	g_iBanLengthType 		= GetConVarInt(g_hConVar_iBanLengthType);
	g_bIntegrateInAdminMenu = GetConVarBool(g_hConVar_bIntegrateInAdminMenu);
	
	// Если включена интеграция в меню, то добавляем к меню пункт
	if ( g_bIntegrateInAdminMenu )
	{
		AddPointToTopMenu();
	}
	
	HookConVarChange(g_hConVar_iBanLengthType, 			ConVarChange_Callback);
	HookConVarChange(g_hConVar_bIntegrateInAdminMenu, 	ConVarChange_Callback);
}

public AdmMenu_Massban_Callback(Handle:topmenu, TopMenuAction:action, TopMenuObject:object_id, param, String:buffer[], maxlength)  
{  
	if (action == TopMenuAction_DisplayOption) 
	{
		Format(buffer, maxlength, "Забанить много игроков");
	}
	else if (action == TopMenuAction_SelectOption)  
	{
		if (object_id == g_Point)  
		{
			g_bOpenThroughMenu[param] = true;
			g_iTargetCount[param] = 0;
			SendClientMenuToClient(param);
		}
	}
}

// Если вызвали команду
public Action:Command_MassBan(client, argc)
{
	// Если вызвали со стороны сервера
	if ( client == 0 )
	{
		// Выводим сообщение, что команда только для клиентов
		PrintToServer("client-side only");
		return Plugin_Handled;
	}
	
	// Обнуляем число выбранных целей
	g_iTargetCount[client] = 0;
	// Отмечаем, что команду вызвали через консоль
	g_bOpenThroughMenu[client] = false;
	
	// Отсылаем меню с игроками
	SendClientMenuToClient(client);
	return Plugin_Handled;
}

// Отсылает меню с игроками. Параметры: кому отсылать, и с какой страницы начинать
SendClientMenuToClient(client, item=0)
{
	// Создали меню с игроками
	new Handle:hClientMenu = CreateMenu(Handle_ClientMenu);
	if ( hClientMenu != INVALID_HANDLE )
	{
		// Дали название
		SetMenuTitle(hClientMenu, "Выберите цели:\n \n");
		
		// Добавляем игроков
		for ( new i = 1; i <= MaxClients; i++ )
		{
			// Если игрок подключен
			if ( IsClientConnected(i) )
			{
				// Получаем его UserId
				new iUserId = GetClientUserId(i);
				
				// Добавляем в меню пункт с ником игрока, а информацией передаем UserId
				decl String:sUserId[8], String:sClientName[64];
				IntToString(iUserId, sUserId, sizeof(sUserId) - 1);
				GetClientName(i, sClientName, sizeof(sClientName) - 1);
				
				// Ищем, нет ли его в массиве
				new iPos = FindUserIdInArray(client, iUserId);
				// Если игрок есть
				if ( iPos > -1 )
				{
					// добавим к его нику справа [X]
					Format(sClientName, sizeof(sClientName) - 1, "%s [X]", sClientName);
				}
				else
				{
					// если нет, то добавим [ ]
					Format(sClientName, sizeof(sClientName) - 1, "%s [ ]", sClientName);
				}
				
				AddMenuItem(hClientMenu, sUserId, sClientName);
			}
		}
		
		// Добавляем пункт "Забанить выбранных игроков"
		AddMenuItem(hClientMenu, "", "Забанить выбранных игроков");
		
		if ( g_bOpenThroughMenu[client] )
		{
			SetMenuExitBackButton(hClientMenu, true);
		}
		
		// Отсылаем меню
		DisplayMenuAtItem(hClientMenu, client, item, MENU_TIME_FOREVER);
	}
}

//----------------------------------------------------------------------------------------
// Х А Н Д Л Ы
//----------------------------------------------------------------------------------------
public Handle_ClientMenu(Handle:hMenu, MenuAction:action, client, slot)
{
	if ( action == MenuAction_Select )
	{
		// Получаем выбранный UserID
		decl String:sUserId[8];
		GetMenuItem(hMenu, slot, sUserId, sizeof(sUserId) - 1);
		
		// Преобразуем в целое значение
		new iUserId = StringToInt(sUserId);
		// Если UserId валиден (не равен "")
		if ( iUserId != 0 )
		{
			// Ищем игрока в массиве
			new iPos = FindUserIdInArray(client, iUserId);
			// Если игрок есть
			if ( iPos > -1 )
			{
				// Удаляем его из массива
				ShiftArrayLeft(client, iPos);
			}
			else
			{
				// Иначе добавляем цель в массив.
				g_iTargetArray[client][g_iTargetCount[client]++] = iUserId;
			}
			
			// Отсылаем меню
			SendClientMenuToClient(client, GetMenuSelectionPosition());
		}
		else
		{
			// Иначе выбрали пункт "Забанить выбранных игроков", отсылаем меню с временем
			DisplayMenu(g_hTimeMenu, client, MENU_TIME_FOREVER);
		}
	}
	else if ( action == MenuAction_Cancel && slot == MenuCancel_ExitBack )
	{
		RedisplayAdminMenu(g_hTopMenu, client);
	}
	else if ( action == MenuAction_End )
	{
		// Закрываем Handle, чтобы избежать утечки памяти
		CloseHandle(hMenu);
	}
}

public Handle_TimeMenu(Handle:hMenu, MenuAction:action, client, slot)
{
	if ( action == MenuAction_Select )
	{
		// Получаем время бана
		decl String:sTime[8];
		GetMenuItem(g_hTimeMenu, slot, sTime, sizeof(sTime) - 1);
		
		// Записываем его
		g_iTargetTime[client] = StringToInt(sTime);
		// Отсылаем меню с выбором причины бана
		DisplayMenu(g_hReasonMenu, client, MENU_TIME_FOREVER);
	}
	else if ( action == MenuAction_Cancel && slot == MenuCancel_ExitBack )
	{
		// Если нажали назад, то возвращаем к выбору игроков
		SendClientMenuToClient(client);
	}
}

public Handle_ReasonMenu(Handle:hMenu, MenuAction:action, client, slot)
{
	if ( action == MenuAction_Select )
	{
		// Получаем причину
		decl String:sReason[64];
		GetMenuItem(g_hReasonMenu, slot, sReason, sizeof(sReason) - 1);
		
		// По всем записям в массиве
		for ( new i = 0; i <= g_iTargetCount[client]; i++ )
		{
			// Получаем UserId, client игроков из массива
			new iUserId = g_iTargetArray[client][i];
			new iClient = GetClientOfUserId(iUserId);
			// Если преобразование успешно (игрок всё еще на сервере)
			if ( iClient != 0 )
			{
				// Если выбрали кикнуть
				if ( g_iTargetTime[client] == -1 )
				{
					// Кикаем с выбранной причиной
					KickClient(iClient, sReason);
				}
				else
				{
					// Иначе шлем через клиента команду на бан
					ClientCommand(client, "sm_ban #%d %i \"%s\"", iUserId, g_iTargetTime[client] * g_iMultiplier[g_iBanLengthType], sReason);
				}
			}
			// Чтобы обновить информацию в меню
			CreateTimer(0.1, Timer_RestoreMenu, client);
		}
	}
	else if ( action == MenuAction_Cancel && slot == MenuCancel_ExitBack )
	{
		// Если нажали назад, то возвращаем к выбору времени
		DisplayMenu(g_hTimeMenu, client, MENU_TIME_FOREVER);
	}
}
public Action:Timer_RestoreMenu(Handle:hTimer, any:client)
{
	SendClientMenuToClient(client);
	return Plugin_Stop;
}

//----------------------------------------------------------------------------------------
// В С П О М О Г А Т Е Л Ь Н Ы Е   Ф У Н К Ц И И
//----------------------------------------------------------------------------------------
// Ищет позицию UserId в массиве. Если не найден, то возвращает -1.
FindUserIdInArray(client, const UserId)
{
	for ( new i = 0; i < g_iTargetCount[client]; i++ )
	{
		if ( g_iTargetArray[client][i] == UserId )
		{
			return i;
		}
	}
	return -1;
}
// Сдвигает массив влево (дабы удалить существующее значение из массива)
ShiftArrayLeft(client, start_value)
{
	for ( new i = start_value; i < g_iTargetCount[client] - 1; i++ )
	{
		g_iTargetArray[client][i] = g_iTargetArray[client][i+1];
	}
	g_iTargetCount[client]--;
}

//----------------------------------------------------------------------------------------
// И Н Ф О Р М А Ц И Я   О   П Л А Г И Н Е
//----------------------------------------------------------------------------------------
public Plugin:myinfo = 
{
	name 		= "[ MassBan ]",
	author 		= "Regent",
	description = "",
	version 	= "1.1b",
	url 		= "http://hlmod.ru/forum/plaginy-dlya-sourcemod/19729-massban.html && http://all4css.ru/"
};

Загрузил Ju4ka1371

2019-01-24 23:25:42

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram