	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Money_Transfer

Теги: Скачать плагины csСерверные

Данный плагин позволит передавать деньги другим игрокам, а так же попросить их.
Простенькая менюшка + вывод сообщений в чат.

Компилятор: 1.8.2 947

Команды:

Команды для вызова меню: /donate , /money , /transfer

.sma / .sp

#include < amxmodx >
#include < cstrike >
#include < fakemeta >

new TransferMoney[33], PlayerCredit[33]

public plugin_init() 
{
	register_plugin("Transfer Money", "1.0", "Maxee")
	register_clcmd("say /transfer", "transfermoney")
	register_clcmd("say /money", "transfermoney")
	register_clcmd("say /donate", "transfermoney")
}
//======================================================================
//= [Передача денег] Меню с игроками
//======================================================================
public transfermoney(id)
{
	new i, name[32], num[5], menu, menuitem[64]
	menu = menu_create("\r:[Сервер]: \yМеню передачи денег:\r", "transfermoney_choice")
	for(i=1; i<=32; i++)
	{
		if(is_user_connected(i))
		{
			if(get_user_team(id) == get_user_team(i) && id != i)
			{
				get_user_name(i, name, charsmax(name))
				formatex(menuitem, charsmax(menuitem), "%s [\r%i$\w]", name, cs_get_user_money(i))
				num_to_str(i, num, charsmax(num))
				menu_additem(menu, menuitem, num, 0)
			}
		}
	}
	menu_display(id, menu)
	return PLUGIN_HANDLED
}

//======================================================================
//= [Передача денег] Выбор в меню с игроками
//======================================================================
public transfermoney_choice(id, menu, item)
{
	if(item == MENU_EXIT)
		return PLUGIN_HANDLED
	new dst[32], data[5], access, callback
	menu_item_getinfo(menu, item, access, data, charsmax(data), dst, charsmax(dst), callback)
	menu_destroy(menu)
	PlayerCredit[id] = str_to_num(data)
	TransferMoney[id] = 0
	transfermoney_count(id)
	return PLUGIN_HANDLED
}

//======================================================================
//= [Передача денег] Меню с количеством денег
//======================================================================
public transfermoney_count(id)
{
	new menu, menuname[128], name[32]
	get_user_name(PlayerCredit[id], name, charsmax(name))
	formatex(menuname, charsmax(menuname), "\r:[Сервер]: \yПередать %i$ игроку %s", TransferMoney[id], name)
	menu = menu_create(menuname, "transfermoney_count_choice")
	if(cs_get_user_money(id) >= TransferMoney[id] + 100 && TransferMoney[id] <= 15900)
		menu_additem(menu, "Добавить 100$", "1", 0)
	else
		menu_additem(menu, "\dДобавить 100$", "1", 0)
	if(cs_get_user_money(id) >= TransferMoney[id] + 1000 && TransferMoney[id] <= 15000)
		menu_additem(menu, "Добавить 1000$", "2", 0)
	else
		menu_additem(menu, "\dДобавить 1000$", "2", 0)
	if(TransferMoney[id] >= 100)
		menu_additem(menu, "Отнять 100$", "3", 0)
	else
		menu_additem(menu, "\dОтнять 100$", "3", 0)
	if(TransferMoney[id] >= 1000)
		menu_additem(menu, "Отнять 1000$", "4", 0)
	else
		menu_additem(menu, "\dОтнять 1000$", "4", 0)
	if(cs_get_user_money(id) != 0)
		menu_additem(menu, "Добавить все деньги", "5", 0)
	else
		menu_additem(menu, "\dДобавить все деньги", "5", 0)
	if(TransferMoney[id] != 0)
		menu_additem(menu, "Отнять все деньги^n", "6", 0)
	else
		menu_additem(menu, "\dОтнять все деньги^n", "6", 0)
	if(TransferMoney[id] != 0)
		menu_additem(menu, "\rПередать", "7", 0)
	else
		menu_additem(menu, "\dПередать", "7", 0)
	menu_display(id, menu)
	return PLUGIN_HANDLED
}

//======================================================================
//= [Передача денег] Выбор в меню с количеством денег
//======================================================================
public transfermoney_count_choice(id, menu, item)
{
	if(item == MENU_EXIT) 
		return PLUGIN_HANDLED
	new name1[32], name2[32], data[5], dst[32], access, callback
	menu_item_getinfo(menu, item, access, data, charsmax(data), dst, charsmax(dst), callback)
	menu_destroy(menu)
	new key = str_to_num(data)
	switch(key)
	{
		case 1:
		{
			if(cs_get_user_money(id) >= TransferMoney[id] + 100)
			{
				if(TransferMoney[id] <= 15900)
					TransferMoney[id] = TransferMoney[id] + 100
				else
					ChatColor(id, "!g[Сервер]!t Количество денег для передачи достигло максимума.")
			}
			else
				ChatColor(id, "!g[Сервер]!t У Вас недостаточно денег.")
			transfermoney_count(id)
		}
		case 2:
		{
			if(cs_get_user_money(id) >= TransferMoney[id] + 1000)
			{
				if(TransferMoney[id] <= 15000)
					TransferMoney[id] = TransferMoney[id] + 1000
				else
					ChatColor(id, "!g[Сервер]!t Количество денег для передачи достигло максимума.")
			}
			else
				ChatColor(id, "!g[Сервер]!t У Вас недостаточно денег.")
			transfermoney_count(id)
		}
		case 3:
		{
			if(TransferMoney[id] >= 100)
				TransferMoney[id] = TransferMoney[id] - 100
			else
				ChatColor(id, "!g[Сервер]!t Количество денег для передачи достигло минимума.")
			transfermoney_count(id)
		}
		case 4:
		{
			if(TransferMoney[id] >= 1000)
				TransferMoney[id] = TransferMoney[id] - 1000
			else
				ChatColor(id, "!g[Сервер]!t Количество денег для передачи достигло минимума.")
			transfermoney_count(id)
		}
		case 5:
		{
			if(cs_get_user_money(id) != 0)
			{
				TransferMoney[id] = cs_get_user_money(id)

if(TransferMoney[id] > 16000)
					TransferMoney[id] = 16000
			}
			else
				ChatColor(id, "!g[Сервер]!t У Вас недостаточно денег.")
			transfermoney_count(id)
		}
		case 6:
		{
			if(TransferMoney[id] != 0)
				TransferMoney[id] = 0
			else
				ChatColor(id, "!g[Сервер]!t Нельзя отнять деньги, количество денег для передачи равно нулю.")
			transfermoney_count(id)
		}
		case 7:
		{
			if(TransferMoney[id] <= cs_get_user_money(id))
			{
				if(is_user_connected(PlayerCredit[id]))
				{
					get_user_name(id, name1, charsmax(name1))
					get_user_name(PlayerCredit[id], name2, charsmax(name2))
					cs_set_user_money(id, cs_get_user_money(id) - TransferMoney[id])
					cs_set_user_money(PlayerCredit[id], cs_get_user_money(PlayerCredit[id]) + TransferMoney[id])
					ChatColor(id, "!g[SERVER]!t Вы передали %i$ игроку %s.", TransferMoney[id], name2)
					ChatColor(PlayerCredit[id], "!g[Сервер]!t Игрок %s передал Вам %i$.", name1, TransferMoney[id])

if(cs_get_user_money(PlayerCredit[id]) > 16000)
						cs_set_user_money(PlayerCredit[id], 16000)

PlayerCredit[id] = 0
					TransferMoney[id] = 0
				}
				else
					ChatColor(id, "!g[Сервер]!t Игрок которому вы передаёте деньги отключился.")
			}
			else
				ChatColor(id, "!g[Сервер]!t У Вас недостаточно денег для передачи.")
		}
	}				
	return PLUGIN_HANDLED
}
stock ChatColor(const id, const input[], any:...)
{
	new count = 1, players[32];
	static msg[191];
	vformat(msg, 190, input, 3);
	
	replace_all(msg, 190, "!g", "^4");
	replace_all(msg, 190, "!y", "^1");
	replace_all(msg, 190, "!t", "^3");
	
	if (id) players[0] = id; else get_players(players, count, "ch");
	{
		for (new i = 0; i < count; i++)
		{
			if (is_user_connected(players[i]))
			{
				message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, players[i]);
				write_byte(players[i]);
				write_string(msg);
				message_end();
			}
		}
	}
}

Загрузил CS90

2019-01-08 11:46:03

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram