	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Ножи со скилами 1.1 (обновление)

Теги: Скачать плагины csМодели

Доброго времени суток.

Список изменений, которые пришли с обновлением:
- Убран CurWeapon на проверке способностей, сделал все на Ham_Item_Deploy, Ham_Item_Holster и Ham_CS_Item_GetMaxSpeed;
- Изменил алгоритм кода, проверки на способностях идут не по ножу, а по переменным. Все, что нужно менять - переменные в Ham_Item_Deploy на ножах;
- Добавил возможность убрать спрайты регенерации и отравления, для этого закомментируйте макрос #define SPRITES в самом верху;
- Изменил модель замораживающего ножа, многие хейтили комбат;
- Сток спрайтов регенерации и отравления вшил в один, а не в два, как было;
- Вывел в макрос настройки высоты второго прыжка( #define JUMP_POWER );

Планы на следующее обновление:
- Сделаю поддержку KNIFE MOD'A;
- Ножи с активной способностью и перезарядкой( для того же найф-мода );
- Возможность отключать нож, закомментировав одну строку в исходнике( пойдет для тех, кому не нравятся все ножи );
- Перерисовать спрайты отравления, вместо крестов будут исходить фиолетовые черепа;
- Добавить лед на ноги замороженной жертве;

Компилятор: 1.8.2 +ZIP 1080

Команды:

- Общие функции заморозки и отравления вывел в стоки;

Переменные для настроек в Ham_Item_Deploy | Ham_TakeDamage:

- Has_Jumps[ iPlayer/attacker ] = true/false( Если тру - у ножа есть 2 прыжка, если фолс - нет )

- Has_Speed[ iPlayer/attacker ] = true/false( Если тру - у ножа есть скорость, если фолс - нет )

- Has_Damage[ iPlayer/attacker ] = true/false( Если тру - у ножа есть двойной урон, если фолс - нет )

- Has_Regen[ iPlayer/attacker ] = true/false( Если тру - у ножа есть регенерация, если фолс - нет )

- Has_Poison[ iPlayer/attacker ] = true/false( Если тру - у ножа есть отравление, если фолс - нет )

- Has_Freeze[ iPlayer/attacker ] = true/false( Если тру - у ножа есть заморозка, если фолс - нет )

* iPlayer используем в Ham_Item_Deploy, attacker - в Ham_TakeDamage;

.sma / .sp

/* 
	Связь с автором:
	Vk Page: https://vk.com/liquid_exodus
	Vk Group: https://vk.com/exodus_plugs
*/

//#define DEATHRUN								/* Раскомментируйте, если используете Дезран-модификацию */
//#define ZOMBIEPLAGUE							/* Раскомментируйте, если используете Зомби-модификацию */

#define SPRITES								/* Раскомментируйте, если хотите использовать спрайты от регенерации и отравления, закомментируйте, если нет */

#include < amxmodx >
#include < hamsandwich >
#include < fakemeta_util >
#include < engine >
#if defined ZOMBIEPLAGUE
#include < zombieplague >
#endif

#define NAME 				"Knife Mode"
#define VERSION				"1.0"
#define AUTHOR				"Exodus"

#define COMMAND				"knife"				/* Команда, вызывающая меню ножей */

#define ACCESS_V			ADMIN_LEVEL_A		/* Флаг m для Вип-Ножа */
#define ACCESS_A			ADMIN_BAN			/* Флаг d Для Админ-Ножа */

#define SPEED_NORMAL		250.0				/* Нормальная скорость на сервере */
#define GRAVITY_NORMAL		0.9					/* Нормальная гравитация на сервере */
#define SPEED_POWER			300.0				/* Повышенная скорость от ножей */
#define GRAVITY_POWER		0.68				/* Пониженная гравитация от ножей */
#define DAMAGE_POWER		2.0					/* Повышенный множитель урона от ножей */
#define JUMP_POWER			300.0				/* Высота второго прыжка в воздухе */

#define REGEN_TIME			5.0					/* Интервал времени, через которое будет прибавляться здоровье от ножей */
#define REGEN_AMOUNT		15					/* Колличество здоровья, которое будет прибавляться от ножей */
#define REGEN_MAXIMAL		200					/* Максимальное колличество здоровья на сервере */
#define POISON_TREATMENT	20.0				/* Время в секундах, за которое игрок будет вылечен от "Яда" */
#define POISON_TIME			5.0					/* Интервал времени, через которое будет работать навык "Яд" */
#define POISON_AMOUNT		25					/* Колличество здоровья, которое будет отниматься при отравлении */
#define POISON_MINIMAL		5					/* Минимальное колличество здоровья, ниже которого навык отравления не будет работать */
#define TIME_FREEZE			3.0					/* Время, через которое будет разморожен игрок при "Заморозке" */
#define TIME_PROTECT		5.0					/* Время, через которое будет окончена защита при "Заморозке" */

static 
	Knife_Menu, 
	Regen_Sprite,
	Poison_Sprite,
	Frost_Sprite,
	Frost_Gibs,
	Knife_Number[ 33 ], 
	Jumps_Amount[ 33 ], 
	Jumps_Done[ 33 ],
	bool: Has_Jumps[ 33 ],
	bool: Has_Speed[ 33 ],
	bool: Has_Damage[ 33 ],
	bool: Has_Regen[ 33 ],
	bool: Has_Poison[ 33 ],
	bool: Has_Freeze[ 33 ],
	bool: In_Freeze[ 33 ],
	bool: In_Poison[ 33 ]

#if defined DEATHRUN
static 
	Duel_Mode[ 127 ]
#endif

static const Models_List[ 2 ][ 10 ][] = {
	{
		"",
		"models/Exodus_System/Knive/v_steels.mdl",
		"models/Exodus_System/Knive/v_combat.mdl",
		"models/Exodus_System/Knive/v_strong.mdl",
		"models/Exodus_System/Knive/v_dagger.mdl",
		"models/Exodus_System/Knive/v_kujang.mdl",
		"models/Exodus_System/Knive/v_splash.mdl",
		"models/Exodus_System/Knive/v_light.mdl",
		"models/Exodus_System/Knive/v_muerto.mdl",
		"models/Exodus_System/Knive/v_katana.mdl"
	},
	
	{
		"",
		"models/Exodus_System/Knive/p_steels.mdl",
		"models/Exodus_System/Knive/p_combat.mdl",
		"models/Exodus_System/Knive/p_strong.mdl",
		"models/Exodus_System/Knive/p_dagger.mdl",
		"models/Exodus_System/Knive/p_kujang.mdl",
		"models/Exodus_System/Knive/p_splash.mdl",
		"models/Exodus_System/Knive/p_light.mdl",
		"models/Exodus_System/Knive/p_muerto.mdl",
		"models/Exodus_System/Knive/p_katana.mdl"
	}
}

static const Sound_List[][] = {
	"Exodus_System/Knive/Regen.wav",
	"Exodus_System/Knive/Poison.wav",
	"Exodus_System/Knive/Freeze.wav",
	"Exodus_System/Knive/Unfreeze.wav"
}

public plugin_init() {
	register_plugin( NAME, VERSION, AUTHOR )
	
	Knife_Menu = menu_create( "Холодное оружие:", "Knife_Handle" )
	register_clcmd( COMMAND, "Knife_Function", ADMIN_ALL, "G_Knife_Menu" )
	Build_Menu()
	
	register_event( "HLTV", "Knife_Round", "a", "1=0", "2=0" )
	
	RegisterHam( Ham_TakeDamage, "player", "Knife_Damage", 0 )
	RegisterHam( Ham_Killed, "player", "Knife_Killed", 0 )
	RegisterHam( Ham_Item_Deploy, "weapon_knife", "Knife_Deploy", 1 )
	RegisterHam( Ham_Item_Holster, "weapon_knife", "Knife_Holster", 1 )
	RegisterHam( Ham_CS_Item_GetMaxSpeed, "player", "Player_Speed", 0 )
	RegisterHam( Ham_Player_Jump, "player", "Knife_Jumps" )
	RegisterHam( Ham_Player_PostThink, "player", "Knife_Ability" )
}

public plugin_precache() {
	for( new a = 1; a < 10; a++ ) {
		precache_model( Models_List[ 0 ][ a ] )
		precache_model( Models_List[ 1 ][ a ] )
	}
	for( new b; b < sizeof Sound_List; b++ ) {
		precache_sound( Sound_List[ b ] )
	}
	Regen_Sprite = precache_model( "sprites/Exodus_System/Knive/Regen.spr" )
	Poison_Sprite = precache_model( "sprites/Exodus_System/Knive/Poison.spr" )
	Frost_Sprite = precache_model( "sprites/Exodus_System/Knive/Frost.spr" )
	Frost_Gibs = precache_model( "models/glassgibs.mdl" )
}

public client_authorized( iPlayer ) Knife_Number[ iPlayer ] = 1

public client_disconnect( iPlayer ) {
	In_Poison[ iPlayer ] = false
	In_Freeze[ iPlayer ] = false
}

public Build_Menu() {
	menu_additem( Knife_Menu, "Нож \ySteels | \rСкорость", "1" )
	menu_additem( Knife_Menu, "Нож \yCombat | \rГравитация", "2" )
	menu_additem( Knife_Menu, "Нож \yStrong | \rДвойной Урон", "3" )
	menu_additem( Knife_Menu, "Нож \yDagger | \rДвойной Прыжок", "4" )
	menu_additem( Knife_Menu, "Нож \yKujang | \rРегенерация", "5" )
	menu_additem( Knife_Menu, "Нож \ySplash | \rОтравление", "6" )
	menu_additem( Knife_Menu, "Нож \yLight | \rЗаморозка", "7" )
	menu_additem( Knife_Menu, "Нож \yMuerto | Вип | \rСкорость|Урон|Прыжки|Яд", "8" )
	menu_additem( Knife_Menu, "Нож \yKatana | Админ | \rВсе Способности", "9" )
	menu_setprop( Knife_Menu, MPROP_BACKNAME, "Назад" ) 
	menu_setprop( Knife_Menu, MPROP_NEXTNAME, "Вперёд" )
	menu_setprop( Knife_Menu, MPROP_EXITNAME, "Выход" )
}

public Knife_Function( iPlayer ) {
	#if defined DEATHRUN
	get_cvar_string( "deathrun_mode", Duel_Mode, charsmax( Duel_Mode ) )
	#endif
	if( !is_user_alive( iPlayer ) ) {
		Color_Print( iPlayer, "!g[Ножи] Недоступны для мертвых!" )
		return
	}
	#if defined ZOMBIEPLAGUE
	else if( zp_get_user_zombie( iPlayer ) || zp_get_user_nemesis( iPlayer ) || zp_get_user_survivor( iPlayer ) ) {
		Color_Print( iPlayer, "!g[Ножи] Недоступны для зомби, немезиды или выжившего!" )
		return
	}
	#endif
	#if defined DEATHRUN
	else if( ( equal( Duel_Mode, "DUEL" ) ) ) {
		Color_Print( iPlayer, "!g[Ножи] Недоступны в дуэли!" )
		return
	}
	#endif
	else {
		menu_display( iPlayer, Knife_Menu, 0 )
	}
}

public Knife_Handle( iPlayer, menu, item ) {
	if( item < 0 ) {
		return PLUGIN_CONTINUE
	}
	new cmd[ 2 ]
	new access, callback
	menu_item_getinfo( menu, item, access, cmd,2, _, _, callback )
	new choice = str_to_num( cmd )
	switch ( choice ) {
		case 1: {
			Knife_Number[ iPlayer ] = 1
			Color_Print( iPlayer, "!g[Ножи] !teamВаша способность: !gСкорость" )
			Play_Anim( iPlayer )
		}
		case 2: {
			Knife_Number[ iPlayer ] = 2
			Color_Print( iPlayer, "!g[Ножи] !teamВаша способность: !gГравитация" )
			Play_Anim( iPlayer )
		}
		case 3: {
			Knife_Number[ iPlayer ] = 3
			Color_Print( iPlayer, "!g[Ножи] !teamВаша способность: !gУрон" )
			Play_Anim( iPlayer )
		}
		case 4: {
			Knife_Number[ iPlayer ] = 4
			Color_Print( iPlayer, "!g[Ножи] !teamВаша способность: !gДвойной Прыжок" )
			Play_Anim( iPlayer )
		}
		case 5: {
			Knife_Number[ iPlayer ] = 5
			Color_Print( iPlayer, "!g[Ножи] !teamВаша способность: !gРегенерация" )
			Play_Anim( iPlayer )
		}
		case 6: {
			Knife_Number[ iPlayer ] = 6
			Color_Print( iPlayer, "!g[Ножи] !teamВаша способность: !gОтравление" )
			Play_Anim( iPlayer )
		}
		case 7: {
			Knife_Number[ iPlayer ] = 7
			Color_Print( iPlayer, "!g[Ножи] !teamВаша способность: !gЗаморозка" )
			Play_Anim( iPlayer )
		}
		case 8: {
			if( get_user_flags( iPlayer ) & ACCESS_V ) {
				Knife_Number[ iPlayer ] = 8
				Color_Print( iPlayer, "!g[Ножи] !teamВаши способности: !gСкорость, Урон, Прыжки, Яд" )
				Play_Anim( iPlayer )
			}
			else {
				Knife_Function( iPlayer )
				Color_Print( iPlayer, "!g[Ножи] !teamСперва купи привелегию !gВип!" )
			}
		}
		case 9: {
			if( get_user_flags( iPlayer ) & ACCESS_A ) {
				Knife_Number[ iPlayer ] = 9
				Color_Print( iPlayer, "!g[Ножи] !teamВаши способности: !gВсе Возможные" )
				Play_Anim( iPlayer )
			}
			else {
				Knife_Function( iPlayer )
				Color_Print( iPlayer, "!g[Ножи] !teamСперва купи привелегию !gАдмин!" )
			}
		}
	}
	return PLUGIN_HANDLED
}

public Knife_Round() { 
	new iPlayers[ 32 ], iCount, iPlayer
	get_players( iPlayers, iCount, "ch" ) 
	for( new i = 0; i < iCount; i++ ) {
		iPlayer = iPlayers[ i ]
		if( In_Poison[ iPlayer ] ) {
			In_Poison[ iPlayer ] = false
		}
		if( In_Freeze[ iPlayer ] ) {
			In_Freeze[ iPlayer ] = false
		}
	}
}

public Knife_Deploy( iEnt ) {
	new iPlayer = pev( iEnt, pev_owner )
	  
	if( !is_user_alive( iPlayer ) )
		return HAM_IGNORED
	
	#if defined ZOMBIEPLAGUE
	if( zp_get_user_zombie( iPlayer ) || zp_get_user_nemesis( iPlayer ) || zp_get_user_survivor( iPlayer ) ) {
		return HAM_IGNORED
	}
	#endif
	#if defined DEATHRUN
	get_cvar_string( "deathrun_mode", Duel_Mode, charsmax( Duel_Mode ) )
	if( ( equal( Duel_Mode, "DUEL" ) ) ) {
		return HAM_IGNORED
	}
	#endif
	
	Has_Speed[ iPlayer ] = true

switch( Knife_Number[ iPlayer ] ) {
		case 1: {
			Has_Damage[ iPlayer ] = false
			Has_Jumps[ iPlayer ] = false
			Has_Regen[ iPlayer ] = false
			Has_Poison[ iPlayer ] = false
			Has_Freeze[ iPlayer ] = false
			fm_set_user_gravity( iPlayer, GRAVITY_NORMAL )
		}
		case 2: {
			Has_Damage[ iPlayer ] = true
			Has_Jumps[ iPlayer ] = false
			Has_Regen[ iPlayer ] = false
			Has_Poison[ iPlayer ] = false
			Has_Freeze[ iPlayer ] = false
			fm_set_user_gravity( iPlayer, GRAVITY_POWER )
		}
		case 3: {
			Has_Damage[ iPlayer ] = true
			Has_Jumps[ iPlayer ] = false
			Has_Regen[ iPlayer ] = false
			Has_Poison[ iPlayer ] = false
			Has_Freeze[ iPlayer ] = false
			fm_set_user_gravity( iPlayer, GRAVITY_NORMAL )
		}
		case 4: {
			Has_Damage[ iPlayer ] = false
			Has_Jumps[ iPlayer ] = true
			Has_Regen[ iPlayer ] = false
			Has_Poison[ iPlayer ] = false
			Has_Freeze[ iPlayer ] = false
			fm_set_user_gravity( iPlayer, GRAVITY_NORMAL )
		}
		case 5: {
			Has_Damage[ iPlayer ] = false
			Has_Jumps[ iPlayer ] = false
			Has_Regen[ iPlayer ] = true
			Has_Poison[ iPlayer ] = false
			Has_Freeze[ iPlayer ] = false
			fm_set_user_gravity( iPlayer, GRAVITY_NORMAL )
		}
		case 6: {
			Has_Damage[ iPlayer ] = true
			Has_Jumps[ iPlayer ] = false
			Has_Regen[ iPlayer ] = false
			Has_Poison[ iPlayer ] = true
			Has_Freeze[ iPlayer ] = false
			fm_set_user_gravity( iPlayer, GRAVITY_NORMAL )
		}
		case 7: {
			Has_Damage[ iPlayer ] = true
			Has_Jumps[ iPlayer ] = false
			Has_Regen[ iPlayer ] = false
			Has_Poison[ iPlayer ] = false
			Has_Freeze[ iPlayer ] = true
			fm_set_user_gravity( iPlayer, GRAVITY_NORMAL )
		}
		case 8: {
			Has_Damage[ iPlayer ] = true
			Has_Jumps[ iPlayer ] = true
			Has_Regen[ iPlayer ] = false
			Has_Poison[ iPlayer ] = true
			Has_Freeze[ iPlayer ] = false
			fm_set_user_gravity( iPlayer, GRAVITY_NORMAL )
		}
		case 9: {
			Has_Damage[ iPlayer ] = true
			Has_Jumps[ iPlayer ] = true
			Has_Regen[ iPlayer ] = true
			Has_Poison[ iPlayer ] = true
			Has_Freeze[ iPlayer ] = true
			fm_set_user_gravity( iPlayer, GRAVITY_POWER )
		}
	}
	set_pev( iPlayer, pev_viewmodel2, Models_List[ 0 ][ Knife_Number[ iPlayer ] ] )
	set_pev( iPlayer, pev_weaponmodel2, Models_List[ 1 ][ Knife_Number[ iPlayer ] ] )
	
	return HAM_IGNORED
}

public Knife_Holster( iEnt ) {
	new iPlayer = pev( iEnt, pev_owner )
	  
	if( !is_user_alive( iPlayer ) )
		return HAM_IGNORED
		
	Has_Damage[ iPlayer ] = false
	Has_Speed[ iPlayer ] = false
	Has_Jumps[ iPlayer ] = false
	Has_Regen[ iPlayer ] = false
	Has_Poison[ iPlayer ] = false
	Has_Freeze[ iPlayer ] = false
	fm_set_user_gravity( iPlayer, GRAVITY_NORMAL )
	set_pev( iPlayer, pev_maxspeed, SPEED_NORMAL )
	
	return HAM_IGNORED
}

public Player_Speed( iPlayer ) {
	if( !is_user_alive( iPlayer ) || get_user_weapon( iPlayer ) != CSW_KNIFE || !Has_Speed[ iPlayer ] ) {
		return
	}
	switch( Knife_Number[ iPlayer ] ) {
		case 1: {
			set_pev( iPlayer, pev_maxspeed, SPEED_POWER  )
		}
		case 2..7: {
			set_pev( iPlayer, pev_maxspeed, SPEED_NORMAL )
		}
		case 8..9: {
			set_pev( iPlayer, pev_maxspeed, SPEED_POWER  )
		}
	}
}

public Knife_Damage( victim, inflictor, attacker, Float: damage, bits ) {
	if( !is_user_connected( attacker ) || get_user_weapon( attacker ) != CSW_KNIFE || get_user_team( victim ) == get_user_team( attacker ) || !is_user_alive( attacker ) )
		return HAM_IGNORED
	#if defined ZOMBIEPLAGUE
	if( zp_get_user_zombie( attacker ) || zp_get_user_nemesis( attacker ) || zp_get_user_survivor( attacker ) ) {
		return HAM_IGNORED
	}
	#endif
	#if defined DEATHRUN
	get_cvar_string( "deathrun_mode", Duel_Mode, charsmax( Duel_Mode ) )
	if( ( equal( Duel_Mode, "DUEL" ) ) ) {
		return HAM_IGNORED
	}
	#endif
	if( Has_Damage[ attacker ] ) {
		SetHamParamFloat( 4, damage * DAMAGE_POWER )
	}
	if( Has_Poison[ attacker ] ) {
		Poison_Try( victim )
	}
	if( Has_Freeze[ attacker ] ) {
		Freeze_Try( victim )
	}
	return HAM_IGNORED
}

public Func_Poison( victim ) {
	In_Poison[ victim ] = true
	Color_Print( victim, "!g[Здоровье] !teamВас отравили на 20 секунд!" )
	set_task( POISON_TREATMENT, "Treatment", 7513 + victim )
}

public Func_Freeze( victim ) {
	Screen_Fade( victim, 0, 0, 255, 90 )
	set_rendering( victim, kRenderFxGlowShell, 0, 100, 200, kRenderNormal, 30 )
	if( ~pev( victim, pev_flags ) & FL_FROZEN ) set_pev( victim, pev_flags, pev( victim, pev_flags ) | FL_FROZEN ) 
	new Float: Origin[ 3 ]
	pev( victim, pev_origin, Origin )
	Origin[ 2 ] -= 35.0
	Frost_Effect( Origin )
	emit_sound( victim, CHAN_BODY, Sound_List[ 2 ], VOL_NORM, ATTN_NORM, 0, PITCH_NORM )
	In_Freeze[ victim ] = true
	Color_Print( victim, "!g[Информация] !teamВы заморожены на 3 секунды!" )
	set_task( TIME_FREEZE, "Unfreeze", 7512 + victim )
	set_task( TIME_PROTECT, "Protect", 7511 + victim )
}

public Treatment( taskid ) {
	new id = taskid - 7513
	if( !is_user_alive( id ) ) {
		return
	}
	In_Poison[ id ] = false
	Color_Print( id, "!g[Здоровье] !teamДействие яда успешно завершено!" )
}

public Unfreeze( taskid ) {
	new id = taskid - 7512
	if( !is_user_alive( id ) ) {
		return
	}
	set_rendering( id )
	if( pev( id, pev_flags ) & FL_FROZEN ) set_pev( id, pev_flags, pev( id, pev_flags ) & ~FL_FROZEN )
	emit_sound( id, CHAN_BODY, Sound_List[ 3 ], VOL_NORM, ATTN_NORM, 0, PITCH_NORM )
	Color_Print( id, "!g[Информация] !teamВы разморожены и снова можете двигаться!" )
	
	static iOrigin[ 3 ]
	get_user_origin( id, iOrigin )

message_begin( MSG_PVS, SVC_TEMPENTITY, iOrigin )
	write_byte( TE_BREAKMODEL )
	write_coord( iOrigin[ 0 ] )
	write_coord( iOrigin[ 1 ] )
	write_coord( iOrigin[ 2 ] + 24 )
	write_coord( 16 )
	write_coord( 16 )
	write_coord( 16 )
	write_coord( random_num( -50, 50 ) )
	write_coord( random_num( -50, 50 ) )
	write_coord( 25 )
	write_byte( 10 )
	write_short( Frost_Gibs )
	write_byte( 10 )
	write_byte( 25 )
	write_byte( 0x01 )
	message_end()
}

public Protect( taskid ) {
	new id = taskid - 7511
	if( !is_user_alive( id ) ) {
		return
	}
	In_Freeze[ id ] = false
}

public Knife_Killed( victim, attacker, shouldgib ) {
	if( In_Freeze[ victim ] ) {
		set_rendering( victim )
		if( pev( victim, pev_flags ) & FL_FROZEN ) set_pev( victim, pev_flags, pev( victim, pev_flags ) & ~FL_FROZEN )
		In_Freeze[ victim ] = false
	}
	if( In_Poison[ victim ] ) {
		In_Poison[ victim ] = false
	}
}

public Knife_Jumps( iPlayer ) {
	if( Has_Jumps[ iPlayer ] ) {
		#if defined ZOMBIEPLAGUE
		if( zp_get_user_zombie( iPlayer ) || zp_get_user_nemesis( iPlayer ) || zp_get_user_survivor( iPlayer ) ) {
			return PLUGIN_CONTINUE
		}
		#endif
		#if defined DEATHRUN
		get_cvar_string( "deathrun_mode", Duel_Mode, charsmax( Duel_Mode ) )
		if( ( equal( Duel_Mode, "DUEL" ) ) ) {
			return PLUGIN_CONTINUE
		}
		#endif
		new szButton = pev( iPlayer, pev_button )
		new szOldButton = pev( iPlayer, pev_oldbuttons )
 
		if( ( szButton & IN_JUMP ) && !( pev( iPlayer, pev_flags ) & FL_ONGROUND ) && !( szOldButton & IN_JUMP ) ) {
			if( Jumps_Amount[ iPlayer ] < 1 ) {
				Jumps_Done[ iPlayer ] = true
				Jumps_Amount[ iPlayer ]++
				Jump_Think_Post( iPlayer )
				return PLUGIN_CONTINUE
			}
		}
		if( ( szButton & IN_JUMP ) && ( pev( iPlayer, pev_flags) & FL_ONGROUND ) ) {
			Jumps_Amount[ iPlayer ] = 0
		}
	}
	return PLUGIN_CONTINUE
}

public Jump_Think_Post( iPlayer ) {
	if( Has_Jumps[ iPlayer ] ) {
		if( !is_user_alive( iPlayer ) ) {
			return PLUGIN_CONTINUE
		}
		#if defined ZOMBIEPLAGUE
		if( zp_get_user_zombie( iPlayer ) || zp_get_user_nemesis( iPlayer ) || zp_get_user_survivor( iPlayer ) ) {
			return PLUGIN_CONTINUE
		}
		#endif
		#if defined DEATHRUN
		get_cvar_string( "deathrun_mode", Duel_Mode, charsmax( Duel_Mode ) )
		if( ( equal( Duel_Mode, "DUEL" ) ) ) {
			return PLUGIN_CONTINUE
		}
		#endif
	
		if( Jumps_Done[ iPlayer ] ) {
			new Float:szVelocity[ 3 ]  
			pev( iPlayer, pev_velocity, szVelocity )
			szVelocity[ 2 ] = JUMP_POWER
			set_pev( iPlayer, pev_velocity, szVelocity )
			Jumps_Done[ iPlayer ] = false
			return PLUGIN_CONTINUE
		}
	}
	return PLUGIN_CONTINUE
}

public Knife_Ability( iPlayer ) {
	if( get_user_weapon( iPlayer ) != CSW_KNIFE ) {
		return
	}
	#if defined ZOMBIEPLAGUE
	if( zp_get_user_zombie( iPlayer ) || zp_get_user_nemesis( iPlayer ) || zp_get_user_survivor( iPlayer ) ) {
		return
	}
	#endif
	#if defined DEATHRUN
	get_cvar_string( "deathrun_mode", Duel_Mode, charsmax( Duel_Mode ) )
	if( ( equal( Duel_Mode, "DUEL" ) ) ) {
		return
	}
	#endif
	new Float: gt = get_gametime()
	static Float: lim[ 33 ]
	if( lim[ iPlayer ] < gt ){
		lim[ iPlayer ]= gt + REGEN_TIME
		if( Has_Regen[ iPlayer ] ) {
			if( is_user_alive( iPlayer ) ) {
				if( get_user_health( iPlayer ) < REGEN_MAXIMAL ) {
				fm_set_user_health( iPlayer, get_user_health( iPlayer ) + min( ( REGEN_MAXIMAL - get_user_health( iPlayer ) ), REGEN_AMOUNT ) )
				client_cmd( iPlayer, "spk %s", Sound_List[ 0 ] )
				Color_Print( iPlayer, "!g[Здоровье] !teamВы восстановили %d здоровья", REGEN_AMOUNT )
				Screen_Fade( iPlayer, 0, 255, 20, 50 )
				#if defined SPRITES
				new Float: Origin[ 3 ]
				pev( iPlayer, pev_origin, Origin )
				Origin[ 2 ] -= 35.0
				Sprite_Effect( Origin, 1 )
				#endif
				}
				else {
					return
				}
			}
		}
	}
	new Float: gt2 = get_gametime()
	static Float: lim2[ 33 ]
	if( lim2[ iPlayer ] < gt2 ){
		lim2[ iPlayer ]= gt2 + POISON_TIME
		if( In_Poison[ iPlayer ] ) {
			if( is_user_alive( iPlayer ) ) {
				if( get_user_health( iPlayer ) > POISON_MINIMAL ) {
				fm_set_user_health( iPlayer, get_user_health( iPlayer ) - min( ( get_user_health( iPlayer ) - POISON_MINIMAL ), POISON_AMOUNT ) )
				client_cmd( iPlayer, "spk %s", Sound_List[ 1 ] )
				Color_Print( iPlayer, "!g[Здоровье] !teamВы отравлены и получаете %d урона от Яда.", POISON_AMOUNT )
				Screen_Fade( iPlayer, 255, 70, 20, 50 )
				#if defined SPRITES
				new Float: Origin[ 3 ]
				pev( iPlayer, pev_origin, Origin )
				Origin[ 2 ] -= 35.0
				Sprite_Effect( Origin, 2 )
				#endif
				}
				else {
					return
				}
			}
		}
	}
}

stock Play_Anim( iPlayer ) {
	new iEnt = get_pdata_cbase( iPlayer, 373, 5 )
	if( pev_valid( iEnt ) && get_user_weapon( iPlayer ) == CSW_KNIFE ) {
		ExecuteHamB( Ham_Item_Deploy, iEnt )
	}
}

stock Poison_Try( victim ) {
	if( !In_Poison[ victim ] ) {
		Func_Poison( victim )
	}
}

stock Freeze_Try( victim ) {
	if( !In_Freeze[ victim ] ) {
		Func_Freeze( victim )
	}
}

stock Sprite_Effect( Float: origin[ 3 ], number = 1 ) {
	message_begin( MSG_BROADCAST, SVC_TEMPENTITY )
	write_byte( TE_SPRITE )
	engfunc( EngFunc_WriteCoord, origin[ 0 ] )
	engfunc( EngFunc_WriteCoord, origin[ 1 ] )
	engfunc( EngFunc_WriteCoord, origin[ 2 ] + 45 )
	switch( number ) {
		case 1: {
			write_short( Regen_Sprite )
		}
		case 2: {
			write_short( Poison_Sprite )
		}
	}
	write_byte( 15 )
	write_byte( 255 )
	message_end()
}

stock Frost_Effect( Float: origin[ 3 ] ) {
	message_begin( MSG_BROADCAST, SVC_TEMPENTITY )
	write_byte( TE_SPRITETRAIL )
	engfunc( EngFunc_WriteCoord, origin[ 0 ] )
	engfunc( EngFunc_WriteCoord, origin[ 1 ] )
	engfunc( EngFunc_WriteCoord, origin[ 2 ] + 45 )
	engfunc( EngFunc_WriteCoord, origin[ 0 ] )
	engfunc( EngFunc_WriteCoord, origin[ 1 ] )
	engfunc( EngFunc_WriteCoord, origin[ 2 ] + 30 )
	write_short( Frost_Sprite )
	write_byte( 60 )
	write_byte( random_num( 25, 30 ) )
	write_byte( 2 )
	write_byte( 50 )
	write_byte( 10 )
	message_end()
}

stock Screen_Fade( iPlayer, Red, Green, Blue, Alpha ) {
	if( !is_user_connected( iPlayer ) ) {
		return
	}
	message_begin ( MSG_ONE_UNRELIABLE, get_user_msgid ( "ScreenFade" ), { 0, 0, 0 }, iPlayer )
	write_short ( 1 << 10 )
	write_short ( 1 << 11 )
	write_short ( 0x0000 )
	write_byte( Red )
	write_byte( Green )
	write_byte( Blue )
	write_byte( Alpha )
	message_end()
}

stock Color_Print( const iPlayer, const input[], any:... ) {
	new count = 1, players[ 32 ]
	static msg[ 191 ]
	vformat( msg, 190, input, 3 )
	replace_all( msg, 190, "!g", "^4" )
	replace_all( msg, 190, "!y", "^1" )
	replace_all( msg, 190, "!team", "^3" )
	if( iPlayer ) {
		players[ 0 ] = iPlayer
	}
	else {
		get_players( players, count, "ch" )
	}
	for ( new i = 0; i < count; i++ ) {
		if (is_user_connected( players[ i ] ) ) {
			message_begin( MSG_ONE_UNRELIABLE, get_user_msgid( "SayText" ), _, players[ i ] )
			write_byte( players[ i ] )
			write_string( msg )
			message_end()
		}
	}
}

Загрузил popca2424

2018-11-22 14:29:45

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram