	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Плагин - "Damage-Roulette"

Теги: Скачать плагины csСерверные

Плагин Damage-Roulette добавит на твой сервер CS 1.6 рулетку в начале раунда.
Т.е. рандомному игроку выпадет увеличенный дамаг.
Тем самым зайдя на сервер игрок зависнет у вас, т.к захочет получить бонус.

Компилятор: 1.8.3 +ZIP 1007

Команды:

В .sma

#define AUTOMATIC_CONFIG //Автоматическое создание CFG.

#define OPERATION_FIREWORKS //Влияет на работу феерверка (если закомментировано, то ресурсы для феерверка скачиваться не будут, а также все что связано с этим).

.sma / .sp

/*
* - ----------
Плагин - "Damage-Roulette" // Rus: "Урон-Рулетка"
* - ---------- 
Описание - Разыгрывание (в виде рулетки) увеличенного дамага при старте нового раунда среди игроков.
* - ---------- 
Благодарность за помощь (содействие): - Mistrick, w0w
* - ---------- 
Благодарность за перевод на разные языки: wellasgood
* - ---------- 
Поддержка плагина:
* - ---------- 
Dev-Cs: @wellasgood 
vk: https://vk.com/d1mkin
Telegram: @WellAsGood
* - ---------- 
* - ---------- 
* - Версии:
* - ----------
* - ----------
* - ver 1.0:
- Создание основных функций плагина.
- Переработан алгоритм рулетки с учетом того, что id не нужен при вызове тасков, так как подставляем 0 в разных случаях.
- Добавлена система запуска поздравительного феерверка для победителя рулетки.
- Добавлен 'stock SendAudio' (Музыку слышат Стим и Нон-Стим)
- Оптимизация всего кода для легкости.
- Добавлены новые квары, для гибкости и удобства настройки кода.
- Произведена проверка на работаспособность в игре. (рекмендуется при эксплуатации не ставить слишком болишие значения (цифры))
- Добавлено Bug, оповещания игроков отладка в виде HUD сообщений при ошибке.
* - ver 1.1:
- get_playersnum заменено на get_players_ex.
- register_cvar заменен на create_cvar(...).
- Отключение не нужных карт, перемещено после регистрации плагина.
- При отключении карт (префиксов), если после префа карты идет '_', пример: awp_, то нужно вписывать так: "awp_", "cs_" и тп.
- Добавлены валидные таски к задачам.
- Проверка на валидность игроков переработана.
- Подстановка значений с работой SendAudio исправлено на валидные значения.
- Подправлены другие маленькие моменты кода, для его оптимизации и улучшения.
- Переработан код показа HUD сообщений. (улучшен (с учетом использования AMXX 1.9.0+), укорочен)
- Подправлен LANG файл.
* - ver 1.2:
- Критичное обновление!
- Подправлен код в части: g_iRndPlayer = iPlayers[random(iPlayerCount)]; (если iPlayerCount == 0, то будет ошибка на сервере! Добавлена проверка.)
- Спасибо: Mistrick
* - ver 1.3:
- Изменены лимиты на значение квара где оно может быть большим: с 'true, 0.0, true, 32.0' на 'false, 0.0, false, 0.0'
* - ver 1.3.1:
- Переход на 3-х значную версию.
- Рефакторинг кода. (добавлены enum и другое)
- Добавлено автоматическое создание CFG.
- Изменены таски к задачам.
- Изменены set_task на set_task_ex.
- Убран код по выключению ненужных карт. (за ненадобностью)
- Были переработаны некоторые функции.
- Изменены названия функций и другие правки.
- Описание кваров изменены на более читабельные, а также правильнее по смыслу.
- Уход за кодом.
* - ----------
* - ----------
* - Актуальная версия плагина (конечная с учетом переделок: ver 1.3.1)
* - ----------
*/

#include <amxmodx>
#include <hamsandwich>
#include <amxmisc>

#define AUTOMATIC_CONFIG //Автоматическое создание CFG.
#define OPERATION_FIREWORKS //Влияет на работу феерверка (если закомментировано, то ресурсы для феерверка скачиваться не будут, а также все что связано с этим).

new const PLUGIN[] = "Damage-Roulette";
new const VERSION[] = "1.3.1";
new const AUTHOR[] = "wellasgood";

new const SND_MR[] = "damage-roulette/mr.wav";
new const SND_RT[] = "damage-roulette/rt.wav";

enum _:CvarData
{
	DMG_NUMBER,
	DMG_PLAYERS,
	Float:DMG_TIME_NEXT_ONE,
	Float:DMG_TIME_NEXT_TWO,
	Float:DMG_HUD_BUG_TIME_ONE,
	Float:DMG_HUD_BUG_TIME_TWO,
	DMG_SCROLL_ALLOW,
	DMG_SCROLL_EXIT,
	Float:DMG_SCROLL_SPEEDY,
	Float:DMG_SCROLL_SLOW,
	Float:DMG_SCROLL_HUD_ONE,
	Float:DMG_SCROLL_HUD_TWO,
	Float:DMG_SCROLL_HUD_THREE
};

enum _:TaskData //Уникальные идентификаторы к задачам set_task_ex.
{
	TASK_ID_ONE = 1693, //запуск основого скролла рулетки
	TASK_ID_TWO = 2582, //первый длинный запуск быстрого прохода (с показом в худ)
	TASK_ID_THREE = 3169, //обратная отдача скроллу в скролл
	TASK_ID_FOUR = 4561, //основыне быстрые проходы
	TASK_ID_FIVE = 5902, //переключение на медленные проходы до выхода скролла
	TASK_ID_SIX = 6125, //включение функции феерверка победителю
	TASK_ID_SEVEN = 7047, //повторные запуски феерверка
	TASK_ID_EIGHT = 8369, //запуск ошибко-инфо в Hud о том почему не рабоатет плагин в раунде
	TASK_ID_NINE = 9851 //запуск ошибко-инфо в Hud о причине почему не рабоатет плагин в раунде
};

#if defined OPERATION_FIREWORKS
enum _:FireworkData
{
	DMG_FIREWORK_EN,
	DMG_FIREWORK_NUM,
	Float:DMG_FIREWORK_TIME_ONE,
	Float:DMG_FIREWORK_TIME_TWO,
	DMG_FIREWORK_MSG
};

new eFireworkData[FireworkData], g_shortSpr[6], g_FireworkCount, g_short[6][] =
{
	"sprites/damage-roulette/3dmflared.spr",
	"sprites/damage-roulette/3dmflaora.spr",
	"sprites/damage-roulette/frostgib.spr",
	"sprites/damage-roulette/ledglow.spr",
	"sprites/damage-roulette/pink.spr",
	"sprites/damage-roulette/star_gib.spr"
};
#endif

new eCvarData[CvarData], eTaskData[TaskData], g_iPlayers[MAX_PLAYERS], g_iPlayerCount, g_iRndPlayer, g_Scroll;

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR);

register_logevent("round_start", 2, "0=World triggered", "1=Round_Start");
	register_dictionary("damage-roulette.txt");

RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage", 0);
	RegisterCvars();

#if defined AUTOMATIC_CONFIG
	AutoExecConfig(true, "Damage-Roulette");
#endif
}

public RegisterCvars()
{
	new Cvar;

Cvar = create_cvar("dmg_number", "5", FCVAR_NONE, "Num of damage (how much in + to the winner's damage)", false, 0.0, false, 0.0); //Кол-во урона.
	bind_pcvar_num(Cvar, eCvarData[DMG_NUMBER]);

Cvar = create_cvar("dmg_players", "2", FCVAR_NONE, "Num of players that will work after recruitment.", true, 0.0, true, 32.0); //Кол-во игроков, после набора которых будет работать.
	bind_pcvar_num(Cvar, eCvarData[DMG_PLAYERS]);

Cvar = create_cvar("dmg_time_next_one", "6.0", FCVAR_NONE, "The time before the error starts. (small player)", false, 0.0, false, 0.0); //Время до запуска ошибки. (мало игроков)
	bind_pcvar_float(Cvar, eCvarData[DMG_TIME_NEXT_ONE]);

Cvar = create_cvar("dmg_time_next_two", "4.0", FCVAR_NONE, "Time from the new round to the work of all.", false, 0.0, false, 0.0); //Время от нового раунда до работы всего.
	bind_pcvar_float(Cvar, eCvarData[DMG_TIME_NEXT_TWO]);

Cvar = create_cvar("dmg_bug_end_one", "3.0", FCVAR_NONE, "The time of the extinction of the warning errors run.", false, 0.0, false, 0.0); //Время угасания оповещания ошибки запуска.
	bind_pcvar_float(Cvar, eCvarData[DMG_HUD_BUG_TIME_ONE]);

Cvar = create_cvar("dmg_bug_end_two", "3.0", FCVAR_NONE, "Time of fading of the notification of the cause of the launch error.", false, 0.0, false, 0.0); //Время угасания оповещания причины ошибки запуска.
	bind_pcvar_float(Cvar, eCvarData[DMG_HUD_BUG_TIME_TWO]);

#if defined OPERATION_FIREWORKS
	Cvar = create_cvar("dmg_fw_en", "1", FCVAR_NONE, "Firework launch to the winner. (off|on > 0|1)", true, 0.0, true, 1.0); //Запуск феерверка победителю.
	bind_pcvar_num(Cvar, eFireworkData[DMG_FIREWORK_EN]);

Cvar = create_cvar("dmg_fw_num", "5", FCVAR_NONE, "The num of consecutive start of the fireworks to the winner.", false, 0.0, false, 0.0); //Кол-во раз подряд запуска феерверка.
	bind_pcvar_num(Cvar, eFireworkData[DMG_FIREWORK_NUM]);

Cvar = create_cvar("dmg_fw_time_one", "0.3", FCVAR_NONE, "Time until the initial charge of the fireworks.", false, 0.0, false, 0.0); //Время до первичного заряда феерверка.
	bind_pcvar_float(Cvar, eFireworkData[DMG_FIREWORK_TIME_ONE]);

Cvar = create_cvar("dmg_fw_time_two", "0.8", FCVAR_NONE, "Time to re-charge the fireworks.", false, 0.0, false, 0.0); //Время до повторного заряда феерверка.
	bind_pcvar_float(Cvar, eFireworkData[DMG_FIREWORK_TIME_TWO]);

Cvar = create_cvar("dmg_fw_msg", "1", FCVAR_NONE, "Visibility of fireworks near the player. (all|one > 0|1)", true, 0.0, true, 1.0); //Видимость феерверка около игрока.
	bind_pcvar_num(Cvar, eFireworkData[DMG_FIREWORK_MSG]);
#endif

Cvar = create_cvar("dmg_scroll_allow", "30", FCVAR_NONE, "Num, for the passage of the rapid sounds of roulette.", false, 0.0, false, 0.0); //Кол-во, для прохода быстрых звуков рулетки.
	bind_pcvar_num(Cvar, eCvarData[DMG_SCROLL_ALLOW]);

Cvar = create_cvar("dmg_scroll_exit", "35", FCVAR_NONE, "Max num of roulette, after which there will be a victory.", false, 0.0, false, 0.0); //Макс кол-во рулетки, после которого будет победа.
	bind_pcvar_num(Cvar, eCvarData[DMG_SCROLL_EXIT]);

Cvar = create_cvar("dmg_scroll_speedy", "0.1", FCVAR_NONE, "For quick passage of the roulette sound.", false, 0.0, false, 0.0); //Для быстрого прохода звука рулетки.
	bind_pcvar_float(Cvar, eCvarData[DMG_SCROLL_SPEEDY]);

Cvar = create_cvar("dmg_scroll_slow", "0.7", FCVAR_NONE, "For slow passage of the roulette sound.", false, 0.0, false, 0.0); //Для медленного прохода звука рулетки.
	bind_pcvar_float(Cvar, eCvarData[DMG_SCROLL_SLOW]);

Cvar = create_cvar("dmg_scroll_end_one", "5.0", FCVAR_NONE, "For fading hud messages (the initial info about the plugin).", false, 0.0, false, 0.0); //Для угасания hud (начальное инфо о плагине).
	bind_pcvar_float(Cvar, eCvarData[DMG_SCROLL_HUD_ONE]);

Cvar = create_cvar("dmg_scroll_end_two", "5.0", FCVAR_NONE, "For fading hud messages (info to everyone except the winner).", false, 0.0, false, 0.0); //Для угасания hud (инфо всем кроме победителя).
	bind_pcvar_float(Cvar, eCvarData[DMG_SCROLL_HUD_TWO]);

Cvar = create_cvar("dmg_scroll_end_three", "5.0", FCVAR_NONE, "For fading hud messages (info personally to the winner).", false, 0.0, false, 0.0); //Для угасания hud (инфо лично победителю).
	bind_pcvar_float(Cvar, eCvarData[DMG_SCROLL_HUD_THREE]);
}

public plugin_precache()
{
	precache_sound(SND_MR);
	precache_sound(SND_RT);

#if defined OPERATION_FIREWORKS
	for(new i; i < sizeof g_short; i++){
		g_shortSpr[i] = precache_model(g_short[i]);
	}
#endif
}

public round_start()
{
	get_players_ex(g_iPlayers, g_iPlayerCount, GetPlayers_ExcludeDead|GetPlayers_ExcludeBots|GetPlayers_ExcludeHLTV);

if(g_iPlayerCount != 0){
		g_iRndPlayer = g_iPlayers[random(g_iPlayerCount)];
	}

if(g_iPlayerCount < eCvarData[DMG_PLAYERS]){
		set_task_ex(eCvarData[DMG_TIME_NEXT_ONE], "BugReportGlobal", eTaskData[TASK_ID_EIGHT]);
		return PLUGIN_HANDLED;
	}

for(new i; i < sizeof eTaskData; i++){
		remove_task(eTaskData[i]);
	}

g_Scroll = 0;
	set_task_ex(eCvarData[DMG_TIME_NEXT_TWO], "ScrollActivation", eTaskData[TASK_ID_ONE]);

return PLUGIN_HANDLED;
}

public fw_TakeDamage(victim, inflictor, attacker, Float:damage)
{
	if(g_iPlayerCount < eCvarData[DMG_PLAYERS]){
		return HAM_IGNORED;
	}

if(attacker == g_iRndPlayer && is_user_connected(attacker) && victim != attacker){
		SetHamParamFloat(4, damage + eCvarData[DMG_NUMBER])
		return HAM_HANDLED;
	}

return HAM_IGNORED;
}

public BugReportGlobal()
{
	//Худ с ошибкой запуска инфо-оповещание игроков (по желанию, настройка кваром)
	set_dhudmessage(random_num(50, 255), random_num(50, 255), random_num(50, 255), -1.0, 0.60, 2, 0.4, 0.4, 0.1, eCvarData[DMG_HUD_BUG_TIME_ONE]);
	show_dhudmessage(0, "%l", "DMG_HUD_BUG");

set_task_ex(eCvarData[DMG_HUD_BUG_TIME_ONE], "BugReportReason", eTaskData[TASK_ID_NINE]);
}

public BugReportReason()
{
	//Худ с причиной ошибки запуска инфо-оповещание игроков (по желанию, настройка кваром)
	set_dhudmessage(random_num(50, 255), random_num(50, 255), random_num(50, 255), -1.0, 0.63, 2, 0.4, 0.4, 0.1, eCvarData[DMG_HUD_BUG_TIME_TWO]);
	show_dhudmessage(0, "%l", "DMG_HUD_BUG_REASON");
}

public ScrollActivation()
{
	if(g_Scroll > eCvarData[DMG_SCROLL_EXIT]){
		g_Scroll = 0;
		SendAudio(0, SND_MR);

for(new i; i < g_iPlayerCount; i++)
		{
			if(g_iPlayers[i] != g_iRndPlayer){
				//Конечный худ с инфой по поводу разыгрывания дамага среди игроков
				set_dhudmessage(random_num(50,255), random_num(50,255), random_num(50,255), -1.0, 0.60, 2, 0.4, 0.4, 0.1, eCvarData[DMG_SCROLL_HUD_TWO]);
				show_dhudmessage(g_iPlayers[i], "%l", "DMG_HUD_STOP", g_iRndPlayer);
			}
		}

//Конечный худ с инфой по поводу разыгрывания дамага только победителю
		set_dhudmessage(random_num(50,255), random_num(50,255), random_num(50,255), -1.0, 0.55, 2, 0.4, 0.4, 0.1, eCvarData[DMG_SCROLL_HUD_THREE]);
		show_dhudmessage(g_iRndPlayer, "%l", "DMG_HUD_WINNER", g_iRndPlayer, eCvarData[DMG_NUMBER]);

#if defined OPERATION_FIREWORKS
		if(eFireworkData[DMG_FIREWORK_EN]){
			set_task_ex(eFireworkData[DMG_FIREWORK_TIME_ONE], "FireworkActivation", eTaskData[TASK_ID_SIX]);
		}
#endif

return PLUGIN_HANDLED;
	}

if(g_Scroll <= eCvarData[DMG_SCROLL_ALLOW]){
		if(g_Scroll == 0){
			//Начальный худ с инфой по поводу разыгрывания дамага среди игроков
			set_dhudmessage(random_num(50,255), random_num(50,255), random_num(50,255), -1.0, 0.60, 2, 0.4, 0.4, 0.1, eCvarData[DMG_SCROLL_HUD_ONE]);
			show_dhudmessage(0, "%l", "DMG_HUD_START");

set_task_ex(eCvarData[DMG_SCROLL_HUD_ONE] + 1, "MusicActivation", eTaskData[TASK_ID_TWO]);
		}
		else if(g_Scroll > 0){
			set_task_ex(eCvarData[DMG_SCROLL_SPEEDY], "MusicActivation", eTaskData[TASK_ID_FOUR]);
		}
	}
	else if(g_Scroll > eCvarData[DMG_SCROLL_ALLOW]){
		set_task_ex(eCvarData[DMG_SCROLL_SLOW], "MusicActivation", eTaskData[TASK_ID_FIVE]);
	}
	return PLUGIN_HANDLED;
}

public MusicActivation()
{
	SendAudio(0, SND_RT);
	g_Scroll++;

set_task_ex(0.1, "ScrollActivation", eTaskData[TASK_ID_THREE]);
}

#if defined OPERATION_FIREWORKS
public FireworkActivation()
{
	for(new i; i < sizeof g_shortSpr; i++)
	{
		new origin[3];
		get_user_origin(g_iRndPlayer, origin, 0)

message_begin(eFireworkData[DMG_FIREWORK_MSG] ? MSG_ONE : MSG_ALL, SVC_TEMPENTITY, {0, 0, 0}, g_iRndPlayer);
		write_byte(TE_SPRITETRAIL);
		write_coord(origin[0]-random_num(6, 10));
		write_coord(origin[1]-random_num(7, 15));
		write_coord(origin[2]+random_num(30, 70));
		write_coord(origin[0]-random_num(5, 9));
		write_coord(origin[1]-random_num(9, 20));
		write_coord(origin[2]+random_num(50, 100));
		write_short(g_shortSpr[i]);
		write_byte(random_num(2, 7));
		write_byte(random_num(7, 15));
		write_byte(random_num(3, 6));
		write_byte(random_num(6, 20));
		write_byte(random_num(20, 50));
		message_end();
	}

if(eFireworkData[DMG_FIREWORK_NUM]){
		return PLUGIN_HANDLED;
	}
	else if(g_FireworkCount <= eFireworkData[DMG_FIREWORK_NUM]){
		g_FireworkCount++;
		set_task_ex(eFireworkData[DMG_FIREWORK_TIME_TWO], "FireworkActivation", eTaskData[TASK_ID_SEVEN]);
	}
	else if(g_FireworkCount > eFireworkData[DMG_FIREWORK_NUM]){
		g_FireworkCount = 0;
	}
	return PLUGIN_HANDLED;
}
#endif

stock SendAudio(id, const audio[], pitch = 100)
{
	static iMsgSendAudio;

if(!iMsgSendAudio){
		iMsgSendAudio = get_user_msgid("SendAudio");
	}

message_begin(id ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, iMsgSendAudio, .player = id);
	write_byte(id);
	write_string(audio);
	write_short(pitch);
	message_end();
}

Загрузил ADEPT

2020-02-19 21:16:52

Скачать

91.211.118.38:27015

УКРАЇНСЬКИЙ - P U B L I C - [ UP-CS.TOP ] - [ 18+ ]

195.211.60.214:27015

195.211.60.214:27017

CSHOST.COM.UA |REHLDS|

195.211.60.214:27018

УКРАЇНА - Б А Н Д Е Р Ш Т А Т - [2000 FPS] 18+

91.211.118.156:27071

195.211.60.214:27016

УКРАЇНСЬКІ - ДІВЧАТА - [ RYZEN 9 - 5.7 GHZ ]

91.211.118.49:27030

К І Б О Р Г И - У К Р А Ї Н И [RYZEN 9 - 4.7 GHZ]

91.211.118.49:27037

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram