	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Плагин "Stop SpamBots" - Защита сервера от спам ботов

Теги: Скачать плагины csСерверные

Плагин "Stop SpamBots" - Защита сервера от спам ботов - Замечательный плагин, который защитит ваш сервер от spam ботов, заходящих на ваш сервер со спамом в чат или микрофон.

Он работает по аналогии капчи. Для того чтобы игрок смог сказать что-то в микрофон или же написать в чат, ему нужно ввести команду:

Компилятор: 1.8.2 416

Команды:

say /unlock.

Вводится она один раз, после метка данного игрока записывается по SteamID

.sma / .sp

/*
	При просмотре и редактировании данного файла необходимо использовать кодировку 'UTF-8 без BOM'

Требования:
		* В plugins.ini плагин должен стоять выше чат-системы, чтобы первым хукать say/say_team
*/

new const PLUGIN_NAME[] = "Stop SpamBots"
new const PLUGIN_VERSION[] = "0.2"
new const PLUGIN_AUTHOR[] = "mx?!"

/* -------------------- */

// Использовать заданную команду разблокировки
new const CONST_UNLOCK_CMD[] = "/unlock" // Закомментировать для использования динамической команды

// Длина динамической команды
#define WORD_LEN 6

// Символы для генерации динамической команды (не использовать кириллицу и другие мультибайтовые символы!)
stock const CHARS_TABLE[] = {
	'Q', 'F', 'G', 'J', 'S', 'V', 'W', 'Z',
	'1', '2', '3', '4', '5', '6', '7', '8', '9'
}

// Записи игроков, не заходивших указанное кол-во дней, удаляются из хранилища
const PRUNE_DAYS = 30

/* -------------------- */

#include <amxmodx>
#include <nvault>
#include <time>

#tryinclude <reapi>

#if !defined _reapi_included
	#include <fakemeta>
	#include <engine>
	#define _SEND_AUDIO func_SendAudio
#else
	#define _SEND_AUDIO rg_send_audio
#endif

#if AMXX_VERSION_NUM < 183
	#include <colorchat>
	#define MAX_PLAYERS 32
	#define client_disconnected client_disconnect
#endif

#define chx charsmax

new const SOUND__ERROR[] = "buttons/button2.wav"
new const SOUND__BLIP2[] = "buttons/blip2.wav"

const IMPULSE__SPRAY = 201

enum {
	HAS_AUTH,
	IS_CONNECTED,
	IS_VERIFIED
}

new g_hVault, g_szAuthID[24], g_iPlayerFlags[MAX_PLAYERS + 1], g_szBuffer[32]
stock g_msgSendAudio, g_szUnlockWord[MAX_PLAYERS + 1][WORD_LEN]

/* -------------------- */

public plugin_init() {
	register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)

register_dictionary("stop_spambots.txt")

g_hVault = nvault_open("stop_spambots")

if(g_hVault == INVALID_HANDLE) {
		pause("ad")
		return // redundant?
	}

nvault_prune(g_hVault, 0, get_systime() - (PRUNE_DAYS * SECONDS_IN_DAY))

register_clcmd("say", "func_HookSay")
	register_clcmd("say_team", "func_HookSay")

#if defined CONST_UNLOCK_CMD
	formatex(g_szBuffer, chx(g_szBuffer), "say %s", CONST_UNLOCK_CMD)
	register_clcmd(g_szBuffer, "clcmd_Unlock")
	formatex(g_szBuffer, chx(g_szBuffer), "say_team %s", CONST_UNLOCK_CMD)
	register_clcmd(g_szBuffer, "clcmd_Unlock")
#endif

#if defined _reapi_included
	RegisterHookChain(RG_CSGameRules_CanPlayerHearPlayer, "CanPlayerHearPlayer_Pre")
	RegisterHookChain(RG_CBasePlayer_ImpulseCommands, "OnImpulseCommands_Pre")
#else
	register_forward(FM_Voice_SetClientListening, "OnSetClientListening_Pre")
	register_impulse(IMPULSE__SPRAY, "hook_Spray")
	g_msgSendAudio = get_user_msgid("SendAudio")
#endif
}

/* -------------------- */

#if defined _reapi_included
	public CanPlayerHearPlayer_Pre(iReceiver, iSender) {
		if(!CheckFlag(iSender, IS_VERIFIED)) {
			SetHookChainReturn(ATYPE_INTEGER, false)
			return HC_SUPERCEDE
		}

return HC_CONTINUE
	}
#else
	public OnSetClientListening_Pre(iReceiver, iSender, bool:bCanHear) {
		if(!CheckFlag(iSender, IS_VERIFIED)) {
			engfunc(EngFunc_SetClientListening, iReceiver, iSender, false)
			return FMRES_SUPERCEDE
		}

return FMRES_IGNORED
	}
#endif

/* -------------------- */

public func_HookSay(id) {
	if(CheckFlag(id, IS_VERIFIED)) {
		return PLUGIN_CONTINUE
	}

read_args(g_szBuffer, chx(g_szBuffer))
	remove_quotes(g_szBuffer)

if(g_szBuffer[0] == '/') {
		return PLUGIN_CONTINUE
	}

#if !defined CONST_UNLOCK_CMD
	if(equali(g_szBuffer, g_szUnlockWord[id])) {
		return func_Unlock(id)
	}
#endif

_SEND_AUDIO(id, SOUND__ERROR)
#if defined CONST_UNLOCK_CMD
	client_print_color(id, print_team_red, "%L", id, "SSB__BLOCK_INFO", CONST_UNLOCK_CMD)
#else
	client_print_color(id, print_team_red, "%L", id, "SSB__BLOCK_INFO", g_szUnlockWord[id])
#endif
	return PLUGIN_HANDLED
}

/* -------------------- */

#if defined _reapi_included
	public OnImpulseCommands_Pre(id) {
		if(CheckFlag(id, IS_VERIFIED) || get_entvar(id, var_impulse) != IMPULSE__SPRAY) {
			return HC_CONTINUE
		}

return HC_SUPERCEDE
	}
#else
	public hook_Spray(id) {
		if(CheckFlag(id, IS_VERIFIED)) {
			return PLUGIN_CONTINUE
		}

return PLUGIN_HANDLED
	}
#endif

/* -------------------- */

#if defined CONST_UNLOCK_CMD
	public clcmd_Unlock(id) {
		if(!CheckFlag(id, IS_VERIFIED))	{
			return func_Unlock(id)
		}

_SEND_AUDIO(id, SOUND__ERROR)
		client_print_color(id, print_team_red, "%L", id, "SSB__ALREADY")
		return PLUGIN_HANDLED
	}
#endif

/* -------------------- */

stock func_Unlock(id) {
	SetFlag(id, IS_VERIFIED)
	get_user_authid(id, g_szAuthID, chx(g_szAuthID))
	nvault_set(g_hVault, g_szAuthID, "1")
	_SEND_AUDIO(id, SOUND__BLIP2)
	client_print_color(id, print_team_default, "%L", id, "SSB__UNLOCKED")
	return PLUGIN_HANDLED
}

/* -------------------- */

public client_authorized(id) {
	SetFlag(id, HAS_AUTH)

if(CheckFlag(id, IS_CONNECTED)) {
		func_AgregatePlayer(id)
	}
}

/* -------------------- */

public client_putinserver(id) {
	SetFlag(id, IS_CONNECTED)

if(CheckFlag(id, HAS_AUTH)) {
		func_AgregatePlayer(id)
	}
}

/* -------------------- */

stock func_AgregatePlayer(id) {
	get_user_authid(id, g_szAuthID, chx(g_szAuthID))

if(!nvault_get(g_hVault, g_szAuthID)) {
	#if !defined CONST_UNLOCK_CMD
		for(new i; i < sizeof(g_szUnlockWord[]); i++) {
			g_szUnlockWord[id][i] = CHARS_TABLE[random_num(0, sizeof(CHARS_TABLE) - 1)]
		}
	#endif
		return
	}

SetFlag(id, IS_VERIFIED)
	nvault_touch(g_hVault, g_szAuthID)
}

/* -------------------- */

public client_disconnected(id) {
	g_iPlayerFlags[id] = 0
}

/* -------------------- */

stock func_SendAudio(id, const szSample[]) {
	message_begin(MSG_ONE_UNRELIABLE, g_msgSendAudio, .player = id)
	write_byte(id)
	write_string(szSample)
	write_short(PITCH_NORM)
	message_end()
}

/* -------------------- */

public plugin_end() {
	nvault_close(g_hVault)
}

/* -------------------- */

stock SetFlag(id, iFlag) (g_iPlayerFlags[id] |= (1 << iFlag))
stock ClearFlag(id, iFlag) (g_iPlayerFlags[id] &= ~(1 << iFlag))
stock CheckFlag(id, iFlag) return (g_iPlayerFlags[id] & (1 << iFlag))

Загрузил koloda

2022-03-21 21:34:33

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram