	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Плагин The ratio of bombs

Теги: Скачать плагины csСерверные

Иногда кажется, что одной бомбы для всей команды TT недостаточно, например, 20 человек в команде, и только у одного человека есть бомба, и почему, например, не 2 или 3? этот плагин позволяет определить, сколько процентов людей в команде будет иметь бомбу.

Компилятор: 1.8.2 957

Команды:

Настройки:

// значения от 0.0 до 1.0

// количество бомб определяется путем умножения количества людей на этот примерный коэффициент. 10 человек * 0,5 = 5 человек будут

// была бомба на 0.1 только одна и т.д.

bomb_ratio 0.1

.sma / .sp

/*	
@author Rafal "DarkGL" Wiecek 
@site www.darkgl.amxx.pl
*/

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <fakemeta>
#include <hamsandwich>
#include <fun>

#include <fakemeta_util>

#define PLUGIN	"Bomb Ratio"
#define AUTHOR	"DarkGL"
#define VERSION	"1.0"

new Float: bombRatio;

new msgAttrib ,
	msgBombPickup;

public plugin_init(){
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	if( !checkISMapBomb() ){
		return ;
	}
	
	bombRatio	=	floatmax( 0.0 , floatmin( get_pcvar_float( register_cvar( "bomb_ratio" , "0.1" ) ) , 1.0 ) );
	
	RegisterHam( Ham_Spawn , "player" , "fwSpawned" , 1 );
	
	register_logevent( "roundStart", 2, "1=Round_Start");
	
	register_logevent( "bombPlanted", 3, "2=Planted_The_Bomb");
	
	msgAttrib		=	get_user_msgid("ScoreAttrib");
	msgBombPickup	=	get_user_msgid("BombPickup");
}

public fwSpawned( id ){
	
	if( !is_user_alive( id ) ){
		return HAM_IGNORED;
	}
	
	if( cs_get_user_team( id ) == CS_TEAM_T ){
		stripUserBomb( id );
	}
	
	return HAM_IGNORED;
}

public roundStart(){
	new bombAmount	=	max( 1 , floatround( float( getTTAmountAlive() ) * bombRatio ) );
	
	new Array: usersBomb	=	ArrayCreate( 1 , 1 );
	
	deleteBombsDroped();
	
	for( new iCurrent = 1 ; iCurrent <= get_maxplayers() ; iCurrent++ ){
		
		if( !is_user_alive( iCurrent ) || cs_get_user_team( iCurrent ) != CS_TEAM_T ){
			continue;
		}
		
		ArrayPushCell( usersBomb , iCurrent );
	}
	
	while( ArraySize( usersBomb ) > bombAmount ){
		ArrayDeleteItem( usersBomb , random_num( 0 , ArraySize( usersBomb ) - 1 ) );
	}
	
	for( new iCurrent = 0 ; iCurrent < ArraySize( usersBomb ) ; iCurrent++ ){
		
		new idPlayer	=	ArrayGetCell( usersBomb , iCurrent );
		
		if( !is_user_alive( idPlayer ) || cs_get_user_team( idPlayer ) != CS_TEAM_T ){
			continue;
		}
		
		giveUserBomb( idPlayer );
	}
	
	ArrayDestroy( usersBomb );
}

public bombPlanted(){
	
	deleteBombsDroped();
	
	for( new iCurrent = 1 ; iCurrent <= get_maxplayers() ; iCurrent++ ){
		
		if( !is_user_alive( iCurrent ) || cs_get_user_team( iCurrent ) != CS_TEAM_T ){
			continue;
		}
		
		stripUserBomb( iCurrent );
	}
}

getTTAmountAlive(){
	new iAmount = 0;
	
	for( new iCurrent = 1 ; iCurrent <= get_maxplayers() ; iCurrent++ ){
		
		if( !is_user_alive( iCurrent ) || cs_get_user_team( iCurrent ) != CS_TEAM_T ){
			continue;
		}
		
		iAmount++;
	}
	
	return iAmount;
}

stripUserBomb( id ){
	
	if( !is_user_alive( id ) ){
		return 0;
	}
	
	new wEnt;
	while((wEnt = engfunc( EngFunc_FindEntityByString,wEnt,"classname","weapon_c4" )) && pev(wEnt,pev_owner) != id) {}
	if(!wEnt) return 0;
	
	if( get_user_weapon(id) == CSW_C4 ) ExecuteHamB(Ham_Weapon_RetireWeapon,wEnt);
	
	if(!ExecuteHamB(Ham_RemovePlayerItem,id,wEnt)) return 0;
	ExecuteHamB(Ham_Item_Kill,wEnt);
	
	set_pev(id,pev_weapons,pev(id,pev_weapons) & ~( 1 << CSW_C4));
	
	cs_set_user_plant( id,0,0 );
	cs_set_user_bpammo( id , CSW_C4,0 );
	
	cs_set_user_submodel( id , 0 );
	
	message_begin( MSG_ALL, msgAttrib );
	write_byte( id );
	write_byte( is_user_alive( id ) ? 0 : 1 );
	message_end();
	
	return 1;
}

giveUserBomb( id ){
	
	if( !is_user_alive( id ) ){
		return 0;
	}
	
	new wEnt = engfunc(EngFunc_CreateNamedEntity,engfunc(EngFunc_AllocString,"weapon_c4" ));
	
	if(!pev_valid(wEnt)) return 0;
	
	set_pev(wEnt,pev_spawnflags,SF_NORESPAWN);
	dllfunc(DLLFunc_Spawn,wEnt);
	
	if(!ExecuteHamB(Ham_AddPlayerItem,id,wEnt))
	{
		if(pev_valid(wEnt)) set_pev(wEnt,pev_flags,pev(wEnt,pev_flags) | FL_KILLME);
		return 0;
	}
	
	ExecuteHamB(Ham_Item_AttachToPlayer,wEnt,id);
	
	cs_set_user_plant( id,1,1 );
	
	cs_set_user_submodel( id , 1 );
	
	message_begin( MSG_ALL, msgAttrib );
	write_byte( id );
	write_byte( 2 );
	message_end();
	
	return 1;
}

bool: checkISMapBomb(){
	return ( pev_valid( fm_find_ent_by_class( -1 , "func_bomb_target" ) ) || pev_valid( fm_find_ent_by_class( -1 , "info_bomb_target" ) ) );
}

deleteBombsDroped(){
	new iEnt = -1 ,
		weapbox;
	
	while( ( iEnt = fm_find_ent_by_class( iEnt , "weapon_c4" ) ) != 0 ){
		if ( iEnt && (weapbox = pev( iEnt, pev_owner)) > get_maxplayers()) {
			dllfunc(DLLFunc_Think, weapbox);
			
			message_begin(MSG_ALL, msgBombPickup );
			message_end()
		}
	}
}

Загрузил ADEPT

2019-05-05 21:02:55

Скачать

91.211.118.38:27015

УKPAЇHA - Б A H Д E P Ш T A T - [ RYZEN 9 - 5.7 GHz ]

91.211.118.156:27071

УKPAЇHCЬKІ - ДІBЧATA - [ RYZEN 9 - 5.7 GHz ] - [ 18+ ]

91.211.118.49:27030

K І Б O P Г И - У K P A Ї H И - [ RYZEN 9 - 5.7 GHz ]

91.211.118.49:27037

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram