	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Плагин не прошел проверку:
СТРУКТУРА АРХИВА - У ВАС ВСЕ ПОДОБНЫЕ ПЛАГИНЫ НЕ ПРОЙДУТ ПРОВЕРКУ
Создайте новую запись с устранением ошибок

prefix_manager

Теги: Скачать плагины csРеклама и чат

Данный плагин позволяет дописать префикс любому игроку не давая при этом никаких прав на сервере. Прописать можно по нику, стиму или айпи. Все записи редактируются в отдельном файле Prefix.ini

Компилятор: 1.8.2 +ZIP 1862

Команды:

Пример настройки файла Prefix.ini:

//по нику

"wellman" "!y[!gглав. Админ!y]"

//по SteamID

"STEAM_0:0:12345678" "!y[!gглав. Админ!y]"

//по IP

"123.123.123.123" "!y[!gглав. Админ!y]"

Использование цветного префикса:

!y - Обыкновенный цвет (оранжевый по умолчанию)

!t - Цвет игрока команды (синий - CT, красный - T)

!g - Зеленый цвет

.sma / .sp

/*
	CHANGES LIST:
	{
		[1.0][25.02.2012] -> First Release;
		[2.0][16.08.2012] ->
		{
			BugFix;
			Update Code;
			Change Form to Hook_Say();
			Add Bits;
		}
	}
		
	THANKS:
	{
		TurangaLeela -> For the help and continued support;
		PRoSToTeM@   -> For the help;
		Plrip        -> For testing;
	}	
*/

#include <amxmodx>
#include <cstrike>
#include <WPMGPrintChatColor>

#pragma semicolon 				1
#pragma ctrlchar				'\'

#define PLUGIN "Prefix_Manager"
#define VERSION "2.0"
#define AUTHOR "Mon[str]"

#define _BIT_TOTAL				2
#define _BIT_PREFIX				0
#define _BIT_CONNECTED				1

#define _STATUS_ALIVE				0
#define _STATUS_DEAD				1
#define _STATUS_SPECTATOR			2

#define MAX_LEN					32

#define PM_CONFIG				"addons/amxmodx/configs/Prefix.ini"

#define _Bit_Add(%2,%1)				(g_iBits[%1] |= 1 << (%2 - 1))
#define _Bit_Sub(%2,%1)				(g_iBits[%1] &= ~(1 << (%2 - 1)))
#define _Bit_Exists(%2,%1)			(g_iBits[%1] & 1 << (%2 - 1))

#define IndexFix(%1)				(%1 - 1)

new Trie:g_tData;
new g_szPrefix[32][MAX_LEN];
new g_szNames[32][32];

new g_iBits[_BIT_TOTAL];
new g_iStatus[32];
new g_iMaxplayers;

public plugin_init() 
{
	g_tData = TrieCreate();
	
	g_iMaxplayers = get_maxplayers();
	
	register_plugin(PLUGIN, VERSION, AUTHOR);
	
	register_clcmd("say", "Hook_Say");
	register_clcmd("say_team", "Hook_Say");
	
	register_event("ResetHUD", "EventResetHUD", "be"); 
	register_event("DeathMsg", "EventDeathMessage", "a");
	register_event("Spectator", "EventSpectation", "a");
}

public plugin_cfg()
{	
	if(!file_exists(PM_CONFIG))
	{
		set_fail_state("ERROR: [PM] Config is Not Found!!!");
		
		return;
	}
	
	new _:iFile;
	
	if((iFile = fopen(PM_CONFIG, "r")))
	{	
		new 
		szBuffer[100],
		szPrefix[32],
		szKey[32];
		
		while(fgets(iFile, szBuffer, charsmax(szBuffer)))
		{	
			if(szBuffer[0])
			{	
				RemoveComment(szBuffer, charsmax(szBuffer));
				trim(szBuffer);
					
				strtok(szBuffer, szKey, charsmax(szKey), szPrefix, charsmax(szPrefix), ' ');
				
				remove_quotes(szKey);
				remove_quotes(szPrefix);
			
				TrieSetString(g_tData, szKey, szPrefix);
			}
		}
	}
}

public client_connect(id)
{
	get_user_name(id, g_szNames[IndexFix(id)], 31);
	
	_Bit_Add(id, _BIT_CONNECTED);
}

public client_infochanged(id)
{
	get_user_info(id, "name", g_szNames[IndexFix(id)], 31);
}

public client_authorized(id)
{
	enum _:_INFO
	{
		_:_STEAM,
		_:_IP
	};
	
	new szInformation[_INFO][32];
	
	get_user_authid(id, szInformation[_STEAM], 31);
	get_user_ip(id, szInformation[_IP], 31, 1);
	
	if(TrieKeyExists(g_tData, g_szNames[IndexFix(id)]))
	{
		TrieGetString(g_tData, g_szNames[IndexFix(id)], g_szPrefix[IndexFix(id)], 31);
		
		_Bit_Add(id, _BIT_PREFIX);
	}
		
	else if(TrieKeyExists(g_tData, szInformation[_STEAM]))
	{
		TrieGetString(g_tData, szInformation[_STEAM], g_szPrefix[IndexFix(id)], 31);
		
		_Bit_Add(id, _BIT_PREFIX);
	}

else if(TrieKeyExists(g_tData, szInformation[_IP]))
	{
		TrieGetString(g_tData, szInformation[_IP], g_szPrefix[IndexFix(id)], 31);
		
		_Bit_Add(id, _BIT_PREFIX);
	}
}

public Hook_Say(id)
{
	if(_Bit_Exists(id, _BIT_PREFIX) && _Bit_Exists(id, _BIT_CONNECTED))
	{
		new _:iTeam;
		
		if((iTeam = _:cs_get_user_team(id)))
		{
			new 
			szMessage[70],
			szArgv[9];
			
			enum _:_TYPE
			{
				_CLCMD_INFO,
				_CLCMD_TEAM
			};
			
			static _:iTeamColor[] = 
			{
				PRINT_COLOR_RED,
				PRINT_COLOR_BLUE,
				PRINT_COLOR_GREY
			};
			
			static szPlayerStatus[_TYPE][][] = 
			{
				{
					"",
					"*DEAD*",
					"*SPEC*"
				},
				
				{
					"(Terrorist)",
					"(Counter-Terrorist)",
					"(Spectator)"
				}	
			};
		
			read_args(szMessage, charsmax(szMessage));
			remove_quotes(szMessage);
			
			read_argv(0, szArgv, charsmax(szArgv));
			
			while(replace(szMessage, charsmax(szMessage), "%", "")) {}
		
			if(!szMessage[0])
				return 1;
			
			if(equal(szArgv, "say"))
			{		
				PrintChatColor
				(
					0,
					iTeamColor[IndexFix(iTeam)],
					"%s%s%s%s !t%s!y :  %s",
					g_iStatus[IndexFix(id)] == _STATUS_ALIVE ? "" : "!y",
					szPlayerStatus[_CLCMD_INFO][g_iStatus[IndexFix(id)]],
					g_iStatus[IndexFix(id)] == _STATUS_ALIVE ? "!y" : " ",
					g_szPrefix[IndexFix(id)],
					g_szNames[IndexFix(id)],
					szMessage
				);
			}	
	
			else
			{
				for(new _:i = 1; i <= g_iMaxplayers; i++)
				{
					if(_Bit_Exists(i, _BIT_CONNECTED))
					{
						if(_:cs_get_user_team(i) == iTeam)
						{
							PrintChatColor
							(
								i,
								iTeamColor[IndexFix(iTeam)],
								"!y%s %s !t%s!y :  %s",
								szPlayerStatus[_CLCMD_TEAM][IndexFix(iTeam)],
								g_szPrefix[IndexFix(id)],
								g_szNames[IndexFix(id)],
								szMessage
							);
						}
					}
				}
			}	
			
			return 1;	
		}
	}
	
	return 0;
}

public EventResetHUD(id)
{
	g_iStatus[IndexFix(id)] = _STATUS_ALIVE;
}

public EventDeathMessage()
{
	g_iStatus[IndexFix(read_data(2))] = _STATUS_DEAD;
}

public EventSpectation()
{
	g_iStatus[IndexFix(read_data(1))] = _STATUS_SPECTATOR;
}

public client_disconnect(id)
{
	if(_Bit_Exists(id, _BIT_PREFIX))
	{
		g_szPrefix[IndexFix(id)][0] = '\0';
		
		_Bit_Sub(id, _BIT_PREFIX);
	}
	
	_Bit_Sub(id, _BIT_CONNECTED);
}

stock RemoveComment(szString[], _:iLen)
{
	for(new _:i = 0; i <= iLen; i++)
	{
		if(szString[i] == ';')
		{
			szString[i] = '\0';
			
			return;
		}
	}
}

Загрузил dvoenkin23gfg

2019-01-16 20:04:49

371

Скачать

Где найти этот файл?

Dimonster1997

2019-02-22 21:17:15

Не ставьте те, которые не прошли проверку

root

2019-01-19 11:46:06

Не работает. Или я неправильно устанавливаю или оно реально не работает

LyuZifer

2019-01-17 20:11:57

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram