	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Плагин не прошел проверку:
структура архива
Создайте новую запись с устранением ошибок

Random Weapons WarmUP (разминка)

Теги: Скачать плагины csСерверные

Плагин random_weapons_warmup.amxx создаёт в начале карты разминку (40 сек) на случайном оружии (муха, авп, дигл, гранаты и т.д.), у всех одинаковое. Во время разминки если игрока убили, он сразу же воскрешает и играет снова, как в csdm

Компилятор: 1.8.2 +ZIP 883

Команды:

Настройки (в исходнике):

#define WARMUPTIME 40 // Время вармапа

#define NUM_RR 1 // Кол-во рестартов

#define LATENCY 1.5 // Задержка между рестартами

#define DHUD_MESSAGE // Показывать в dhud. Закомментируйте, чтобы был hud

#define GIVE_SHIELD 0 // 0 - выключить; 1 - Щит + deagle; 2 - щит + нож; 3 - щит и с диглом и ножом

#define STOP_PLUGS // Отключать плагины на время вармапа

#define DM_MODE // Бесконечный респавн на время вармапа

#define ThFiveHP_ON_KNIFE // Выдает 35HP игрокам, если оружие - НОЖ

#if defined STOP_PLUGS

new g_arPlugins[][] = // Указывать название файлов, например test.amxx

{

"test.amxx",

"test2.amxx"

}

#endif

Доп инфо:

Изменять оружия можно на строках 79-86 и 106-138 (менять в двух местах)

.sma / .sp

#include <amxmodx>
#include <hamsandwich>
#include <fakemeta_util>
#include <cstrike>

#define WARMUPTIME 	40	// Время вармапа
#define NUM_RR		1	// Кол-во рестартов
#define LATENCY		1.5	// Задержка между рестартами
#define DHUD_MESSAGE		// Показывать в dhud. Закомментируйте, чтобы был hud
#define GIVE_SHIELD	3	// 0 - выключить; 1 - Щит + deagle; 2 - щит + нож; 3 - щит и с диглом и ножом
#define STOP_PLUGS		// Отключать плагины на время вармапа
#define DM_MODE			// Бесконечный респавн на время вармапа
#define ThFiveHP_ON_KNIFE	// Выдает 35HP игрокам, если оружие - НОЖ

#if defined STOP_PLUGS
	new g_arPlugins[][] =	// Указывать название файлов, например test.amxx
	{
		"test.amxx",
		"test2.amxx"
	}
#endif

new g_szWeapon[32];
new g_iWp;

new HamHook:fwd_HamSpawnHandle;
#if defined DM_MODE
new HamHook:fwd_HamKilledHandle;
#endif
new fwd_MessageHandle, g_msgStatusIcon;
#if defined DHUD_MESSAGE
	#if AMXX_VERSION_NUM < 183
		#include <dhudmessage>
	#endif
#else
	new g_iHudSync;
#endif

public plugin_init()
{
	register_plugin("Random Weapons WarmUP", "1.6", "neugomon");
#if defined DM_MODE
	register_clcmd("joinclass", 	"clCmdJoinClass");
	register_clcmd("menuselect", 	"clCmdJoinClass");
#endif	
	register_event("TextMsg", "eventGameCommencing", "a", "2=#Game_Commencing");
	register_event("HLTV", 	  "eventRoundStart", 	"a", "1=0", "2=0");
	
	DisableHamForward((fwd_HamSpawnHandle = RegisterHam(Ham_Spawn, "player", "fwdPlayerSpawnPost", true)));
#if defined DM_MODE	
	DisableHamForward((fwd_HamKilledHandle = RegisterHam(Ham_Killed, "player", "fwdPlayerKilledPost", true)));
#endif	
	g_msgStatusIcon = get_user_msgid("StatusIcon");
#if !defined DHUD_MESSAGE
	g_iHudSync	= CreateHudSyncObj();
#endif	
	state WarmUPBlocked;
}

public eventGameCommencing()
	state WarmUPStarted;

public eventRoundStart() <WarmUPBlocked>	
	return;
public eventRoundStart() <WarmUPStarted>	
{
	if(task_exists(67554564))
		return;
	
	fwd_MessageHandle = register_message(g_msgStatusIcon, "msgStatusIcon");
		
	EnableHamForward(fwd_HamSpawnHandle);
#if defined DM_MODE	
	EnableHamForward(fwd_HamKilledHandle);
#endif	
#if defined STOP_PLUGS	
	PluginController(1);
#endif	
	switch((g_iWp = random(4)))
	{
		case 0: formatex(g_szWeapon, charsmax(g_szWeapon), "AWP");
		case 1: formatex(g_szWeapon, charsmax(g_szWeapon), "Deagle");
		case 2: formatex(g_szWeapon, charsmax(g_szWeapon), "Scout");
		case 3: formatex(g_szWeapon, charsmax(g_szWeapon), "Grenade");
		case 4: formatex(g_szWeapon, charsmax(g_szWeapon), "Knife");
	}
		
	set_task(1.0, "ShowTimer", 67554564, .flags = "a", .repeat = WARMUPTIME);
}
#if defined DM_MODE
public clCmdJoinClass(id) <WarmUPBlocked>
	return;
public clCmdJoinClass(id) <WarmUPStarted>
	if(get_pdata_int(id, 205) == 3)
		set_task(1.0, "SpawnPlayer", id);
#endif
public fwdPlayerSpawnPost(const id)
{
	if(!is_user_alive(id))
		return;
		
	if(fm_strip_user_weapons(id))
	{
		switch(g_iWp)
		{
			case 0:
			{
				fm_give_item(id, "weapon_awp");
				cs_set_user_bpammo(id, CSW_AWP, 30);
			}
			case 1:
			{
			#if GIVE_SHIELD == 1 || GIVE_SHIELD == 3
				fm_give_item(id, "weapon_shield");
			#endif
				fm_give_item(id, "weapon_deagle");
				cs_set_user_bpammo(id, CSW_DEAGLE, 35);
			}
			case 2:
			{
				fm_give_item(id, "weapon_scout");
				cs_set_user_bpammo(id, CSW_SCOUT, 90);
			}
			case 3:
			{
				fm_give_item(id, "weapon_hegrenade");
				cs_set_user_bpammo(id, CSW_HEGRENADE, 512);
			}
			case 4:
			{
			#if GIVE_SHIELD == 2 || GIVE_SHIELD == 3
				fm_give_item(id, "weapon_shield");
			#endif
				fm_give_item(id, "weapon_knife");
			#if defined ThFiveHP_ON_KNIFE
				fm_set_user_health(id, 35);
			#endif	
			}	
		}
	}	
}
#if defined DM_MODE
public fwdPlayerKilledPost(pVictim)
	set_task(1.0, "SpawnPlayer", pVictim);
#endif
public msgStatusIcon(msgId, msgDest, msgEnt)
{
	if(!get_msg_arg_int(1))
		return PLUGIN_CONTINUE;
	
	static szIcon[8];
	get_msg_arg_string(2, szIcon, charsmax(szIcon));
 
	if(!strcmp(szIcon, "buyzone"))
	{
		set_pdata_int(msgEnt, 235, get_pdata_int(msgEnt, 235) & ~(1<<0));
		return PLUGIN_HANDLED;
	}
	return PLUGIN_CONTINUE; 
}	
	
public ShowTimer()
{
	static timer = -1; 
	if(timer == -1) timer = WARMUPTIME;
	
	switch(--timer)
	{
		case 0: 
		{
			state WarmUPBlocked;
			DisableHamForward(fwd_HamSpawnHandle);
		#if defined DM_MODE	
			DisableHamForward(fwd_HamKilledHandle);
		#endif	
			unregister_message(g_msgStatusIcon, fwd_MessageHandle);
		#if defined STOP_PLUGS	
			PluginController(0);
		#endif	
		#if NUM_RR > 1		
			set_task(LATENCY, "SV_Restart", .flags = "a", .repeat = NUM_RR);
		#else
			SV_Restart();
		#endif
			timer = -1;
		}
		default:
		{
		#if defined DHUD_MESSAGE
			set_dhudmessage(.red = 135, .green = 206, .blue = 235, .x = -1.0, .y = 0.08, .holdtime = 0.9);
			show_dhudmessage(0, "Разминка на %s!^nРестарт через %d сек", g_szWeapon, timer);
		#else	
			set_hudmessage(135, 206, 235, .x = -1.0, .y = 0.9, .holdtime = 1.03, .channel = -1);
			ShowSyncHudMsg(0, g_iHudSync, "Разминка на %s!^nРестарт через %d сек", g_szWeapon, timer);
		#endif	
		}
	}
}

public SV_Restart()
	set_cvar_num("sv_restart", 1);
#if defined DM_MODE	
public SpawnPlayer(id)
{
	if(is_user_alive(id))
		return;
		
	switch(get_pdata_int(id, 114))
	{
		case 1, 2: ExecuteHamB(Ham_CS_RoundRespawn, id);
	}
}
#endif
stock PluginController(stop)
{
	for(new i; i < sizeof g_arPlugins; i++)
	{
		if(stop)pause  ("ac", g_arPlugins[i]);
		else	unpause("ac", g_arPlugins[i]);
	}	
}

Загрузил ivnchenko

2022-05-05 14:34:29

131

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram