	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

REAPI Плагин [WeaponBox FadeOut Effect]

Теги: Скачать плагины csЭффекты

Данный плагин создаёт красивый эффект исчезания брошенного оружия через определённое количество секунд, и собственно создаёт само исчезание оружий. При этом бомба и лежащие оружие которые предусмотрены картой исчезать не будут.

Требования для корректной работы плагина:
ReAPI
ReHLDS
ReGameDLL
AmxModX 1.8.3

Компилятор: 1.8.2 REapi +ZIP 1062

Команды:

Кваров и команд нет

.sma / .sp

#include <amxmodx>
#include <reapi>

#define GLOW
#define STEP 15.0
#define VERTICAL_SPEED 20.0
#define HORISONTAL_SPEED 120.0

enum (+= 1) {
	STATUS_NONE = 0,
	STATUS_EFFECT,
	STATUS_KILL
}

new g_CvarTimeout;

public plugin_init() {
	register_plugin("WeaponBox FadeOut Effect", "0.3", "GordonFreeman & F@nt0M");
	RegisterHookChain(RG_CWeaponBox_SetModel, "CWeaponBox_SetModel", true);
	g_CvarTimeout = register_cvar("wb_effect_timeout", "10.0");
}

public CWeaponBox_SetModel(const ent) {
	if (is_nullent(ent) || !checkWeaponBox(ent)) {
		return HC_CONTINUE;
	}

set_entvar(ent, var_impulse, STATUS_NONE);
	set_entvar(ent, var_nextthink, get_gametime() + get_pcvar_float(g_CvarTimeout));
	SetThink(ent, "CWeaponBox_Think");
	
	return HC_CONTINUE;
}

public CWeaponBox_Think(const ent) {
	if (is_nullent(ent)) {
		return;
	}

new status = get_entvar(ent, var_impulse);
	if (status == STATUS_NONE) {
		set_entvar(ent, var_movetype, MOVETYPE_FLY);
		set_entvar(ent, var_solid, SOLID_NOT);
		set_entvar(ent, var_rendermode, kRenderTransAlpha);
#if defined GLOW
		set_entvar(ent, var_renderfx, kRenderFxGlowShell);
		set_entvar(ent, var_rendercolor, Float:{255.0, 255.0, 0.0});
#endif
		set_entvar(ent, var_renderamt, 255.0);
		set_entvar(ent, var_velocity, Float:{0.0, 0.0, VERTICAL_SPEED});
		set_entvar(ent, var_avelocity, Float:{0.0, HORISONTAL_SPEED, 0.0})
		set_entvar(ent, var_impulse, STATUS_EFFECT);
	} else if (status == STATUS_EFFECT) {
		new Float:renderamt = Float:get_entvar(ent, var_renderamt);
		if (renderamt > 0.0) {
			set_entvar(ent, var_renderamt, floatmax(0.0, renderamt - STEP));
		} else {
			SetThink(ent, "");
			set_entvar(ent, var_flags, FL_KILLME);
			set_entvar(ent, var_impulse, STATUS_KILL);
		}
	}
	set_entvar(ent, var_nextthink, get_gametime() + 0.1);
}

bool:checkWeaponBox(const ent) {
	for (new i = 0, weapon; i < MAX_ITEM_TYPES; i++) {
		weapon = get_member(ent, m_WeaponBox_rgpPlayerItems, i);
		if (is_nullent(weapon)) {
			continue;
		}
		new WeaponIdType:wid = get_member(weapon, m_iId);
		if (wid == WEAPON_C4) {
			return false;
		}
	}
	return true;
}

Загрузил popca2424

2018-11-19 21:09:20

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram