	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Плагин не прошел проверку:
zip архив имеет не правильную структуру, addons/amxmod нету
Создайте новую запись с устранением ошибок

Реклама NEW

Теги: Скачать плагины csРеклама и чат

Сообщения выводятся циклично, друг за другом, с заданной кваром периодичностью
Поддерживаются цветные сообщения
Поддерживается порежимный (от значения квара) вывод сообщений
Поддерживается старт со случайной позиции
Поддерживается случайная задержка между выводом сообщений
Поддерживается вывод сразу нескольких сообщений (мульти-вывод)
Поддерживается сопровождение вывода различными звуками
Поддерживается перезагрузка конфига с сообщениями "на лету"
Имеется возможность персонального отключения вывода сообщений
Имеется автоответчик

Компилятор: 1.8.2 +ZIP 926

Команды:

reklama_status - вывести общее кол-во сообщений, а так же № последнего показанного сообщения

reklama_show - вывести определённое сообщение (пример: reklama_show 2)

reklama_reload - перезагрузить конфиг с сообщениями

say /reklama - вкл./выкл. вывод сообщений

.sma / .sp

// При просмотре и редактировании данного файла необходимо использовать кодировку 'UTF-8 без BOM'

/* Требования:
* AMX Mod X версии 1.8.1, либо новее
* colorchat.inc для AMX Mod X до версии 1.8.3-dev [ https://dev-cs.ru/threads/222/page-2#post-12669 ]
*/

/* История изменений:
	29.03.2018
		* Релиз
	06.04.2018
		* Добавлен квар 'reklama_freq'
		* Удалена команда 'reklama_mode'
		* Убрана стартовая задержка перед загрузкой конфига
		* Незначительные правки кода
	29.11.2018
		* Добавлен квар 'reklama_for_all'
		* Добавлена опция персонального отключения сообщений
		* Добавлена опция 'чат-префикс'
		* Добавлен квар 'reklama_mode'
		* Изменена структура конфига -> добавлен аргумент 'режим'
	29.11.2018 v2
		* Добавлена опция 'автоответчик'
	30.11.2018
		* Добавлена опция CMD_BLOCK_AUTORESPOND
		* Добавлена опция RANDOM_FREQ
		* Метод проигрывания звуков заменён на более надёжный
		* Упразднена опция USE_PRECACHE
		* Звук под пунктом 4 (ambience/warn1) заменён на 'buttons/button2'
		* Добавлена опция USE_SOUND
	30.11.2018 v2
		* Хотфикс критичного недосмотра. Спасибо zhorzh78 (https://dev-cs.ru/members/326/)
*/

new const PLUGIN_NAME[] = "Reklama"
new const PLUGIN_DATE[] = "30.11.2018 v2"
new const PLUGIN_AUTHOR[] = "mx?!"
new const g_szPluginPrefix[] = "[Reklama]"

/* ---------------------- НАСТРОЙКИ [НАЧАЛО] ---------------------- */

// Определяет наличие автоответчика
#define AUTORESPONDER // закомментировать для отключения

// Блокировать ли вывод сообщений, вызывающих ответ автоответчика
// Чтобы данная опция работала, установите в plugins.ini данный плагин ВЫШЕ плагина, отвечающего за чат
#define BLOCK_TRIGGER_MSG // закомментировать для отключения

// Определяет доступность команды персонального отключения сообщений
#define CMD_NAME "say /reklama" // закомментировать для отключения

// Отключать ли автоответчик при персональном отключении сообщений
#define CMD_BLOCK_AUTORESPOND  // закомментировать для отключения

// Регулирует сброс состояния показа сообщений для игроков, не заходивших указанное кол-во дней
#define OBSOLETE_DAYS 30 // закомментировать для отключения

// Чат-префикс
new const CHAT_PREFIX[] = "" // без чат-префикса
//new const CHAT_PREFIX[] = "^4* "
//new const CHAT_PREFIX[] = "^1[^3Инфо^1] "
//new const CHAT_PREFIX[] = "^1[^4Reklama^1] "

// Выводить ли префикс вместе с сообщениями
//#define SHOW_PREFIX_WITH_ADS // закомментировать для отключения

// Стандартная частота вывода сообщений (в секундах)
#define DEFAULT_FREQ "60"

// Позволяет рандомизировать задержку между автоматическим выводом сообщений
// Включение добавляет квары 'reklama_freq_min', 'reklama_freq_max', и отключает квар 'reklama_freq'
//#define RANDOM_FREQ // закомментировать для отключения
// Стандартные значения вышеупомянутых кваров
#define RANDOM_FREQ_MIN "30"
#define RANDOM_FREQ_MAX "60"

// Стандартное значение квара 'reklama_for_all'
#define FOR_ALL "1" // 0 - показывать сообщения только мёртвым; 1 - показывать всем

// Стандартное значение квара 'reklama_mode'
#define DEFAULT_MODE "0" // 0 - выводить все сообщения, иначе только те, что соответствуют текущему значению квара

// Режим старта со случайной позиции. Полезно при большом конфиге, когда таймлимит не позволяет показать всё содержимое
// Не забудьте указать тип '2' или '3' для тех строк конфига, с которых не должен происходить старт
#define RANDOM_START // закомментировать для отключения

// Имя конфига с сообщениями (располагается в amxmodx/configs)
new const ADS_FILE_NAME[] = "reklama.ini"

// Имя lang-файла (amxmodx/data/lang)
new const LANG_NAME[] = "reklama.txt"

// Имя хранилища (amxmodx/data/vault)
stock const VAULT_NAME[] = "reklama"

/* --- НАСТРОЙКИ ЗВУКОВ --- */

// Определяет поддержку звуков
#define USE_SOUND // закомментировать для отключения

// Проигрывать ли звуки всем игрокам
#define SOUND_FOR_ALL // заккоментировать, чтобы звуки проигрывались только мёртвым

// Звуки
stock const g_szSounds[][] = {
/* 0 */ "buttons/blip1.wav",
/* 1 */ "buttons/blip2.wav",
/* 2 */ "events/tutor_msg.wav",
/* 3 */ "buttons/button2.wav",
/* 4 */ "buttons/bell1.wav",
/* 5 */ "buttons/button3.wav",
/* 6 */ "buttons/button7.wav",
/* 7 */ "buttons/button9.wav",
/* 8 */ "plats/elevbell1.wav",
/* 9 */ "plats/train_use1.wav",
/* 10 */ "x/x_shoot1.wav"
}

/* ---------------------- НАСТРОЙКИ [КОНЕЦ] ---------------------- */

#include <amxmodx>
#include <time>

#if defined CMD_NAME
	#include <nvault>
#endif

#if AMXX_VERSION_NUM < 183
    #include <colorchat>
	#define MAX_PLAYERS 32
	#define PLATFORM_MAX_PATH 260
#endif

#define chx charsmax

#define MODE_AUTO false
#define MODE_MANUAL true

#define MSG_LEN 191
#define TEMPLATE_LEN 64

const TASKID_TIMER = 23901

enum _:MSG_STRUCT
{
	MSG_BODY[MSG_LEN],
	MSG_COLOR_ID,
	bool:IS_MULTI_MSG,
	MSG_SOUND_ID,
	bool:NOT_FOR_START,
	MSG_MODE,
	bool:AUTORESPOND_ONLY
}

enum _:AR_STRUCT {
	POINTER,
	TEMPLATE[TEMPLATE_LEN]
}

stock g_AuReData[AR_STRUCT]

new Array:g_aMsgArray, g_eMsgData[MSG_STRUCT], g_iMsgCount,	g_iCurPos, g_iFirstSkipPos
new g_szFilePath[PLATFORM_MAX_PATH], g_pForAll, g_pMode

stock g_bDisabled[MAX_PLAYERS + 1], g_szAuthID[25], g_iVault, Array:g_aAuReArray, g_iAuReCount
stock g_pFreq, g_pFreqMin, g_pFreqMax, g_iMsgSendAudio

/* -------------------- */

public plugin_init()
{
	register_plugin(PLUGIN_NAME, PLUGIN_DATE, PLUGIN_AUTHOR)

#if defined RANDOM_FREQ
	g_pFreqMin = register_cvar("reklama_freq_min", RANDOM_FREQ_MIN)
	g_pFreqMax = register_cvar("reklama_freq_max", RANDOM_FREQ_MAX)
#else
	g_pFreq = register_cvar("reklama_freq", DEFAULT_FREQ)
#endif
	g_pForAll = register_cvar("reklama_for_all", FOR_ALL)
	g_pMode = register_cvar("reklama_mode", DEFAULT_MODE)

#if defined AUTORESPONDER
	g_aAuReArray = ArrayCreate(AR_STRUCT, 1)
	register_clcmd("say", "hook_Say")
	register_clcmd("say_team", "hook_Say")
#endif

#if defined USE_SOUND
	g_iMsgSendAudio = get_user_msgid("SendAudio")
#endif

func_LoadMessages(MODE_AUTO)

// Статус: общее кол-во сообщений, текущая позиция
	register_srvcmd("reklama_status", "func_CmdShowStatus")
	// Вывод определённого сообщения (напр. reklama_show 5)
	register_srvcmd("reklama_show", "func_CmdShowCustomMessage")
	// Перезагрузка конфига с сообщениями
	register_srvcmd("reklama_reload", "func_CmdReloadFile")

#if defined CMD_NAME
	register_dictionary(LANG_NAME)
	register_clcmd(CMD_NAME, "clcmd_ToggleState")

g_iVault = nvault_open(VAULT_NAME)

if(g_iVault == INVALID_HANDLE) {
		return
	}

#if defined OBSOLETE_DAYS
		nvault_prune(g_iVault, 0, get_systime() - (OBSOLETE_DAYS * SECONDS_IN_DAY))
	#endif
#endif
}

/* -------------------- */

#if defined AUTORESPONDER
	public hook_Say(id) {
	#if defined CMD_BLOCK_AUTORESPOND
		if(!g_iAuReCount || g_bDisabled[id]) {
	#else
		if(!g_iAuReCount) {
	#endif
			return PLUGIN_CONTINUE
		}

new szMessage[MSG_LEN]

read_args(szMessage, chx(szMessage))
		remove_quotes(szMessage)
		trim(szMessage)

for(new i; i < g_iAuReCount; i++) {
			ArrayGetArray(g_aAuReArray, i, g_AuReData)

if(containi(szMessage, g_AuReData[TEMPLATE]) == -1) {
				continue
			}

ArrayGetArray(g_aMsgArray, g_AuReData[POINTER], g_eMsgData)

if(g_eMsgData[MSG_MODE] && get_pcvar_num(g_pMode) != g_eMsgData[MSG_MODE]) {
				return PLUGIN_CONTINUE
			}

func_ShowToSingle(id)

#if AMXX_VERSION_NUM < 183
			func_CheckMultiMsg(id, g_AuReData[POINTER])
		#else
			while(g_eMsgData[IS_MULTI_MSG]) {
				ArrayGetArray(g_aMsgArray, ++g_AuReData[POINTER], g_eMsgData)
				func_ShowToSingle(id)
			}
		#endif

#if defined BLOCK_TRIGGER_MSG
			return PLUGIN_HANDLED
		#else
			return PLUGIN_CONTINUE
		#endif
		}

return PLUGIN_CONTINUE
	}
#endif

/* -------------------- */

#if AMXX_VERSION_NUM < 183
	stock func_CheckMultiMsg(id, iPos) {
		if(!g_eMsgData[IS_MULTI_MSG]) {
			return
		}

new szData[1]; szData[0] = iPos + 1
		set_task(0.1, "task_PrintCrutch", id, szData, sizeof(szData))
	}

/* -------------------- */

public task_PrintCrutch(szData[], id) {
		if(!is_user_connected(id)) {
			return
		}

ArrayGetArray(g_aMsgArray, szData[0], g_eMsgData)
		func_ShowToSingle(id)
		func_CheckMultiMsg(id, szData[0])
	}
#endif

/* -------------------- */

stock func_ShowToSingle(id) {
#if defined SHOW_PREFIX_WITH_ADS
	client_print_color(id, g_eMsgData[MSG_COLOR_ID], "%s^1%s", CHAT_PREFIX, g_eMsgData[MSG_BODY])
#else
	client_print_color(id, g_eMsgData[MSG_COLOR_ID], "^1%s", g_eMsgData[MSG_BODY])
#endif

#if defined USE_SOUND
	if(g_eMsgData[MSG_SOUND_ID] != -1) {
		func_SendAudio(id, g_szSounds[g_eMsgData[MSG_SOUND_ID]])
	}
#endif
}

/* -------------------- */

#if defined CMD_NAME
	public clcmd_ToggleState(id) {
		g_bDisabled[id] = !g_bDisabled[id]
#if defined USE_SOUND
		func_SendAudio(id, g_szSounds[1])
#endif
		client_print_color(id, print_team_red, "%s^1%L %s%L", CHAT_PREFIX, id, "REKLAMA_STATE", g_bDisabled[id] ? "^3" : "^4", id, g_bDisabled[id] ? "REKLAMA_OFF" : "REKLAMA_ON")

if(g_iVault == INVALID_HANDLE) {
			return PLUGIN_HANDLED
		}

get_user_authid(id, g_szAuthID, chx(g_szAuthID))

if(g_bDisabled[id]) {
			nvault_set(g_iVault, g_szAuthID, "1")
		}
		else {
			nvault_remove(g_iVault, g_szAuthID)
		}

return PLUGIN_HANDLED
	}
#endif

/* -------------------- */

public func_LoadMessages(bool:bMode) {
	if(bMode == MODE_AUTO) {
		g_aMsgArray = ArrayCreate(MSG_STRUCT)

get_localinfo("amxx_configsdir", g_szFilePath, chx(g_szFilePath))
		format(g_szFilePath, chx(g_szFilePath), "%s/%s", g_szFilePath, ADS_FILE_NAME)
	}

new iFile

if(!file_exists(g_szFilePath)) {
		iFile = fopen(g_szFilePath, "w")

if(!iFile) {
		#if AMXX_VERSION_NUM < 183
			set_fail_state("Error, cannot create default config")
		#else
			set_fail_state("Error, cannot create '%s'", ADS_FILE_NAME)
		#endif
		}

fprintf(iFile, "; Конфиг сообщений плагина '%s'^n", PLUGIN_NAME)
		fputs(iFile, "; Формат строк: режим тип звук цвет автоответчик ^"шаблон автоответчика^" ^"сообщение^"^n")
		fputs(iFile, "; Режим: 0 - выводить всегда, иначе выводить только при аналогичном значении квара 'reklama_mode'^n")
		fputs(iFile, "; Тип (однострочное/вызвать след. строку/вызвать след. строку + не для старта/не для старта): 0/1/2/3^n")
		fputs(iFile, "; Звук (без звука/blip1/blip2/tutor_msg/button2/bell1/button3/button7/button9/elevbell1/train_use1/x_shoot1): 0/1/2/3/4/5/6/7/8/9/10/11^n")
		fputs(iFile, "; Цвет (цвет команды получателя/белый/красный/синий): D/W/R/B^n")
		fputs(iFile, "; Колоркод (обычный/цвет/зелёный): !n/!t/!g^n")
		fputs(iFile, "; Автоответчик: 1 - выводить только при автоответе, 0 - выводить в обоих режимах^n")
		fputs(iFile, "; Пример сообщения: 0 0 R ^"!g* !nЗдесь был !tЖорик!^"^n")
		fputs(iFile, "; Макс. длина сообщения, - 190 символов (UTF-символы считаются за два)^n")
		fputs(iFile, "; По-умолчанию звук проигрывается только мёртвым игрокам, дабы не отвлекать живых^n")
		fputs(iFile, "; Памятка: не делайте мульти-вывод с двумя (или более) звуками, т.к. будет наложение^n")
		fputs(iFile, "^n; Однострочное сообщение без звука и с цветом команды получателя для '!t'^n")
		fputs(iFile, "0 0 0 D 0 ^"^" ^"!g* !nПосетите наш форум: !tDev-CS.ru^"^n")
		fputs(iFile, "^n; Трёхстрочное сообщение со звуком 'tutor_msg' и красным (первая строка), синим (вторая), и белым (третья) цветом для '!t'^n")
		fputs(iFile, "0 1 3 R 0 ^"^" ^"!g* !nНа сервере !tчитер? !nБегите на !gwww.адрес.ru !nзвать админа!^"^n")
		fputs(iFile, "0 2 0 B 0 ^"^" ^"!g* !nТак же админа можно позвать в группе !tTelegram: !gадрес^"^n")
		fputs(iFile, "0 3 0 W 0 ^"^" ^"!g* !nСамостоятельно наказать читера можно командой !t/voteban^"^n")
		fputs(iFile, "^n; Трёхстрочное сообщение, выводящееся только автоответчиком, в ответ на слово ^"привет^"^n")
		fputs(iFile, "0 2 2 B 1 ^"привет^" ^"!g* !tПриветствуем вас на нашем сервере!^"^n")
		fputs(iFile, "0 2 0 B 1 ^"^" ^"!g* !tПожалуйста, прочтите правила игры: !gsay /rules^"^n")
		fputs(iFile, "0 3 0 R 1 ^"^" ^"!g* !tЗа игру с читами у нас банят НАВСЕГДА!^"")
		fclose(iFile)

if(bMode == MODE_AUTO) {
			log_amx("'%s' not found, creating default file...", ADS_FILE_NAME)
		}
		else {
			server_print("%s '%s' not found, creating default file...", g_szPluginPrefix, ADS_FILE_NAME)
		}
	}

iFile = fopen(g_szFilePath, "r")

if(!iFile)
	#if AMXX_VERSION_NUM < 183
		set_fail_state("Cannot read config (wrong chmod?)")
	#else
		set_fail_state("Cannot read '%s' (wrong chmod?)", ADS_FILE_NAME)
	#endif

new szString[MSG_LEN * 2], szMode[3], szType[3], szSound[3], szColor[2], szAuRe[2]

while(!feof(iFile))
	{
		fgets(iFile, szString, chx(szString))

if(!isdigit(szString[0])) {
			continue
		}

#if defined AUTORESPONDER
		g_AuReData[TEMPLATE][0] = EOS

parse( szString, szMode, chx(szMode), szType, chx(szType), szSound, chx(szSound), szColor, chx(szColor),
			szAuRe, chx(szAuRe), g_AuReData[TEMPLATE], chx(g_AuReData[TEMPLATE]), g_eMsgData[MSG_BODY], chx(g_eMsgData[MSG_BODY]) );

if(g_AuReData[TEMPLATE][0]) {
			g_AuReData[POINTER] = g_iMsgCount
			ArrayPushArray(g_aAuReArray, g_AuReData)
			g_iAuReCount++
		}
	#else
		parse( szString, szMode, chx(szMode), szType, chx(szType), szSound, chx(szSound), szColor, chx(szColor),
			szAuRe, chx(szAuRe), "", "", g_eMsgData[MSG_BODY], chx(g_eMsgData[MSG_BODY]) );
	#endif

#if AMXX_VERSION_NUM < 183
		#define replace_string replace_all
	#endif
		replace_string(g_eMsgData[MSG_BODY], chx(g_eMsgData[MSG_BODY]), "!n", "^1")
		replace_string(g_eMsgData[MSG_BODY], chx(g_eMsgData[MSG_BODY]), "!t", "^3")
		replace_string(g_eMsgData[MSG_BODY], chx(g_eMsgData[MSG_BODY]), "!g", "^4")

// Режим
		g_eMsgData[MSG_MODE] = str_to_num(szMode)

// Тип
	#if defined RANDOM_START
		switch(szType[0]) {
			case '0': {
				g_eMsgData[IS_MULTI_MSG] = false
				g_eMsgData[NOT_FOR_START] = false
			}
			case '1': {
				g_eMsgData[IS_MULTI_MSG] = true
				g_eMsgData[NOT_FOR_START] = false
			}
			case '2': {
				g_eMsgData[IS_MULTI_MSG] = true
				g_eMsgData[NOT_FOR_START] = true
			}
			case '3': {
				g_eMsgData[IS_MULTI_MSG] = false
				g_eMsgData[NOT_FOR_START] = true
			}
		}
	#else
		g_eMsgData[IS_MULTI_MSG] = (szType[0] == '1' || szType[0] == '2') ? true : false
	#endif
		// Звук
		g_eMsgData[MSG_SOUND_ID] = str_to_num(szSound) - 1

// Цвет
		switch(szColor[0])
		{
			case 'W': g_eMsgData[MSG_COLOR_ID] = print_team_grey
			case 'R': g_eMsgData[MSG_COLOR_ID] = print_team_red
			case 'B': g_eMsgData[MSG_COLOR_ID] = print_team_blue
			default: g_eMsgData[MSG_COLOR_ID] = print_team_default
		}

// Автоответчик
		g_eMsgData[AUTORESPOND_ONLY] = (szAuRe[0] == '0') ? false : true

// Грузим в DynArray
		ArrayPushArray(g_aMsgArray, g_eMsgData)
		g_iMsgCount++
	}

fclose(iFile)

if(g_iMsgCount) {
	#if defined RANDOM_START
		new iTryCount

while(g_iMsgCount)
		{
			if(++iTryCount == g_iMsgCount) // неправильно составлен конфиг, или просто bad luck?
			{
				g_iCurPos = 0
				break
			}

g_iCurPos = random_num(0, g_iMsgCount - 1)
			ArrayGetArray(g_aMsgArray, g_iCurPos, g_eMsgData)

if(g_eMsgData[NOT_FOR_START]) {
				continue
			}

break
		}
	#endif
		func_SetTask()
	}

if(bMode == MODE_AUTO) {
		server_print("%s %d messages to show", g_szPluginPrefix, g_iMsgCount)
	}
}

/* -------------------- */

public func_PrintMessage(iTaskID) {
	if(g_iCurPos == g_iMsgCount) {
		g_iCurPos = 0
	}

ArrayGetArray(g_aMsgArray, g_iCurPos++, g_eMsgData)

if(g_eMsgData[AUTORESPOND_ONLY] && iTaskID) {
		func_PrintMessage(iTaskID)
		return
	}

new iMode = get_pcvar_num(g_pMode)

if(iMode && g_eMsgData[MSG_MODE] && g_eMsgData[MSG_MODE] != iMode && iTaskID) { // Защита от бесконечного цикла
		if(!g_iFirstSkipPos) {
			g_iFirstSkipPos = g_iCurPos
		}
		else if(g_iFirstSkipPos == g_iCurPos) {
			g_iFirstSkipPos = 0
			func_SetTask()
			return
		}

func_PrintMessage(iTaskID)
		return
	}

g_iFirstSkipPos = 0

new iPlayers[MAX_PLAYERS], iPlCount

get_players(iPlayers, iPlCount, get_pcvar_num(g_pForAll) ? "ch" : "bch")

for(new i, iPlayer; i < iPlCount; i++) {
		iPlayer = iPlayers[i]

#if defined CMD_NAME
		if(g_bDisabled[iPlayer]) {
			continue
		}
	#endif

#if defined SHOW_PREFIX_WITH_ADS
		client_print_color(iPlayer, g_eMsgData[MSG_COLOR_ID], "%s^1%s", CHAT_PREFIX, g_eMsgData[MSG_BODY])
	#else
		client_print_color(iPlayer, g_eMsgData[MSG_COLOR_ID], "^1%s", g_eMsgData[MSG_BODY])
	#endif

if(g_eMsgData[MSG_SOUND_ID] != -1) {
		#if !defined SOUND_FOR_ALL
			if(is_user_alive(iPlayer)) {
				continue
			}
		#endif
		#if defined USE_SOUND
			func_SendAudio(iPlayer, g_szSounds[g_eMsgData[MSG_SOUND_ID]])
		#endif
		}
	}

// При использовании колорчат-стока мульти-вывод зачастую работает некорректно (нарушается порядок сообщений)
	// Я не знаю, с чем это связано, но костыль delay'ем решает проблему
	if(g_eMsgData[IS_MULTI_MSG]) {
	#if AMXX_VERSION_NUM < 183
		set_task(0.1, "func_PrintMessage", iTaskID)
	#else
		func_PrintMessage(iTaskID)
	#endif
		return
	}

func_SetTask()
}

/* -------------------- */

func_SetTask() {
#if defined RANDOM_FREQ
	set_task(random_float(get_pcvar_float(g_pFreqMin), get_pcvar_float(g_pFreqMax)), "func_PrintMessage", TASKID_TIMER)
#else
	set_task(get_pcvar_float(g_pFreq), "func_PrintMessage", TASKID_TIMER)
#endif
}

/* -------------------- */

public func_CmdShowStatus() {
	server_print("%s Total messages: %d | Last printed: #%d", g_szPluginPrefix, g_iMsgCount, g_iCurPos)
	return PLUGIN_HANDLED
}

/* -------------------- */

public func_CmdShowCustomMessage() {
#if AMXX_VERSION_NUM < 183
	new szArg[5]; read_argv(1, szArg, chx(szArg))
	new iMsgID = str_to_num(szArg)
#else
	new iMsgID = read_argv_int(1)
#endif

if(!(g_iMsgCount + 1 > iMsgID > 0)) /* if(1 > iMsgID || iMsgID > g_iMsgCount) */
		server_print("%s Error! Wrong message ID #%d (Total: %d)", g_szPluginPrefix, iMsgID, g_iMsgCount)
	else
	{
		remove_task(TASKID_TIMER)
		g_iCurPos = iMsgID - 1
		func_PrintMessage(0)
		server_print("%s Message #%d (Total: %d) printed!", g_szPluginPrefix, iMsgID, g_iMsgCount)
	}

return PLUGIN_HANDLED
}

/* -------------------- */

public func_CmdReloadFile() {
	remove_task(TASKID_TIMER)
	ArrayClear(g_aMsgArray)
#if defined AUTORESPONDER
	ArrayClear(g_aAuReArray)
	g_iAuReCount = 0
#endif
	new iOldMsgCount = g_iMsgCount
	g_iMsgCount = 0
	g_iCurPos = 0
	g_iFirstSkipPos = 0
	func_LoadMessages(MODE_MANUAL)
	server_print("%s Message count before/after reading: %d/%d", g_szPluginPrefix, iOldMsgCount, g_iMsgCount)

return PLUGIN_HANDLED
}

/* -------------------- */

public plugin_end() {
	ArrayDestroy(g_aMsgArray)

#if defined AUTORESPONDER
	ArrayDestroy(g_aAuReArray)
#endif

#if defined CMD_NAME
	if(g_iVault != INVALID_HANDLE) {
		nvault_close(g_iVault)
	}
#endif
}

/* -------------------- */

#if defined CMD_NAME
	public client_putinserver(id) {
		if(g_iVault == INVALID_HANDLE) {
			g_bDisabled[id] = false
			return
		}

get_user_authid(id, g_szAuthID, chx(g_szAuthID))
		g_bDisabled[id] = bool:nvault_get(g_iVault, g_szAuthID)

#if defined OBSOLETE_DAYS
		if(g_bDisabled[id]) {
			nvault_touch(g_iVault, g_szAuthID)
		}
	#endif
	}
#endif

/* -------------------- */

#if defined USE_SOUND
	public plugin_precache() {
		for(new i; i < sizeof(g_szSounds); i++) {
			precache_sound(g_szSounds[i])
		}
	}
#endif

/* -------------------- */

stock func_SendAudio(id, szSample[]) {
	message_begin(MSG_ONE_UNRELIABLE, g_iMsgSendAudio, .player = id)
	write_byte(id)
	write_string(szSample)
	write_short(PITCH_NORM)
	message_end()
}

Загрузил exec208

2019-01-06 16:44:36

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram