	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Round End Trash Mix

Теги: Скачать плагины csgoЭффекты

Всем любителям мусора в конце раунда.

Гравитация в конце раунда.
Скорость в конце раунда.
Слоумо в конце раунда.
Бхоп в конце раунда.
Третье лицо в конце раунда.
Ноклип в конце раунда.

Возможности настройки для каждого клиента отдельно.
Полное отключение ненужных вам функций.

Компилятор: 1.9.0.6281 +ZIP 1902

Команды:

sm_rem - Меню настроек rem

sm_reload_rem - Перезагрузка конфига

.sma / .sp

#include <sourcemod>
#include <clientprefs>

#pragma newdecls required
#pragma semicolon 1

#define GRAVITY (1 << 1)
#define SLOW    (1 << 2)
#define SPEED   (1 << 3)
#define BHOP    (1 << 4)
#define THIRDPERSON    (1 << 5)
#define NOCLIP    (1 << 6)

public Plugin myinfo =
{
	name = "Round End Thrash Mix",
	author = "Tonki_Ton",
	description = "Мусорная солянка",
	version = "1.0.0",
	url = "https://hlmod.ru"
};

Handle g_hRemCookie;

ConVar g_cTimeScale;

int g_iMovProp, g_iFlags[MAXPLAYERS+1];

float g_fSpeedValue, 
	  g_fGravValue, 
	  g_fSlowValue;

bool g_bGravAllowed,
	 g_bSlowAllowed,
	 g_bSpeedAllowed,
	 g_bBhopAllowed,
	 g_bThirdPAllowed,
	 g_bNoclipAllowed,
	 g_bBhopOn[MAXPLAYERS+1];

public void OnPluginStart()
{
	g_hRemCookie = RegClientCookie("REM", "round end trash mix cookies", CookieAccess_Private);
	g_iMovProp = FindSendPropInfo("CCSPlayer", "m_flLaggedMovementValue");
	g_cTimeScale = FindConVar("host_timescale");

HookEvent("round_start", OnRS);
	HookEvent("round_end", OnRE);

RegAdminCmd("sm_reload_rem", RR, ADMFLAG_ROOT);
	RegConsoleCmd("sm_rem", RemMenu);

for (int i = 1; i <= MaxClients; i++) if (IsClientInGame(i) && AreClientCookiesCached(i))
		OnClientCookiesCached(i);

LoadTranslations("round_end_mix.phrases");
}

public Action RR(int client, int args)
{
	PrintToConsole(client, "Конфиг перезагружен!");
	OnMapStart();

return Plugin_Handled;
}

public void OnMapStart()
{
	char sBuff[128];

KeyValues KvRm = new KeyValues("REM_Settings");

BuildPath(Path_SM, sBuff, sizeof(sBuff), "configs/round_end_mix.txt");
	if(!KvRm.ImportFromFile(sBuff))
	{
		LogMessage("Конфигурационный файл отсутсвует!");
		LogMessage("Установлены параметры по умолчанию.");
	}

KvRm.Rewind();

g_bGravAllowed = view_as<bool>(KvRm.GetNum("Enable_Gravity", 1));
	g_bSlowAllowed = view_as<bool>(KvRm.GetNum("Enable_Slow_Motion", 1));
	g_bSpeedAllowed = view_as<bool>(KvRm.GetNum("Enable_Speed", 1));
	g_bBhopAllowed = view_as<bool>(KvRm.GetNum("Enable_Bunny_hop", 1));
	g_bThirdPAllowed = view_as<bool>(KvRm.GetNum("Enable_Thirdperson", 1));
	g_bNoclipAllowed = view_as<bool>(KvRm.GetNum("Enable_Noclip", 1));

g_fGravValue = KvRm.GetFloat("Gravity_Value", 0.5);
	g_fSlowValue = KvRm.GetFloat("Slow_Motion_Value", 0.4);
	g_fSpeedValue = KvRm.GetFloat("Speed_Value", 1.5);

delete KvRm;
}

public void OnPluginEnd()
{
	for (int i = 1; i <= MaxClients; i++) if (IsClientInGame(i))
		OnClientDisconnect(i);
}

public void OnClientCookiesCached(int client)
{
	char sBuff[16];
	GetClientCookie(client, g_hRemCookie, sBuff, sizeof(sBuff));
	if(!sBuff[0])
	{
		g_iFlags[client] = 0;
		return;
	}
	g_iFlags[client] = StringToInt(sBuff);
}

public void OnClientDisconnect(int client)
{
	char sFlags[16];

IntToString(g_iFlags[client], sFlags, 16);
	SetClientCookie(client, g_hRemCookie, sFlags);
	g_bBhopOn[client] = false;
}

public Action RemMenu(int client, int args)
{
	Menu menu = new Menu(RemMenuHandler);

char sBuff[128];

menu.SetTitle("%t\n \n", "rem_menu");

FormatEx(sBuff, sizeof(sBuff), "%t", "gravity", g_bGravAllowed ? (g_iFlags[client] & GRAVITY) ? "+":"-":"X");
	menu.AddItem("", sBuff, g_bGravAllowed ? ITEMDRAW_DEFAULT:ITEMDRAW_DISABLED);

FormatEx(sBuff, sizeof(sBuff), "%t", "slowmotion", g_bSlowAllowed ? (g_iFlags[client] & SLOW) ? "+":"-":"X");
	menu.AddItem("", sBuff, g_bSlowAllowed ? ITEMDRAW_DEFAULT:ITEMDRAW_DISABLED);

FormatEx(sBuff, sizeof(sBuff), "%t", "speed", g_bSpeedAllowed ? (g_iFlags[client] & SPEED)  ? "+":"-":"X");
	menu.AddItem("", sBuff, g_bSpeedAllowed ? ITEMDRAW_DEFAULT:ITEMDRAW_DISABLED);

FormatEx(sBuff, sizeof(sBuff), "%t", "bhop", g_bBhopAllowed ? (g_iFlags[client] & BHOP)  ? "+":"-":"X");
	menu.AddItem("", sBuff, g_bBhopAllowed ? ITEMDRAW_DEFAULT:ITEMDRAW_DISABLED);

FormatEx(sBuff, sizeof(sBuff), "%t", "thirdperson", g_bThirdPAllowed ? (g_iFlags[client] & THIRDPERSON)  ? "+":"-":"X");
	menu.AddItem("", sBuff, g_bThirdPAllowed ? ITEMDRAW_DEFAULT:ITEMDRAW_DISABLED);

FormatEx(sBuff, sizeof(sBuff), "%t", "noclip", g_bNoclipAllowed ? (g_iFlags[client] & NOCLIP)  ? "+":"-":"X");
	menu.AddItem("", sBuff, g_bNoclipAllowed ? ITEMDRAW_DEFAULT:ITEMDRAW_DISABLED);

menu.Display(client, MENU_TIME_FOREVER);
}

public int RemMenuHandler(Menu menu, MenuAction action, int client, int a)
{
	if (action == MenuAction_Select)
	{
		switch (a)
		{
			case 0: g_iFlags[client] ^= GRAVITY;
			case 1: g_iFlags[client] ^= SLOW;
			case 2: g_iFlags[client] ^= SPEED;
			case 3: g_iFlags[client] ^= BHOP;
			case 4: g_iFlags[client] ^= THIRDPERSON;
			case 5: g_iFlags[client] ^= NOCLIP;
		}
		RemMenu(client, 0);
	}
	else if (action == MenuAction_End) 
		delete menu;
}

public void OnRE(Event event, const char[] name, bool dB)
{
	TrashMix(true);
}

public void OnRS(Event event, const char[] name, bool dB)
{
	TrashMix(false);
}

void TrashMix(bool RoundEnd)
{
	for (int i = 1; i <= MaxClients; i++) if (IsClientInGame(i) && !IsFakeClient(i))
	{
		if (RoundEnd && IsPlayerAlive(i))
		{
			if (g_iFlags[i] & GRAVITY) SetEntPropFloat(i, Prop_Data, "m_flGravity", g_fGravValue);
			if (g_iFlags[i] & SLOW)
			{
				SetEntDataFloat(i, g_iMovProp, g_fSlowValue);
				SetConVarFloat(g_cTimeScale, g_fSlowValue, true);
			}
			if (g_iFlags[i] & SPEED) SetEntDataFloat(i, g_iMovProp, g_fSpeedValue);
			if (g_iFlags[i] & BHOP) g_bBhopOn[i] = true;
			if (g_iFlags[i] & THIRDPERSON) ClientCommand(i, "thirdperson");
			if (g_iFlags[i] & NOCLIP) SetEntityMoveType(i, MOVETYPE_NOCLIP);
		}
		else 
		{
			SetEntPropFloat(i, Prop_Data, "m_flGravity", 1.0);
			SetConVarFloat(g_cTimeScale, 1.0, true);
			ClientCommand(i, "firstperson");
			g_bBhopOn[i] = false;
		}
	}
}

public Action OnPlayerRunCmd(int client, int &buttons, int &impulse, float vel[3], float angles[3], int &weapon)
{
	if (g_bBhopOn[client] && IsPlayerAlive(client) && (buttons & IN_JUMP) && !(GetEntityFlags(client) & FL_ONGROUND) && !(GetEntityMoveType(client) & MOVETYPE_LADDER) && (GetEntProp(client, Prop_Data, "m_nWaterLevel") <= 1))
		buttons &= ~IN_JUMP;
}

Загрузил Ju4ka1371

2019-01-24 20:03:40

204

Скачать

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram