	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Shield Teleport 1.0.2

Теги: Скачать плагины csgoСерверные

Защищает игрока определенное время после того как он использовал телепорт карты.
Полезен на таких режимах как: surf, deathrun...

Компилятор: 1.10.0 +ZIP 728

Команды:

sm_st | sm_shieldteleport - открывает меню

.sma / .sp

#include <sdkhooks>
#include <sdktools_entoutput>
#include <clientprefs>

public Plugin myinfo =
{
	name = "Shield Teleport",
	author = "Drumanid",
	version = "1.0.2",
	url = "Discord: Drumanid#9108 | Site: dev-cs.ru"
};

#define LC(%0) for(int %0 = 1; %0 <= MaxClients; ++%0) if(IsClientInGame(%0))
#define IsValidClient(%0) 1 <= %0 <= MaxClients && IsClientInGame(%0)
#define Hook(%0,%1) %0.AddChangeHook(view_as<ConVarChanged>(%1))
#define MP MAXPLAYERS +1
#define SZF(%0) %0, sizeof(%0)

// Координаты худ соообщения... (минимально 0.0 / максимально 1.0)
#define coordx 0.3 // По x / вправо/влево
#define coordy 0.2 // По y / вверх/вниз
#define timehud 3.0 // Время до исчезновения худ сообщения

Handle	g_hTimer[MP],
		g_hSyncHud,
		g_hCookieShield,
		g_hCookieEffect;

float	g_fTimer;

int		g_iTime[MP],
		g_iTimeBlock,
		g_iTeam,
		g_iMessage,
		g_iOffset;

bool	g_bPaint,
		g_bEffect,
		g_bUseShield[MP],
		g_bUseEffect[MP];
		//g_bRecovery;

public void OnPluginStart()
{
	HookEntityOutput("trigger_teleport", "OnStartTouch", OnStartTouch);
	HookEvent("player_spawn", view_as<EventHook>(PlayerSpawn));
	RegConsoleCmd("sm_st", ShieldCommand); RegConsoleCmd("sm_shieldteleport", ShieldCommand);

ConVar hCvar = CreateConVar("shield_teleport_timer", "3.0", "Сколько игрок будет защищен и не сможет наносить урон после телепорта?"); Hook(hCvar, CvarHookTimer); g_fTimer = hCvar.FloatValue;
	hCvar = CreateConVar("shield_teleport_paint", "1", "1 - включить раскраску модели игрока который показывает другим игрокам, что по нему запрещен урон / 0 - выключить", _, true, 0.0, true, 1.0); Hook(hCvar, CvarHookPaint); g_bPaint = hCvar.BoolValue;
	hCvar = CreateConVar("shield_teleport_effect", "1", "1 - включить эффект который показывает игроку, что по нему запрещен урон / 0 - выключить", _, true, 0.0, true, 1.0); Hook(hCvar, CvarHookEffect); g_bEffect = hCvar.BoolValue;
	//hCvar = CreateConVar("shield_teleport_recovery", "1", "1 - восстановить время защиты, если игрок уже защищен / 0 - не восстанавливать", _, true, 0.0, true, 1.0); Hook(hCvar, CvarHookRecovery); g_bRecovery = hCvar.BoolValue;
	hCvar = CreateConVar("shield_teleport_time_block", "10", "Сколько секунд не выдавать игроку защиту после использования телепорта?"); Hook(hCvar, CvarHookTimeBlock); g_iTimeBlock = hCvar.IntValue;
	hCvar = CreateConVar("shield_teleport_team", "1", "Какой команде давать защиту? 1 - всем / 2 - т / 3 кт", _, true, 1.0, true, 3.0); Hook(hCvar, CvarHookTeam); g_iTeam = hCvar.IntValue;
	hCvar = CreateConVar("shield_teleport_message", "3", "Как выводить сообщения игроку? 0 - выключить / 1 - в чате / 2 - в хинте / 3 - в хинте (принудительный) / 4 - в худе", _, true, 0.0, true, 4.0); Hook(hCvar, CvarHookMessage); g_iMessage = hCvar.IntValue;

AutoExecConfig(true, "shield_teleport");
	LoadTranslations("shield_teleport.phrases.txt");

g_hCookieShield = RegClientCookie("shield_teleport_protection", "Щит телепорта | Защита", CookieAccess_Private);
	g_hCookieEffect = RegClientCookie("shield_teleport_effect", "Щит телепорта | Эффект", CookieAccess_Private);
	g_hSyncHud = CreateHudSynchronizer();

LC(iClient)
	{
		OnClientPostAdminCheck(iClient);
		OnClientCookiesCached(iClient);
	}
}

void CvarHookTimer(ConVar hCvar) { g_fTimer = hCvar.FloatValue; }
void CvarHookPaint(ConVar hCvar) { g_bPaint = hCvar.BoolValue; }
void CvarHookEffect(ConVar hCvar) { g_bEffect = hCvar.BoolValue; }
//void CvarHookRecovery(ConVar hCvar) { g_bRecovery = hCvar.BoolValue; }
void CvarHookTimeBlock(ConVar hCvar) { g_iTimeBlock = hCvar.IntValue; }
void CvarHookTeam(ConVar hCvar) { g_iTeam = hCvar.IntValue; }
void CvarHookMessage(ConVar hCvar) { g_iMessage = hCvar.IntValue; }

public void OnConfigsExecuted()
{
	if((g_iOffset = FindSendPropInfo("CAI_BaseNPC", "m_clrRender")) > 0) return;
	
	FindConVar("shield_teleport_paint").SetBool(false);
	LogError("No found offset: 'm_clrRender' | shield_teleport_paint = disable");
}

void Message(int iClient, const char[] sMessage, any...)
{
	if(g_iMessage == 0) return;
	
	char sBuffer[256]; VFormat(SZF(sBuffer), sMessage, 3);
	switch(g_iMessage)
	{
		case 1: PrintToChat(iClient, sBuffer);
		case 2: PrintHintText(iClient, sBuffer);
		case 3:	PrintCenterText(iClient, sBuffer);
		case 4:
		{
			SetHudTextParams(coordx, coordy, timehud, 255, 255, 255, 255, 0, 0.5, 0.5, 0.5);
			ShowSyncHudText(iClient, g_hSyncHud, sBuffer);
		}
	}
}

public void OnClientCookiesCached(int iClient)
{
	char sValue[4]; GetClientCookie(iClient, g_hCookieShield, sValue, sizeof(sValue));
	g_bUseShield[iClient] = sValue[0] ? view_as<bool>(StringToInt(sValue)):true;
	GetClientCookie(iClient, g_hCookieEffect, sValue, sizeof(sValue));
	g_bUseEffect[iClient] = sValue[0] ? view_as<bool>(StringToInt(sValue)):true;
}

public Action ShieldCommand(int iClient, int iArgs)
{
	if(iClient > 0 && iArgs < 1)
	{
		if(g_bEffect) MainMenu(iClient);
		else ChangeProtection(iClient);
	}

return Plugin_Handled;
}

void MainMenu(int iClient)
{
	Menu hMenu = new Menu(MainMenuItems);
	hMenu.ExitButton = true;
	
	SetGlobalTransTarget(iClient);
	hMenu.SetTitle("%t", "Title menu");

char sBuffer[256];
	if(g_bUseShield[iClient])
	{
		FormatEx(SZF(sBuffer), "%t [%t]", "Item, protection", "On");
		hMenu.AddItem(NULL_STRING, sBuffer);
		FormatEx(SZF(sBuffer), "%t [%t]", "Item, effect", g_bUseEffect[iClient] ? "On":"Off");
		hMenu.AddItem(NULL_STRING, sBuffer);
	}
	else
	{
		FormatEx(SZF(sBuffer), "%t [%t]", "Item, protection", "Off");
		hMenu.AddItem(NULL_STRING, sBuffer);
	}

hMenu.Display(iClient, MENU_TIME_FOREVER);
}
public int MainMenuItems(Menu hMenu, MenuAction action, int iClient, int iItem)
{
	switch(action)
	{
		case MenuAction_End: delete hMenu;
		case MenuAction_Select:
		{
			switch(iItem)
			{
				case 0: ChangeProtection(iClient);
				case 1:
				{
					if((g_bUseEffect[iClient] = !g_bUseEffect[iClient]))
					{
						SetClientCookie(iClient, g_hCookieEffect, "1");
						PrintToChat(iClient, "%t %t", "Message, effect", "On");
					}
					else
					{
						SetClientCookie(iClient, g_hCookieEffect, "0");
						PrintToChat(iClient, "%t %t", "Message, effect", "Off");
					}
				}
			}

MainMenu(iClient);
		}
	}
}

void ChangeProtection(int iClient)
{
	if((g_bUseShield[iClient] = !g_bUseShield[iClient]))
	{
		SetClientCookie(iClient, g_hCookieShield, "1");
		PrintToChat(iClient, "%t %t", "Message, protection", "On");
	}
	else
	{
		SetClientCookie(iClient, g_hCookieShield, "0");
		PrintToChat(iClient, "%t %t", "Message, protection", "Off");
	}
}

public void OnStartTouch(const char[] sOutput, int iCaller, int iActivator, float fDelay)
{
	/*if(g_hTimer[iActivator] != null)
	{
		if(g_bRecovery)
		{
			KillTimer(g_hTimer[iActivator]);
			Use(iActivator);
		}

return;
	}*/

Use(iActivator);
}

void Use(int iClient)
{
	if((iClient < 1 || iClient > MaxClients) ||
	(g_iTeam != 1 && GetClientTeam(iClient) != g_iTeam) ||
	!g_bUseShield[iClient]) return;

int iTime = GetTime();
	if(g_iTime[iClient] > iTime)
	{
		Message(iClient, "%t", "No protection", g_iTime[iClient] - iTime);
		return;
	}

int iTimer = RoundToCeil(g_fTimer);
	g_iTime[iClient] = iTime + iTimer + g_iTimeBlock;
	Message(iClient, "%t", "Protection enabled", g_fTimer);

if(g_hTimer[iClient]) KillTimer(g_hTimer[iClient]);
	g_hTimer[iClient] = CreateTimer(g_fTimer, TimerShield, GetClientUserId(iClient));

if(g_bPaint)
	{
		for(int i; i < 4; ++i)
		{
			if(GetEntData(iClient, g_iOffset + i, 1) != 255) break;

if(i != 3) continue;
			SetEntityRenderColor(iClient, 165, 42, 42, 255);
		}
	}

if(g_bEffect && g_bUseEffect[iClient])
	{
		iTimer = iTimer * 600;
		Handle hMessage = StartMessageOne("Fade", iClient);
		if(GetUserMessageType() == UM_Protobuf)
		{
			PbSetInt(hMessage, "duration", iTimer);
			PbSetInt(hMessage, "hold_time", 0);
			PbSetInt(hMessage, "flags", 0x0001);
			PbSetColor(hMessage, "clr", {255, 0, 0, 150});
		}
		else
		{
			BfWriteShort(hMessage, iTimer);
			BfWriteShort(hMessage, 0);
			BfWriteShort(hMessage, 0x0001);
			BfWriteByte(hMessage, 255);
			BfWriteByte(hMessage, 0);
			BfWriteByte(hMessage, 0);
			BfWriteByte(hMessage, 150);
		}
		EndMessage();
	}
}

public Action TimerShield(Handle hTimer, int iClient)
{
	if((iClient = GetClientOfUserId(iClient)) > 0 && IsClientInGame(iClient) && IsPlayerAlive(iClient))
	{
		Painted(iClient);
		Message(iClient, "%t", "Protection disabled");
	}

g_hTimer[iClient] = null;
	return Plugin_Stop;
}

void PlayerSpawn(Event hEvent)
{
	int iClient = GetClientOfUserId(hEvent.GetInt("userid"));

Painted(iClient);
	OnClientDisconnect(iClient);
}

void Painted(int iClient)
{
	if(!g_bPaint) return;
	
	int iColors[4];
	for(int i; i < 4; ++i) iColors[i] = GetEntData(iClient, g_iOffset + i, 1);
	if(iColors[0] == 165 && iColors[1] == 42 && iColors[2] == 42 && iColors[3] == 255) SetEntityRenderColor(iClient, 255, 255, 255, 255);
}

public void OnClientDisconnect(int iClient)
{
	if(g_hTimer[iClient] == null) return;

KillTimer(g_hTimer[iClient]);
	g_hTimer[iClient] = null;
}

public void OnClientPostAdminCheck(int iClient)
{
	SDKHook(iClient, SDKHook_OnTakeDamage, OnTakeDamage);
}

public Action OnTakeDamage(int iVictim, int &iAttacker, int &iInflictor, float &fDamage, int &iDamageType)
{
	if(IsValidClient(iVictim) && IsValidClient(iAttacker) &&
	(g_hTimer[iVictim] || g_hTimer[iAttacker])) return Plugin_Handled;
	
	return Plugin_Continue;
}

Загрузил ADEPT

2020-05-30 17:11:16

Скачать

195.211.60.213:27015

УКРАЇНА - Б А Н Д Е Р Ш Т А Т - [2000 FPS] 18+

195.211.60.213:27018

В І Л Ь Н А - У К Р А Ї Н А [ RYZEN 9 - 5.7 GHZ ]

195.211.60.213:27016

(Д) (І) (В) (О) (Ч) (А) - (В) (Л) (А) (Д) (А) | 18+

195.211.60.213:27017

бред, когда ты респавнишься, тебя тепает в последний телепорт

1attain

2023-06-20 02:11:34

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam Telegram