Скинуть основное оружие перед смертью [CS:CZ + CS 1.6]

// Создание AMXMODX Плагинов: http://vk.com/cs_rain 

​

#include <amxmodx>

#include <hamsandwich>

#include <fakemeta>

#include <cstrike>

// #include <cs_ham_bots_api>

​

// HACK: pev_ field used to store additional ammo on weapons

const PEV_ADDITIONAL_AMMO = pev_iuser1

​

// Weapon bitsums

const PRIMARY_WEAPONS_BIT_SUM = (1<<CSW_SCOUT)|(1<<CSW_XM1014)|(1<<CSW_MAC10)|(1<<CSW_AUG)|(1<<CSW_UMP45)|(1<<CSW_SG550)|(1<<CSW_GALIL)|(1<<CSW_FAMAS)|(1<<CSW_AWP)|(1<<CSW_MP5NAVY)|(1<<CSW_M249)|(1<<CSW_M3)|(1<<CSW_M4A1)|(1<<CSW_TMP)|(1<<CSW_G3SG1)|(1<<CSW_SG552)|(1<<CSW_AK47)|(1<<CSW_P90)

const SECONDARY_WEAPONS_BIT_SUM = (1<<CSW_P228)|(1<<CSW_ELITE)|(1<<CSW_FIVESEVEN)|(1<<CSW_USP)|(1<<CSW_GLOCK18)|(1<<CSW_DEAGLE)

​

// Max BP ammo for weapons

new const MAXBPAMMO[] = { -1, 52, -1, 90, 1, 32, 1, 100, 90, 1, 120, 100, 100, 90, 90, 90, 100, 120,

            30, 120, 200, 32, 90, 120, 90, 2, 35, 90, 90, -1, 100 }

​

// Ammo Type Names for weapons

new const AMMOTYPE[][] = { "", "357sig", "", "762nato", "", "buckshot", "", "45acp", "556nato", "", "9mm", "57mm", "45acp",

            "556nato", "556nato", "556nato", "45acp", "9mm", "338magnum", "9mm", "556natobox", "buckshot",

            "556nato", "9mm", "762nato", "", "50ae", "556nato", "762nato", "", "57mm" }

​

public plugin_init()

{

    register_plugin("Pre Kill: Drop Weapon", "1.0", "Leo_[BH]")

    RegisterHam(Ham_Killed, "player", "PlayerKill_Pre", 0)

    // RegisterHamBots(Ham_Killed, "PlayerKill_Pre", 0)

    RegisterHam(Ham_AddPlayerItem, "player", "fw_AddPlayerItem")

    // RegisterHamBots(Ham_AddPlayerItem, "fw_AddPlayerItem")

}

​

public PlayerKill_Pre(id)

{

    drop_weapons(id, 1)

}

​

// Ham Weapon Pickup Forward

public fw_AddPlayerItem(id, weapon_ent)

{

    // HACK: Retrieve our custom extra ammo from the weapon

    new extra_ammo = pev(weapon_ent, PEV_ADDITIONAL_AMMO)

    // If present

    if (extra_ammo)

    {

        // Get weapon's id

        new weaponid = cs_get_weapon_id(weapon_ent)

        // Add to player's bpammo

        ExecuteHamB(Ham_GiveAmmo, id, extra_ammo, AMMOTYPE[weaponid], MAXBPAMMO[weaponid])

        set_pev(weapon_ent, PEV_ADDITIONAL_AMMO, 0)

    }

}

​

// Drop primary/secondary weapons

stock drop_weapons(id, dropwhat)

{

    // Get user weapons

    static weapons[32], num, i, weaponid

    num = 0 // reset passed weapons count (bugfix)

    get_user_weapons(id, weapons, num)

    // Loop through them and drop primaries or secondaries

    for (i = 0; i < num; i++)

    {

        // Prevent re-indexing the array

        weaponid = weapons[i]

        if ((dropwhat == 1 && ((1<<weaponid) & PRIMARY_WEAPONS_BIT_SUM)) || (dropwhat == 2 && ((1<<weaponid) & SECONDARY_WEAPONS_BIT_SUM)))

        {

            // Get weapon entity

            static wname[32], weapon_ent

            get_weaponname(weaponid, wname, charsmax(wname))

            weapon_ent = fm_find_ent_by_owner(-1, wname, id)

            // Hack: store weapon bpammo on PEV_ADDITIONAL_AMMO

            set_pev(weapon_ent, PEV_ADDITIONAL_AMMO, cs_get_user_bpammo(id, weaponid))

            // Player drops the weapon and looses his bpammo

            engclient_cmd(id, "drop", wname)

            cs_set_user_bpammo(id, weaponid, 0)

        }

    }

}

​

// Find entity by its owner (from fakemeta_util)

stock fm_find_ent_by_owner(entity, const classname[], owner)

{

    while ((entity = engfunc(EngFunc_FindEntityByString, entity, "classname", classname)) && pev(entity, pev_owner) != owner) { /* keep looping */ }

    return entity;

}

​

// Разработка серверов Counter-Strike: Condition Zero: https://goo.gl/forms/GIyvSAw1IJ48szDn2