	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	REBUY	SCANMON	ПАРТНЕРЫ	ФОРУМ	МОНИТОР	HELP	КОНТАКТЫ

Team Grenade Trail 1.3

Теги: Скачать плагины csgoСерверные

Плагин добавит на Ваш сервер цветную линию в след за гранатами. Теперь, когда Вы кинете какую-либо гранату, в след за ней будет цветная линия, как показано на фотографии данного материала. Плагин полезен тем, что он показывает траекторию гранаты. Благодаря этой траектории, Ваши союзники могут быстрее реагировать на то, где взорвется та или иная граната.

Функции
Запись в куки если игрок оключил для себя трейлы за гранатами (при перезаходе на сервер настрока сохранится)
Автодобавление в пункт настроек игрока команда !settings

Компилятор: 1.10.0 +ZIP 104

Команды:

!gtrail Включить или отключить показ трейлов за гранатами

.sma / .sp

#pragma semicolon 1

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
#include <clientprefs>
#include <colors>

#pragma newdecls required

int g_beamsprite;

public Plugin myinfo =
{
	name = "CS:GO Team Grenade Trail (mmcs.pro)",
	author = "9iky6, SAZONISCHE",
	version = "1.3",
	description = "Adds grenade trails",
	url = "https://mmcs.pro"
};

enum DataNade
{
	nade_none = -1,
	nade_he,
	nade_flash,
	nade_smoke,
	nade_decoy,
	nade_molotov,
	nade_inc,
	nade_tag
};

int g_mGrenadeColor[DataNade][] = 
{
	{194,	84,	11,	225},
	{232,	232,	232,	225},
	{136,	194,	11,	225},
	{4,	134,	181,	225},
	{226,	88,	34,	225},
	{226,	88,	34,	225},	
	{204,	0,	102,	225}
};

Handle g_tNadesName;
bool g_bNadeTrailEnabled[MAXPLAYERS+1] = {false, ...};
Handle g_hCookie = null;

public void OnMapStart()
{
	g_beamsprite    = PrecacheModel("materials/sprites/laserbeam.vmt", true);
}

public void OnPluginStart()
{
	g_tNadesName = CreateTrie();

LoadTranslations("team_grenade_trails.phrases");

SetTrieValue( g_tNadesName, "hegrenade_projectile", nade_he );
	SetTrieValue( g_tNadesName, "flashbang_projectile", nade_flash );
	SetTrieValue( g_tNadesName, "smokegrenade_projectile", nade_smoke );
	SetTrieValue( g_tNadesName, "decoy_projectile", nade_decoy );
	SetTrieValue( g_tNadesName, "molotov_projectile", nade_molotov );
	SetTrieValue( g_tNadesName, "incgrenade_projectile", nade_inc );
	SetTrieValue( g_tNadesName, "tagrenade_projectile", nade_tag );

g_hCookie = RegClientCookie("sm_nadetrail", "Nade Trails", CookieAccess_Private);
	SetCookieMenuItem(DsCookieMenuHandler, 0, "Nade Trails");
	
	RegConsoleCmd("sm_gtrail", Cmd_NadeTrail);

for (int client = 1; client <= MaxClients; client++)
	{
		if(!IsClientInGame(client) || !AreClientCookiesCached(client))
			continue;
		
		OnClientCookiesCached(client);
	}
}

public void OnClientCookiesCached(int client)
{
	char[] szBuffer = new char[2];
	GetClientCookie(client, g_hCookie, szBuffer, 2);
	g_bNadeTrailEnabled[client] = szBuffer[0] ? view_as<bool>(StringToInt(szBuffer)) : true;
}

public Action Cmd_NadeTrail(int client, int args)
{
	if(!client)
	{
		ReplyToCommand(client, "[SM] Only ingame command");
		return Plugin_Handled;
	}
	
	if(g_bNadeTrailEnabled[client])
	{
		g_bNadeTrailEnabled[client] = false;
		SetClientCookie(client, g_hCookie, "0");
		CPrintToChat(client, "%t", "NadeTrail_off");
	}
	else
	{
		g_bNadeTrailEnabled[client] = true;
		SetClientCookie(client, g_hCookie, "1");
		CPrintToChat(client, "%t", "NadeTrail_on");
	}
	
	return Plugin_Handled;
}

public void DsCookieMenuHandler(int client, CookieMenuAction action, any info, char[] buffer, int maxlen)
{
	switch(action)
	{
		case CookieMenuAction_DisplayOption:
			Format(buffer, maxlen, "%T", g_bNadeTrailEnabled[client] ? "Off Nade Trail" : "On Nade Trail", client);
		
		case CookieMenuAction_SelectOption:
		{
			if(g_bNadeTrailEnabled[client])
			{
				g_bNadeTrailEnabled[client] = false;
				SetClientCookie(client, g_hCookie, "0");
				CPrintToChat(client, "%t", "NadeTrail_off");
				FakeClientCommand(client, "sm_settings");				
			}
			else
			{
				g_bNadeTrailEnabled[client] = true;
				SetClientCookie(client, g_hCookie, "1");
				CPrintToChat(client, "%t", "NadeTrail_on");
				FakeClientCommand(client, "sm_settings");				
			}
		}
	}
}

public void OnEntityCreated(int entity, const char[] classname)
{
	DataNade iType;
	if(IsValidEntity(entity) && GetTrieValue(g_tNadesName, classname, iType))
	{
		SDKHook(entity, SDKHook_SpawnPost, OnEntitySpawned);
	}
}

public void OnEntityDeleted(int entity, const char[] classname)
{
	DataNade iType;
	if(IsValidEntity(entity) && GetTrieValue(g_tNadesName, classname, iType))
	{
		SDKUnhook(entity, SDKHook_SpawnPost, OnEntitySpawned);
	}
}

public void OnEntitySpawned(int entity)
{
	if(!IsValidEdict(entity))
	{
		return;
	}
	
	DataNade iType;
	char classname[64];
	GetEdictClassname(entity, classname, sizeof(classname)-1);
	int owner = GetEntPropEnt(entity, Prop_Data, "m_hOwnerEntity");
	
	if(GetTrieValue(g_tNadesName, classname, iType))
	{
		TE_SetupBeamFollow(entity, g_beamsprite, 0, 2.5, 0.9, 1.0, 1, g_mGrenadeColor[iType]);
		TE_SendToTeam(GetClientTeam(owner));
	}
}

stock void TE_SendToTeam(int iTeam, float delay=0.0)
{
	int total = 0;
	int[] clients = new int[MaxClients];
	for (int i = 1; i <= MaxClients; i++)
	{
		if (IsClientInGame(i) && IsPlayerAlive(i) && g_bNadeTrailEnabled[i] && GetClientTeam(i) == iTeam)
		{
			clients[total++] = i;
		}
	}
	
	if(total)
		TE_Send(clients, total, delay);
}

Загрузил ADEPT

2020-06-03 01:19:22

Скачать

XXX.XXX.XXX.XXX:27015

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	Вебхостинг PsychoStats Superban Amx Bans Fast DL СS:Bans	Astats Backup MySQL Boost HLTV Army	Помощь Тарифы Дисконты Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam ok.ru