Team Voice Chat

#include <amxmodx>

#tryinclude <reapi>

​

// Если раскомментировано, живые НЕ будут слышать мёртвых, и наоборот

//#define OBEY_ALIVE_STATE

​

#if !defined _reapi_included

    #include <fakemeta>

#endif

​

#if AMXX_VERSION_NUM < 183

    #define client_disconnected client_disconnect

#endif

​

new g_iSpeakBitSum

​

public plugin_init() {

    register_plugin("Team Voice Chat", "0.1", "mx?!")

​

#if defined _reapi_included

    RegisterHookChain(RG_CSGameRules_CanPlayerHearPlayer, "CanPlayerHearPlayer_Pre")

#else

    register_forward(FM_Voice_SetClientListening, "OnSetClientListening_Pre")

#endif

​

    register_clcmd("+teamvoice", "func_AdminVoiceOn")

    register_clcmd("-teamvoice", "func_AdminVoiceOff")

}

​

#if defined _reapi_included

    public CanPlayerHearPlayer_Pre(iReceiver, iSender) {

        if(!IsSpeak(iSender)) {

            return HC_CONTINUE

        }

​

        SetHookChainReturn(ATYPE_BOOL, func_CheckListening(iReceiver, iSender) ? true : false)

​

        return HC_SUPERCEDE

    }

#else

    public OnSetClientListening_Pre(iReceiver, iSender, bool:bCanHear) {

        if(!IsSpeak(iSender)) {

            return FMRES_IGNORED

        }

​

        engfunc(EngFunc_SetClientListening, iReceiver, iSender, func_CheckListening(iReceiver, iSender) ? true : false)

​

        return FMRES_SUPERCEDE

    }

#endif

​

bool:func_CheckListening(iReceiver, iSender) {

#if defined OBEY_ALIVE_STATE

    return (get_user_team(iReceiver) == get_user_team(iSender) && is_user_alive(iReceiver) == is_user_alive(iSender))

#else

    return (get_user_team(iReceiver) == get_user_team(iSender))

#endif

}

​

public func_AdminVoiceOn(id) {

    if(!IsSpeak(id)) {

        SetSpeak(id)

        client_cmd(id, "+voicerecord")

    }

​

    return PLUGIN_HANDLED

}

​

public func_AdminVoiceOff(id) {

    if(IsSpeak(id)) {

        ClearSpeak(id)

        client_cmd(id, "-voicerecord")

    }

​

    return PLUGIN_HANDLED

}

​

public client_disconnected(id) {

    ClearSpeak(id)

}

​

stock SetSpeak(id) (g_iSpeakBitSum |= (1 << id))

stock IsSpeak(id) return (g_iSpeakBitSum & (1 << id))

stock ClearSpeak(id) (g_iSpeakBitSum &= ~(1 << id))