	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	REBUY	SCANMON	ПАРТНЕРЫ	ФОРУМ	МОНИТОР	HELP	КОНТАКТЫ

Toggle Water - Скрываем воду

Теги: Скачать плагины csЭффекты

Плагин позволяет игрокам скрывать воду. Полезно в первую очередь для speedrun/deathrun-серверов, т.к. на некоторых картах сильно повышает fps. Имеется сохранение в nvault по steamid, т.е. при перезаходе игрока состояние скрытия воды сохраняется. Так же имеется API для подключения к меню.

Компилятор: 1.8.3 REapi +ZIP 18

Команды:

say /water - переключить видимость воды

.sma / .sp

/* Change history:
	0.1 (18.09.2019) by mx?!:
		* Public release
	0.2 (24.09.2019) by mx?!:
		* Added support for non-water entities, using their content type (thx ChakkiSkrip)
*/

new const PLUGIN_VERSION[] = "0.2"

/* -------------------- */

new const VAULT_NAME[] = "toggle_water"

#define PRUNE_TIME_IN_SECONDS (SECONDS_IN_WEEK * 3)

/* -------------------- */

#include <amxmodx>
#include <fakemeta>
#include <reapi>
#include <nvault>
#include <time>
#include <toggle_water>

#define chx charsmax

#define MaskEnt(%0)	(1<<(%0 & 31))
#define MarkAsWater(%0) (g_iWaterBitSumArray[%0>>5] |= MaskEnt(%0))
#define IsWater(%0) (g_iWaterBitSumArray[%0>>5] & MaskEnt(%0))
//#define ClearWaterMark(%0) (g_iWaterBitSumArray[%0>>5] &= ~MaskEnt(%0))

#define CheckFlag(%0,%1) (g_iPlayerFlags[%0] & (1<<%1))
#define SetFlag(%0,%1) (g_iPlayerFlags[%0] |= (1<<%1))
#define ClearFlag(%0,%1) (g_iPlayerFlags[%0] &= ~(1<<%1))

new const SOUND__BLIP1[] = "sound/buttons/blip1.wav"

enum {
	IS_ALIVE,
	HIDE_WATER,
	NEED_TO_HIDE
}

enum {
	CONTENT_WATER = -3,
	CONTENT_SLIME = -4,
	CONTENT_LAVA = -5
}

new g_iWaterBitSumArray[64]
new g_iPlayerFlags[MAX_PLAYERS + 1]
new g_hVault = INVALID_HANDLE

/* -------------------- */

public plugin_init() {
	register_plugin("Toggle Water", PLUGIN_VERSION, "mx?!")
	register_dictionary("toggle_water.txt")

new bool:bWaterFound

new iMaxEnts = global_get(glb_maxEntities)

for(new pEnt = MaxClients; pEnt <= iMaxEnts; pEnt++) {
		if(!is_entity(pEnt)) {
			continue
		}

if(FClassnameIs(pEnt, "func_water") || get_entvar(pEnt, var_skin) <= CONTENT_WATER) {
			bWaterFound = true;
			MarkAsWater(pEnt)
		}
	}

//new pEnt = MaxClients

/*while((pEnt = rg_find_ent_by_class(pEnt, "func_water", .useHashTable = true))) {
		bWaterFound = true;
		MarkAsWater(pEnt)
	}*/

if(bWaterFound) {
		register_forward(FM_AddToFullPack, "OnAddToFullPack_Post", true)
		RegisterHookChain(RG_CBasePlayer_PreThink, "OnPreThink_Post", true)
		RegisterHookChain(RG_CBasePlayer_Spawn, "OnPlayerSpawn_Post", true)
		RegisterHookChain(RG_CBasePlayer_Killed, "OnPlayerKilled_Post", true)
	}

register_clcmd("say /water", "clcmd_ToggleWater")
}

/* -------------------- */

public plugin_cfg() {
	g_hVault = nvault_open(VAULT_NAME)

if(g_hVault != INVALID_HANDLE) {
		nvault_prune(g_hVault, 0, get_systime() - PRUNE_TIME_IN_SECONDS)
	}
}

/* -------------------- */

public OnAddToFullPack_Post(es, e, ent, host, flags, player, pSet) {
	if(IsWater(ent) && CheckFlag(host, NEED_TO_HIDE)) {
		set_es(es, ES_Effects, EF_NODRAW)
	}
}

/* -------------------- */

public OnPreThink_Post(pPlayer) {
	if(!CheckFlag(pPlayer, HIDE_WATER)) {
		return
	}

if(!CheckFlag(pPlayer, IS_ALIVE) || (get_entvar(pPlayer, var_flags) & FL_INWATER)) {
		ClearFlag(pPlayer, NEED_TO_HIDE)
		return
	}

SetFlag(pPlayer, NEED_TO_HIDE)
}

/* -------------------- */

public OnPlayerSpawn_Post(pPlayer) {
	if(is_user_alive(pPlayer)) {
		SetFlag(pPlayer, IS_ALIVE)
	}
}

/* -------------------- */

public OnPlayerKilled_Post(pVictim, pKiller, iGib) {
	ClearFlag(pVictim, IS_ALIVE)
}

/* -------------------- */

public client_disconnected(pPlayer) {
	g_iPlayerFlags[pPlayer] = 0
}

/* -------------------- */

public clcmd_ToggleWater(pPlayer) {
	new szAuthID[MAX_AUTHID_LENGTH]
	get_user_authid(pPlayer, szAuthID, chx(szAuthID))

if(CheckFlag(pPlayer, HIDE_WATER)) {
		ClearFlag(pPlayer, HIDE_WATER);
		ClearFlag(pPlayer, NEED_TO_HIDE)

if(g_hVault != INVALID_HANDLE) {
			nvault_remove(g_hVault, szAuthID)
		}
	}
	else {
		SetFlag(pPlayer, HIDE_WATER)

if(g_hVault != INVALID_HANDLE) {
			nvault_set(g_hVault, szAuthID, "1")
		}
	}

rg_send_audio(pPlayer, SOUND__BLIP1)

client_print_color( pPlayer, print_team_red, "%l", "TOGGLE_WATER__PATTERN",
		CheckFlag(pPlayer, HIDE_WATER) ? "TOGGLE_WATER__OFF" : "TOGGLE_WATER__ON" );

return PLUGIN_HANDLED
}

/* -------------------- */

public plugin_end() {
	if(g_hVault != INVALID_HANDLE) {
		nvault_close(g_hVault)
	}
}

/* -------------------- */

public client_authorized(pPlayer, const szAuthID[]) {
	if(g_hVault == INVALID_HANDLE) {
		return
	}

if(nvault_get(g_hVault, szAuthID)) {
		SetFlag(pPlayer, HIDE_WATER)
		nvault_touch(g_hVault, szAuthID)
	}
}

/* -------------------- */

public plugin_natives() {
	register_native("ToggleWater_GetStatus", "_ToggleWater_GetStatus")
	register_native("ToggleWater_ToggleStatus", "_ToggleWater_ToggleStatus")
}

/* -------------------- */

public bool:_ToggleWater_GetStatus(iPluginID, iParamCount) {
	enum { player = 1 }
	return (CheckFlag(get_param(player), HIDE_WATER)) ? false : true;
}

/* -------------------- */

public _ToggleWater_ToggleStatus(iPluginID, iParamCount) {
	enum { player = 1 }
	clcmd_ToggleWater(get_param(player))
}

Загрузил root

2020-11-22 21:50:58

Скачать

CSHOST.COM.UA CSS SERVER

82.118.19.206:27024

Half-Life

91.211.118.37:27028

Half-Life

82.118.19.209:27018

123

193.19.118.68:27059

Garry's Mod

91.211.118.37:27030

Left 4 Dead 2

91.211.118.37:27031

CSDM-ПУШКИ-МИНЫ

91.211.118.37:27044

Зомби стройка

91.211.118.37:27045

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Left 4 Dead 2 Counter-Strike: GO Garry's Mod Remote	Вебхостинг PsychoStats Superban Amx Bans Fast DL СS:Bans	Astats Backup MySQL Boost HLTV Army	Помощь Тарифы Дисконты Партнерка Новости Оферта	Форум Мониторинг Плагины^new vk.com steam ok.ru