Voice Control Csstats

// *************************************************************************************//

// Плагин загружен с  www.neugomon.ru                                                   //

// Автор: Neygomon  [ https://neugomon.ru/members/1/ ]                                  //

// Официальная тема поддержки: https://neugomon.ru/threads/171/                         //

// При копировании материала ссылка на сайт www.neugomon.ru ОБЯЗАТЕЛЬНА!                //

// *************************************************************************************//

​

/*

    Voice Control By CsStats это:

        + Защита от школоты, которая не умеет играть и заходит лишь чтобы поорать в микро

        + Защита от фейк-ботов, которые заходят на сервер и начинают орать в Voice чат, тем самым залагивая сервер

        + Совместимость с статистикой от Скальпеля

*/

​

#include <amxmodx>

#include <csstats>

​

​

#define ADMIN_NONE -1

​

#define FRAGS 15    // Cколько минимум фрагов надо для доступа к Voice чату

//#define CS_MYSQL      // CsStats MySQL by Скальпель

#define IMMUNITY ADMIN_LEVEL_H  // Флаг иммунитета к функциям плагина. ADMIN_NONE выключает иммунитет

//#define ENGINE        // Если нет плагинов типа voice management рекомендуется раскомментировать

​

#if defined ENGINE

    #include <engine>

    #define PLUGIN_VERSION "1.3[Engine]"

#else

#include <fakemeta>

    #define PLUGIN_VERSION "1.3[FakeMeta]"

    #define GetBit(%1,%2)       (%1 & (1 << (%2 & 31)))

    #define SetBit(%1,%2)       %1 |= (1 << (%2 & 31))

    #define ResetBit(%1,%2)     %1 &= ~(1 << (%2 & 31))

    new g_bBlockVoice;

#endif

​

#if defined CS_MYSQL

native csstats_get_user_stats(id, stats[22]);

public plugin_natives() set_native_filter("native_filter");

public native_filter(const name[], index, trap) return !trap ? PLUGIN_HANDLED : PLUGIN_CONTINUE;

#endif

​

public plugin_init()

{

    register_plugin("VoiceControl by CsStats", PLUGIN_VERSION, "neygomon");

    register_logevent("LeRoundEnd", 2, "1=Round_End");

#if !defined ENGINE 

    register_forward(FM_Voice_SetClientListening, "fwdSetClientListening");

#endif  

}

​

public client_putinserver(id)

    CheckStatsAndSetVoice(id);

​

public LeRoundEnd()

    CheckStatsAndSetVoice(0);

​

CheckStatsAndSetVoice(index)

{

    static players[32], pnum;

    if(index > 0)

    {

        players[0] = index;

        pnum = 1;

    }

    else get_players(players, pnum);

#if defined CS_MYSQL    

    new stats[22];

#else

    new stats[8], bh[8];

#endif

    for(new i; i < pnum; i++)

    {

#if IMMUNITY != ADMIN_NONE

        if(get_user_flags(players[i]) & IMMUNITY)

        {

#if defined ENGINE

            set_speak(players[i], SPEAK_NORMAL);

#else       

            ResetBit(g_bBlockVoice, players[i]);

#endif          

            continue;

        }

#endif

#if defined CS_MYSQL    

        csstats_get_user_stats(players[i], stats);

#else       

        get_user_stats(players[i], stats, bh);

#endif      

        if(stats[0] >= FRAGS) 

#if defined ENGINE

            set_speak(players[i], SPEAK_NORMAL);

#else       

            ResetBit(g_bBlockVoice, players[i]);

#endif  

        else

        {

#if defined ENGINE

            set_speak(players[i], SPEAK_MUTED);

#else       

            SetBit(g_bBlockVoice, players[i]);

#endif      

            ChatColor(players[i], "^3* ^1[^4UP-CS^1] ^4Для доступа к голосовому чату осталось ^3[%d/%d] ^4фрагов.", stats[0], FRAGS);

        }   

    }

}

#if !defined ENGINE

public fwdSetClientListening(receiver, sender)

{

    if(receiver != sender && GetBit(g_bBlockVoice, sender))

    {

        engfunc(EngFunc_SetClientListening, receiver, sender, false);

        return FMRES_SUPERCEDE;

    }

    return FMRES_IGNORED;

}

#endif

stock ChatColor(const id, const szMessage[], any:...)

{

    static szMsg[190], IdMsg; 

    vformat(szMsg, charsmax(szMsg), szMessage, 3);

    if(!IdMsg) IdMsg = get_user_msgid("SayText");

    if(!is_user_connected(id)) return 0;

    message_begin(MSG_ONE, IdMsg, .player = id);

    write_byte(id);

    write_string(szMsg);

    message_end();

    return 1;

}