	ГЛАВНАЯ	УСЛУГИ	ПЛАГИНЫ	КАРТЫ	REBUY	SCANMON	CASSA	SALE	ФОРУМ	МОНИТОР	HELP	КОНТАКТ

Заявки админу

Теги: Скачать плагины csgoСерверные

ИГРОКИ МОГУТ ОСТАВЛЯТЬ ЗАЯВКИ РАЗ В N СЕКУНД.
ВОЗМОЖНОСТЬ ПРОСМАТРИВАТЬ ИЛИ УДАЛЯТЬ ПОСЛЕДНЮЮ ЗАЯВКУ ИГРОКА.
МЕНЮ УПРАВЛЕНИЯ, С ВОЗМОЖНОСТЬЮ ПРОСМОТРА И УДАЛЕНИЯ ЗАЯВОК.
УСТАНОВКА СТАТУСА КОНКРЕТНОЙ ЗАЯВКИ, КОТОРЫЙ ПОТОМ МОЖЕТ УВИДЕТЬ ИГРОК.

Компилятор: 1.9.0.6281 1394

Команды:

!rq - Оставить заявку

//Квары

SM_TIME_BEFORE_REQUEST - ВРЕМЯ ПЕРЕД ОТПРАВЛЕНИЕМ СЛЕДУЮЩЕЙ ЗАЯВКИ

SM_REQUEST_SHOWBAN - ОТОБРАЖАТЬ В МЕНЮ ЗАЯВОК ПОДСКАЗКУ О БАНАХ

SM_REQUEST_FLAG - ФЛАГ ДЛЯ ОТОБРАЖЕНИЯ В АДМИНКЕ МЕНЮ ЗАЯВОК ("C")

.sma / .sp

/* Заметка с изменениями: 
	28.08.16 Исправлен фриз при удалении заявки.
	Изменены некоторые пункты меню: убраны ненужные цифры
	Меню управления заявкой умещается на 1 странице
	Статистика возвращает в корректное меню
	29.08.16 Запись кваров в конфиг
	Фикс Event_PostNoCopy
	Удаление старых комментариев
	Счетчик непрочитанных уменьшается при изменении статуса любой заявки (это не правильно, но лучше так)
	09.09.16 Фикс квара с флагом доступа, спасибо R1ko
	Попытка фикса вывода админам кол-ва непрочитанных заявок при входе
	Теперь генерируется файл с конфигом
	Мелкие оптимизаци от Almazon
	11.09.16 Заявки со статусом: "В работе", теперь отображаются не в архиве, а в Новых заявках
*/
#pragma semicolon 1
#pragma newdecls required
#define DEFAULT_ANSWER "Нет ответа" // Стандартная надпись на отсутствующий ответ. Можно например написать: Срочно? Skype: ....  (Базу придется удалить)

#include <sourcemod>
#undef REQUIRE_PLUGIN
#include <adminmenu>

public Plugin myinfo = {
	name = "Requests: Advanced",	author = "diller110",
	description = "Players requests for server's administators",
	version = "2.2.2",	url = "http://hlmod.ru/"
};

Database db = null;
TopMenu hTopMenu = null;
TopMenuObject hRequestCategory;
Menu RequestMenu, RequestMenu_Stats, BanHint;
bool ScanChat[MAXPLAYERS + 1], InStatsFromAdmin[MAXPLAYERS + 1];
int ScanChat_AdminchangeN[MAXPLAYERS + 1], ShowBan = 1, Total = 0, Seen = 0;
static char TAG[] = " \x06[Request]", statuss[][] = {"Не просмотрено", "В работе", "Выполнено", "Отклонено"};
// Добавить статус вот так:
//char statuss[][] = {"Не просмотрено", "В работе", "Выполнено", "Отклонено", "СВОЕ", "СВОЕ", "СВОЕ"};
ConVar ConVar_ShowBanRequest, ConVar_AccessFlag;
ArrayList Informer; int Flag;

public void OnPluginStart() {
	Database.Connect(DBConnect, "request");
	
	HookEvent("player_team", Event_PlayerTeam, EventHookMode_Post);
	
	RegConsoleCmd("sm_request", Command_Request);
	RegConsoleCmd("sm_rq", Command_Request);

AddCommandListener(Command_Say, "say");
	AddCommandListener(Command_Say, "say_team");
	
	TopMenu topmenu;
	if (LibraryExists("adminmenu") && ((topmenu = GetAdminTopMenu()) != null))
		OnAdminMenuReady(topmenu);
	
	ConVar_ShowBanRequest = CreateConVar("sm_request_showban", "1", "Отображать в меню заявок подсказку о банах");
	ConVar_AccessFlag = CreateConVar("sm_request_flag", "c", "Доступ к управлению заявками админам со следующим флагом");
	char access_command[2];
	GetConVarString(ConVar_AccessFlag, access_command, 2);
	Flag = ReadFlagString(access_command);
	
	ShowBan = GetConVarInt(ConVar_ShowBanRequest);
	AutoExecConfig(true, "requests_advanced");
	
	RegisterMenus();
	Informer = new ArrayList(20);
	PrintToChatAll("%s \x01Вы можете оставить сообщение администрации командой \x06!rq", TAG);
}

public void OnClientConnected(int client){
	InStatsFromAdmin[client] = false;
}

public void Event_PlayerTeam(Event event,char[] name,  bool dontBroadcast) {
	int client = GetClientOfUserId(event.GetInt("userid"));
	if(!event.GetBool("disconnect") && event.GetInt("oldteam") == 0 && !IsFakeClient(client)) {
		if(GetUserAdmin(client) != INVALID_ADMIN_ID && CheckCommandAccess(client, "broken_command_i_guess", Flag) && (Total-Seen>0))
			PrintToChat(client, "%s \x0FВнимание: \x01Имеются %d непрочитанных заявки(ок)!", TAG, Total-Seen);
		char steambuff[20];
		GetClientAuthId(client, AuthId_Steam2, steambuff, 20);
		int ind = Informer.FindString(steambuff);
		if(ind != -1){
			PrintToChat(client, "%s \x0FВнимание: \x01Одна из ваших заявок была изменена!", TAG);
			Informer.Erase(ind);
		}
	}
}

public void OnAdminMenuReady(Handle aTopMenu) {
	TopMenu topmenu = TopMenu.FromHandle(aTopMenu);
	if (topmenu == hTopMenu) return;
	hTopMenu = topmenu;
	
	hRequestCategory = hTopMenu.AddCategory("Requests", CategoryHandler, "sm_kick", Flag);
	if (hRequestCategory != INVALID_TOPMENUOBJECT) {
		hTopMenu.AddItem("0", AdminRequest_New, hRequestCategory, "sm_kick", Flag);
		hTopMenu.AddItem("1", AdminRequest_List, hRequestCategory, "sm_kick", Flag);
		hTopMenu.AddItem("2", AdminRequest_Stats, hRequestCategory, "sm_kick", Flag);
	}
}

public Action Command_Say(int client, const char[] command, int args) {
	if(ScanChat[client] && IsValidClient(client)){
		char Text[512];
		GetCmdArgString(Text, sizeof(Text));
		TrimString(Text);
		if(StrContains(Text, "отмена", false) != -1 || StrContains(Text, "cancel", false) != -1) {
			PrintToChat(client, "%s \x01Вы отменили отправление заявки.", TAG);
		} else if(!Text[0]){
			PrintToChat(client, "%s \x01Вы ничего не написали. Отмена запроса.", TAG);	
		} else {
			char name[64], steamid[32], query[1024], name_safe[129], Text_safe[513];
			GetClientName(client, name, 64);
			GetClientAuthId(client, AuthId_Steam2, steamid, 32);
			db.Escape(name, name_safe, 129);
			db.Escape(Text, Text_safe, 513);
			FormatEx(query, 1024, "INSERT INTO Request (name, steamid, time, request, status) VALUES ('%s', '%s', '%d', '%s', '0');", name_safe, steamid, GetTime(), Text_safe);
			db.Query(SQL_Check, query);
			PrintToChat(client, "%s \x01Ваша заявка (%d): \x06%s", TAG, strlen(Text_safe), Text_safe);
			PrintToChat(client, "%s \x01Мы приняли её на рассмотрение. Узнать статус можно в меню \x06!rq", TAG);
		}
		ScanChat[client] = false;
		return Plugin_Handled;
	} else if(ScanChat_AdminchangeN[client]  && IsValidClient(client)){
		char Text[513];
		GetCmdArgString(Text, sizeof(Text));
		if(StrContains(Text, "отмена", false) != -1 || StrContains(Text, "cancel", false) != -1) {
			PrintToChat(client, "%s \x01Вы отменили изменение ответа.", TAG);
		} else if(!Text[0]){
			PrintToChat(client, "%s \x01Вы ничего не написали. Отмена.", TAG);	
		} else {
			char Text_safe[513];
			db.Escape(Text, Text_safe, 513);
			Format(Text, 513, "UPDATE Request SET answer = '%s' WHERE id = '%d'", Text_safe, ScanChat_AdminchangeN[client]);
			SQL_FastQuery(db, Text);
			PrintToChat(client, "%s \x01Ответ успешно изменен!", TAG);
		}
		ScanChat_AdminchangeN[client] = 0;
		return Plugin_Handled;
	}
	return Plugin_Continue;
}

public int RequestMenuHandler(Menu menu, MenuAction action, int client, int item) {
	if (action == MenuAction_Select)
		switch(item){
			case 0:{
				ScanChat[client] = true;
				PrintToChat(client, "%s \x01Напишите заявку в чат, или введите \x06отмена.", TAG);
			}
			case 1:{
				char query[100], steamid[32];
				GetClientAuthId(client, AuthId_Steam2, steamid, 32);
				Format(query, 100, "SELECT id, time, status FROM Request WHERE steamid = '%.20s'", steamid);
				db.Query(UserListMenu, query, GetClientUserId(client), DBPrio_Normal);
			}
			case 2:{
				InStatsFromAdmin[client] = false;
				RequestMenu_Stats.Display(client, 20);
			}
			case 3:{
				BanHint.Display(client, 30);
			}
		}
}

public int RequestMenu_StatsHandler(Menu menu, MenuAction action, int client, int item) {
	if (action == MenuAction_Select){
	} else if(action == MenuAction_Cancel){
		if(GetUserAdmin(client) != INVALID_ADMIN_ID && InStatsFromAdmin[client]){
			hTopMenu.DisplayCategory(hRequestCategory, client);
		} else RequestMenu.Display(client,30);
	}
}

public int UserListMenu(Database dbase, DBResultSet results, const char[] error, int user){
	if(results == null){
		PrintToServer("[Request] Failed to query: %s", error);
	} else {
		Menu UserList = CreateMenu(UserListHandler);
		UserList.SetTitle("Список отправленных заявок:");
		int n = 0;
		while(results.FetchRow()){
			int id = results.FetchInt(0), time = results.FetchInt(1);
			char ids[5]; IntToString(id, ids, 5);
			char date[26];
			int status = results.FetchInt(2);
			FormatTime(date, 26, "%H:%M %d %b", time); //"%H:%M %e %h"
			char text[20];
			FormatEx(text, 32, "%s", date);
			switch(status){
				case 0: {
					Format(text, 32, "○ %s", date);
				}
				case 1: {
					Format(text, 32, "● %s", date);
				}
				case 2: {
					Format(text, 32, "√ %s", date);
				}
				case 3: {
					Format(text, 32, "✖ %s", date);
				}
				default:{
					Format(text, 32, "- %s", text);
				}
			}
			UserList.AddItem(ids, text);
			n++;
		}
		if(!n) UserList.AddItem("-1", "Пусто", ITEMDRAW_DISABLED);
		UserList.Display(GetClientOfUserId(user), 30);
	}
}

public int UserListHandler(Menu menu, MenuAction action, int client, int item) {
	if (action == MenuAction_Select){
		char query[255], items[5];
		menu.GetItem(item, items, 5);
		Format(query, 255, "SELECT id, time, status FROM Request WHERE id = '%s' LIMIT 1", items);
		db.Query(UserListItemMenu, query, GetClientUserId(client), DBPrio_Normal);
	} else if (action == MenuAction_Cancel)	{
		RequestMenu.Display(client,30);
	} else if (action == MenuAction_End) {
		delete menu;
	}
}

public void UserListItemMenu(Database dbase, DBResultSet results, const char[] error, int user){
	if(results == null){
		PrintToServer("[Request] Failed to query: %s", error);
	} else {
		Menu UserListItem = CreateMenu(UserListItemHandler);
		UserListItem.SetTitle("Просмотр заявки:");
		if(results.FetchRow()){
			int id = results.FetchInt(0);
			int time = results.FetchInt(1), status = results.FetchInt(2);
			char date[32];
			char buff[196];
			FormatTime(date, 11, "%m/%d/%Y", time);
			FormatEx(buff, 196, "Дата: %s\n", date);
			FormatTime(date, 11, "%H:%M:%S", time);
			FormatEx(buff, 196, "%s\n    Время: %s", buff, date);
			FormatEx(buff, 196, "%s\n    Статус: %s", buff, statuss[status]);
			UserListItem.AddItem("title", buff, ITEMDRAW_DISABLED);
			IntToString(id, date, 5);
			UserListItem.AddItem(date, "Вывести текст в чат");
			UserListItem.AddItem(date, "Удалить заявку");
			UserListItem.AddItem(date, "Закрыть");
			UserListItem.ExitButton = false;
		}
		UserListItem.Display(GetClientOfUserId(user), 30);
	}
}

public int UserListItemHandler(Menu menu, MenuAction action, int client, int item) {
	if (action == MenuAction_Select){
		char query[255], items[5];
		menu.GetItem(item, items, 5);
		switch(item) {
			case 1: {
				PrintToChat(client, "%s \x01Выводим текст \x06%s \x01заявки", TAG, items);
				Format(query, 255, "SELECT request, answer FROM Request WHERE id = '%s' LIMIT 1", items);
				db.Query(UserListItemMenu_Print, query, GetClientUserId(client), DBPrio_Normal);	
				menu.Display(client, 30);
			}
			case 2: {
				BD_DeleteById(StringToInt(items));
				PrintToChat(client, "%s \x01Заявка \x06%s \x01успешно удалена!", TAG, items);
				menu.Cancel();
				delete menu;
				RequestMenu.Display(client,30);
			}
			case 3: {
				menu.Cancel();
				delete menu;
				RequestMenu.Display(client,30);
			}
		}
	}
}

public void UserListItemMenu_Print(Database dbase, DBResultSet results, const char[] error, int user){
	if(results == null){
		PrintToServer("[Request] Failed to query: %s", error);
	} else {
		if(results.FetchRow()){
			char text[512]; results.FetchString(0, text, 512);
			PrintToChat(GetClientOfUserId(user), "%s \x01Вы писали: %s", TAG, text);
			results.FetchString(1, text, 512);
			PrintToChat(GetClientOfUserId(user), "%s \x01Ответ: %s", TAG, text);
		}
	}
}

public void AdminRequest_New(TopMenu topmenu, TopMenuAction action, TopMenuObject object_id, int param, char[] buffer, int maxlength) {
	if (action == TopMenuAction_DisplayOption) {
		FormatEx(buffer, maxlength, "Новые заявки");
	} else if (action == TopMenuAction_SelectOption) {
		db.Query(AdminRequest_NewDB, "SELECT id, time, name, status FROM Request WHERE status < 2", param, DBPrio_Normal);		
	}
}

public void AdminRequest_NewDB(Database dbase, DBResultSet results, const char[] error, int user){
	if(results == null){
		PrintToServer("[Request] Failed to query: %s", error);
	} else {
		Menu AdminRequest_New_List = CreateMenu(AdminRequest_New_ListHandler);
		AdminRequest_New_List.SetTitle("Список заявок:");
		int n = 0;
		while(results.FetchRow()){
			int id = results.FetchInt(0), time = results.FetchInt(1), status = results.FetchInt(3);
			char ids[5]; IntToString(id, ids, 5);
			char date[26];	FormatTime(date, 26, "%H:%M %d %b", time); //"%H:%M %e %h"
			char name[10]; results.FetchString(2, name, 10);			
			char text[20];
			Format(text, 32, "%s %s", name, date);
			switch(status){
				case 0: {
					Format(text, 32, "○ %s", text);
				}
				case 1: {
					Format(text, 32, "● %s", text);
				}
				default:{
					Format(text, 32, "- %s", text);
				}
			}
			AdminRequest_New_List.AddItem(ids, text);
			n++;
		}
		if(!n) AdminRequest_New_List.AddItem("-1", "Пусто", ITEMDRAW_DISABLED);
		AdminRequest_New_List.Display(user, 30);
	}
}

public int AdminRequest_New_ListHandler(Menu menu, MenuAction action, int client, int item) {
	if (action == MenuAction_Select){
		char query[255], items[5];
		menu.GetItem(item, items, 5);
		Format(query, 255, "SELECT id, time, name, request, status FROM Request WHERE id = '%s' LIMIT 1", items);
		db.Query(AdminRequest_New_ListDB, query, GetClientUserId(client), DBPrio_Normal);
	} else if (action == MenuAction_Cancel)	{
		hTopMenu.DisplayCategory(hRequestCategory, client);
	} else if (action == MenuAction_End) {
		delete menu;
	}
}

public void AdminRequest_New_ListDB(Database dbase, DBResultSet results, const char[] error, int user){
	if(results == null){
		PrintToServer("[Request] Failed to query: %s", error);
	} else {
		if(results.FetchRow()){
			char buff[196];
			Menu AdminRequest_New_View = CreateMenu(AdminRequest_New_ViewHandler);
			AdminRequest_New_View.SetTitle("Просмотр заявки (Админ)");
			int id = results.FetchInt(0), time = results.FetchInt(1), status = results.FetchInt(4);
			char name[45], date[32]; results.FetchString(2, name, 20);
			FormatEx(buff, 196, "Отправитель: %s\n    Дата: ", name);
			FormatTime(date, 11, "%m/%d/%Y", time);
			FormatEx(buff, 196, "%s%s\n    Время: ", buff, date);
			FormatTime(date, 11, "%H:%M:%S", time);
			FormatEx(buff, 196, "%s%s\n", buff, date);
			Format(buff, 196, "%s    Статус: %s", buff, statuss[status]);
			AdminRequest_New_View.AddItem("title", buff, ITEMDRAW_DISABLED);
			IntToString(id, buff, 5);
			AdminRequest_New_View.AddItem(buff, "Вывести текст в чат");
			AdminRequest_New_View.AddItem(buff, "Изменить статус");
			AdminRequest_New_View.AddItem(buff, "Изменить ответ");
			AdminRequest_New_View.AddItem(buff, "Удалить заявку");
			AdminRequest_New_View.AddItem(buff, "Закрыть");
			AdminRequest_New_View.ExitButton = false;
			AdminRequest_New_View.Display(GetClientOfUserId(user), 30);
		}
	}
}

public int AdminRequest_New_ViewHandler(Menu menu, MenuAction action, int client, int item) {
	if (action == MenuAction_Select){
		char query[255], items[5];
		menu.GetItem(item, items, 5);
		switch(item){
			case 1: {
				PrintToChat(client, "%s \x01Выводим текст \x06%s \x01заявки:", TAG, items);
				Format(query, 255, "SELECT request FROM Request WHERE id = '%s' LIMIT 1", items);
				db.Query(AdminRequest_New_View_Print, query, GetClientUserId(client), DBPrio_Normal);
				menu.Display(client, 30);
			}
			case 2: {
				Menu AdminRequest_New_Status = CreateMenu(AdminRequest_New_StatusHandler);
				AdminRequest_New_Status.SetTitle("Изменение статуса (Админ)");
				for (int i = 0; i < sizeof(statuss); i++)
					AdminRequest_New_Status.AddItem(items, statuss[i]);
				AdminRequest_New_Status.Display(client, 30);
				menu.Cancel();
				delete menu;
			}
			case 3: {
				PrintToChat(client, "%s \x01Введите ответ в чат:", TAG);
				ScanChat_AdminchangeN[client] = StringToInt(items);
				menu.Display(client, 30);
			}
			case 4: {
				BD_DeleteById(StringToInt(items));
				PrintToChat(client, "%s \x01Заявка \x06%s \x01удалена!", TAG, items);
				menu.Cancel();
				delete menu;
				hTopMenu.DisplayCategory(hRequestCategory, client);
			}
			case 5: {
				menu.Cancel();
				delete menu;
				hTopMenu.DisplayCategory(hRequestCategory, client);
			}
		}
	}
}

public int AdminRequest_New_StatusHandler(Menu menu, MenuAction action, int client, int item) {
	if (action == MenuAction_Select){
		char items[5];	menu.GetItem(item, items, 5);
		BD_SetStatusById(StringToInt(items), item);
		PrintToChat(client, "%s \x01Статус заявки \x06%d \x01изменен на \x06%s\x01.", TAG, StringToInt(items), statuss[item]);
		hTopMenu.DisplayCategory(hRequestCategory, client);
	} else if (action == MenuAction_End) {
		delete menu;
	}
}

public void AdminRequest_New_View_Print(Database dbase, DBResultSet results, const char[] error, int user){
	if(results == null){
		PrintToServer("[Request] Failed to query: %s", error);
	} else {
		char Text[256]; results.FetchString(0, Text, 256);
		PrintToChat(GetClientOfUserId(user), Text);
	}
}

public void AdminRequest_List(TopMenu topmenu, TopMenuAction action, TopMenuObject object_id, int param, char[] buffer, int maxlength) {
	if (action == TopMenuAction_DisplayOption) {
		FormatEx(buffer, maxlength, "Архив заявок");
	} else if (action == TopMenuAction_SelectOption) {	
		db.Query(AdminRequest_ListDB, "SELECT id, time, name, status FROM Request WHERE status > 1", param, DBPrio_Normal);	
	}
}

public void AdminRequest_ListDB(Database dbase, DBResultSet results, const char[] error, int user){
	if(results == null){
		PrintToServer("[Request] Failed to query: %s", error);
	} else {
		Menu AdminRequest_New_List = CreateMenu(AdminRequest_New_ListHandler);
		AdminRequest_New_List.SetTitle("Архив заявок:");
		int n = 0;
		while(results.FetchRow()){
			int id = results.FetchInt(0), time = results.FetchInt(1), status = results.FetchInt(3);
			char ids[5]; IntToString(id, ids, 5);
			char date[26];	FormatTime(date, 26, "%H:%M %d %b", time); //"%H:%M %e %h"
			char name[10]; results.FetchString(2, name, 10);
			char text[32];
			Format(text, 32, "%s %s", name, date);
			switch(status){
				case 1: {
					Format(text, 32, "● %s", text);
				}
				case 2: {
					Format(text, 32, "√ %s", text);
				}
				case 3: {
					Format(text, 32, "✖ %s", text);
				}
				default:{
					Format(text, 32, "- %s", text);
				}
			}
			AdminRequest_New_List.AddItem(ids, text);
			n++;
		}
		if(!n) AdminRequest_New_List.AddItem("-1", "Пусто", ITEMDRAW_DISABLED);
		AdminRequest_New_List.Display(user, 30);
	}
}

public void AdminRequest_Stats(TopMenu topmenu, TopMenuAction action, TopMenuObject object_id, int client, char[] buffer, int maxlength) {
	if (action == TopMenuAction_DisplayOption)
		FormatEx(buffer, maxlength, "Статистика");
	else if (action == TopMenuAction_SelectOption) {
		InStatsFromAdmin[client] = true;
		RequestMenu_Stats.Display(client, 30);
	}
}

public void CategoryHandler(TopMenu topmenu, TopMenuAction action, TopMenuObject object_id,	int param, char[] buffer, int maxlength) {
	if (action == TopMenuAction_DisplayTitle)
		FormatEx(buffer, maxlength, "Управление заявками:");
	else if (action == TopMenuAction_DisplayOption)
		FormatEx(buffer, maxlength, "Управление заявками");
}

public Action Command_Request(int client, int args)	{
	if(IsValidClient(client))
		RequestMenu.Display(client,30); 
	return Plugin_Handled; 
}

// // // // // // // //
//* Вспомогательные *//
// // // // // // // //
public void DBConnect(Database dbase, const char[] error, any data){
	if(dbase==null){
		SetFailState("Request DB connect failed: %s", error);
	} else {
		db = dbase;
		//PrintToServer("Request DB connection successful!", error);
		SQL_LockDatabase(db);
		char query[512]; Format(query, 512, "CREATE TABLE IF NOT EXISTS Request (id INTEGER PRIMARY KEY, name TEXT, steamid TEXT, time TEXT, request TEXT, answer TEXT DEFAULT '%s', status INTEGER);", DEFAULT_ANSWER);
		SQL_FastQuery(db, query);
		SQL_UnlockDatabase(db);
		db.Query(DB_GetCount, "SELECT COUNT(id) FROM Request", true, DBPrio_Normal); // Добавление пункта Всего заявок в статистике
		db.Query(DB_GetCount2, "SELECT COUNT(id) FROM Request WHERE status > 0", true, DBPrio_Normal); // Добавление пункта Просмотрено в статистике
		db.Query(DB_GetCount3, "SELECT COUNT(id) FROM Request WHERE status = 2", true, DBPrio_Normal); // Добавление пункта Принято	
	}
}

public void OnLibraryRemoved(const char[] name){
	if (StrEqual(name, "adminmenu")) hTopMenu = null;
}

public void SQL_Check(Handle owner, Handle hndl, const char[] error, any data) {
	if(hndl == INVALID_HANDLE) LogError("Ошибка (%s)", error);	
}

public void DB_GetCount(Database dbase, DBResultSet results, const char[] error, any data){
	if (results != null) {
		int Count = 0;
		if(results.FetchRow())	Count = results.FetchInt(0);
		char res[16]; FormatEx(res, 16, "Всего: %d", Count);
		Total = Count;
		if(view_as<bool>(data)) RequestMenu_Stats.InsertItem(0, "total", res, ITEMDRAW_DISABLED);
	} else LogError("Request: %s", error);
}

public void DB_GetCount2(Database dbase, DBResultSet results, const char[] error, any data) {
	if (results != null) {
		int Count = 0;
		if(results.FetchRow())	Count = results.FetchInt(0);
		char res[26]; FormatEx(res, 26, "Прочитано: %d", Count); // 20 не влезает! ШТА?
		Seen = Count;
		if(view_as<bool>(data)) RequestMenu_Stats.InsertItem(1, "viewed", res, ITEMDRAW_DISABLED);
	} else LogError("Request: %s", error);
}

public void DB_GetCount3(Database dbase, DBResultSet results, const char[] error, any data) {
	if (results != null) {
		int Count = 0;
		if(results.FetchRow())	Count = results.FetchInt(0);
		char res[80]; FormatEx(res, 80, "Принято: %d\n(Обновляется каждую карту)", Count);
		if(view_as<bool>(data)) RequestMenu_Stats.InsertItem(2, "accept", res, ITEMDRAW_DISABLED);
	} else LogError("Request: %s", error);
}

stock bool IsValidClient(int client) {
	if (client <= 0 || client > MaxClients) return false;
	if (!IsClientInGame(client)) return false;
	return true;
}

stock void BD_DeleteById(int id){
	char query[42];	FormatEx(query, 42, "DELETE FROM Request WHERE id = '%d'", id);
	//SQL_FastQuery(db, query);
	db.Query(DB_DeleteById, query, _, DBPrio_Normal);
}

public void DB_DeleteById(Database dbase, DBResultSet results, const char[] error, any data){
	// Можно ли как то без тебя обойтись?
}

stock void BD_SetStatusById(int id, int status) {
	//Seen++; // Чтобы кол-во непросмотренных заявок убавлялось при оповещении администратору.
	char query[60];
	FormatEx(query, 60, "UPDATE Request SET status=%d WHERE id='%d'", status, id);
	SQL_FastQuery(db, query);
	FormatEx(query, 60, "SELECT steamid, status FROM Request WHERE id='%d'", id);
	db.Query(DB_InformClient, query, _, DBPrio_Normal);
}

public void DB_InformClient(Database dbase, DBResultSet results, const char[] error, any data){
	if (results != null) {
		if (results.FetchRow()) {
			char steamchar[20]; steamchar[0] = '\0';
			results.FetchString(0, steamchar, 20);
			int status = results.FetchInt(1);
			if(steamchar[0]) {
				bool found = false; char steambuff[20];
				for (int i = 1; i <= MaxClients; i++) {
						if (IsClientInGame(i) && !IsFakeClient(i)) {
							GetClientAuthId(i, AuthId_Steam2, steambuff, 20);
							if(StrEqual(steamchar, steambuff)){
								PrintToChat(i, "%s \x0FВнимание: \x01Одна из ваших заявок изменена на \x06%s",TAG, statuss[status]);
								found = true;
							}
						}
				}
				if(!found)	Informer.PushString(steamchar);			
			}
		}
	} else LogError("Request: %s", error);
}

stock void RegisterMenus() {
	RequestMenu = CreateMenu(RequestMenuHandler);
	RequestMenu.SetTitle("Меню заявок:");
	RequestMenu.AddItem("0", "Отправить новую заявку");
	RequestMenu.AddItem("1", "Список отправленных заявок");
	RequestMenu.AddItem("2", "Статистика заявок");
	if(ShowBan) {
		RequestMenu.AddItem("3", "Подозрения в читерстве");
		BanHint = CreateMenu(BanHintHandler);
		BanHint.SetTitle("Подозрения в читерстве:");
		BanHint.AddItem("0", "На сервере ведется запись демок\nВы можете отправить простую заявку\nС указанием ника читера и\nПримерного времени его игры\nМы просмотрим демки и забаним.", ITEMDRAW_DISABLED);
		BanHint.AddItem("0", "Отправить заявку");
	}
	
	RequestMenu_Stats = CreateMenu(RequestMenu_StatsHandler);
	RequestMenu_Stats.SetTitle("Статистика заявок:");
	RequestMenu_Stats.AddItem("disclaimer", "", ITEMDRAW_IGNORE);
}

public int BanHintHandler(Menu menu, MenuAction action, int client, int item) {
	if (action == MenuAction_Select){
		ScanChat[client] = true;
		PrintToChat(client, "%s \x01Напишите заявку в чат, или введите отмена.", TAG);
	} else if(action == MenuAction_Cancel){
		RequestMenu.Display(client,30); 
	}
}

stock int CheckAdminFlags(int client, const char[] cflag) {
    return GetUserFlagBits(client) & ReadFlagString(cflag);
}

public void OnClientPostAdminCheck(int client){
	if(GetUserAdmin(client) != INVALID_ADMIN_ID && CheckCommandAccess(client, "broken_command_i_guess", Flag)){
		db.Query(DB_GetCount, "SELECT COUNT(id) FROM Request", false, DBPrio_Normal);
		db.Query(DB_GetCount2, "SELECT COUNT(id) FROM Request WHERE status > 0", false, DBPrio_Normal);
	}
}

Загрузил exec208

2019-01-28 12:18:12

119

Скачать

не роботает

Zero00939

2023-08-27 12:31:06

exec208 ясно,с одной стороны ето удобно но с другой там будит такой срач)

CS90

2019-01-28 12:36:20

CS90 По типу репорта , можешь подать жалобу на читера , можешь задать любой вопрос , вариаций много.

exec208

2019-01-28 12:35:10

Что за заявки??

CS90

2019-01-28 12:32:04

Данная иконка означает, что плагин был проверен администрацией хостинга на тестовом сервере, и проблем с ним не было выявлено. Рекомендуем ставить исключительно проверенные плагины.

Плагин загружен на сервер, но проверка еще не была проведена.

Игровые сервера	Дополнительные услуги		Инфо	Сообщество

Counter-Strike 1.6 Counter-Strike: Source Counter-Strike: GO Counter-Strike 2 Garry's Mod Remote	VDS/VPS Dedicated Remote Вебхостинг CASSA	Scanmon Fast DL Backup Каталог проэктов Проверка IP ^new	Help Тарифы Партнерка Новости Оферта	Форум Мониторинг Плагины vk.com steam Telegram